diff --git a/CMakeLists.txt b/CMakeLists.txt
index 709b2a05..0e040153 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -10,6 +10,8 @@ project(codal-microbit-v2)
 #    set( "__merged.config.${_key}" "${_val}" )
 #endforeach()
 
+
+
 LIST( LENGTH FINAL_FIELDS _idxMax )
 MATH( EXPR _idxMax "${_idxMax} - 1" )
 foreach( _index RANGE ${_idxMax} )
@@ -22,16 +24,31 @@ if( DEFINED __merged.config.SOFTDEVICE_PRESENT AND NOT "${__merged.config.DEVICE
     message( FATAL_ERROR "Do not define SOFTDEVICE_PRESENT in your configuration, use DEVICE_BLE instead." )
 endif()
 
+
 # Determine if we need SOFTDEVICE support by checking if BLE is enabled.
 if( "${__merged.config.DEVICE_BLE}" STREQUAL "1" )
     message( "Building WITH softdevice support" )
+
+    if( DEFINED codal.config.S140 )
+        message( "Softdevice S140 selected" )
+        set( NRF52833_SOFTDEVICE_VERSION "s140")
+    else()
+        message( "Softdevice S113 selected" )
+        set( NRF52833_SOFTDEVICE_VERSION "s113")
+    endif()
+
     file( APPEND "${EXTRA_INCLUDES_PATH}" " #define SOFTDEVICE_PRESENT    1" )
-    set(CMAKE_LINKER_FLAGS "${CMAKE_LINKER_FLAGS} -T\"${CMAKE_CURRENT_LIST_DIR}/ld/nrf52833-softdevice.ld\"" PARENT_SCOPE)
-    set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -T\"${CMAKE_CURRENT_LIST_DIR}/ld/nrf52833-softdevice.ld\"" PARENT_SCOPE)
+    set(CMAKE_LINKER_FLAGS "${CMAKE_LINKER_FLAGS} -T\"${CMAKE_CURRENT_LIST_DIR}/ld/nrf52833-softdevice-${NRF52833_SOFTDEVICE_VERSION}.ld\"" PARENT_SCOPE)
+    set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -T\"${CMAKE_CURRENT_LIST_DIR}/ld/nrf52833-softdevice-${NRF52833_SOFTDEVICE_VERSION}.ld\"" PARENT_SCOPE)
+
+    RECURSIVE_FIND_FILE(LIB_OBJECT_FILES "${CMAKE_CURRENT_LIST_DIR}/lib/${NRF52833_SOFTDEVICE_VERSION}" "*.o")
+    
 else()
     message( "Building WITHOUT softdevice support" )
     set(CMAKE_LINKER_FLAGS "${CMAKE_LINKER_FLAGS} -T\"${CMAKE_CURRENT_LIST_DIR}/ld/nrf52833.ld\"" PARENT_SCOPE)
     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -T\"${CMAKE_CURRENT_LIST_DIR}/ld/nrf52833.ld\"" PARENT_SCOPE)
+
+    RECURSIVE_FIND_FILE(LIB_OBJECT_FILES "${CMAKE_CURRENT_LIST_DIR}/lib/no_softdevice" "*.o")
 endif()
 
 # find sources and headers
@@ -44,8 +61,6 @@ RECURSIVE_FIND_FILE(SOURCE_FILES2 "${CMAKE_CURRENT_SOURCE_DIR}/model" "*.c??")
 list(APPEND INCLUDE_DIRS "${INCLUDE_DIRS2}")
 list(APPEND SOURCE_FILES "${SOURCE_FILES2}")
 
-# find prebuilt libraries and objects
-RECURSIVE_FIND_FILE(LIB_OBJECT_FILES "${CMAKE_CURRENT_LIST_DIR}/lib" "*.o")
 RECURSIVE_FIND_FILE(LIB_ARCHIVE_FILES "${CMAKE_CURRENT_LIST_DIR}/lib" "*.a")
 
 set(CMAKE_SYSTEM_PROCESSOR "armv7-m" PARENT_SCOPE)
diff --git a/ld/nrf52833-softdevice.ld b/ld/nrf52833-softdevice-s113.ld
similarity index 100%
rename from ld/nrf52833-softdevice.ld
rename to ld/nrf52833-softdevice-s113.ld
diff --git a/ld/nrf52833-softdevice-s140.ld b/ld/nrf52833-softdevice-s140.ld
new file mode 100644
index 00000000..9e7f3e8b
--- /dev/null
+++ b/ld/nrf52833-softdevice-s140.ld
@@ -0,0 +1,191 @@
+MEMORY
+{
+  MBR (rx) : ORIGIN = 0x0000, LENGTH = 0x1000
+  SD (rx) : ORIGIN = 0x1000, LENGTH = 0x26000
+  FLASH (rx) : ORIGIN = 0x27000, LENGTH = 0x77000 - 0x27000
+  BOOTLOADER (rx) : ORIGIN = 0x77000, LENGTH = 0x7E000 - 0x77000
+  SETTINGS (rx) : ORIGIN = 0x7E000, LENGTH = 0x2000
+  UICR (rx) : ORIGIN = 0x10001014, LENGTH = 0x8
+  RAM (rwx) : ORIGIN = 0x20002510, LENGTH = 0x20020000 - 0x20002510
+}
+OUTPUT_FORMAT ("elf32-littlearm", "elf32-bigarm", "elf32-littlearm")
+ENTRY(Reset_Handler)
+SECTIONS
+{
+    . = ALIGN(4);
+    .mbr :
+    {
+        KEEP(*(.mbr))
+    } > MBR
+
+    . = ALIGN(4);
+    .softdevice :
+    {
+        KEEP(*(.softdevice))
+    } > SD
+    
+    . = ALIGN(4);
+    .bootloader :
+    {
+        KEEP(*(.bootloader))
+    } > BOOTLOADER
+
+    . = ALIGN(4);
+    .uicr :
+    {
+        KEEP(*(.uicr))
+    } > UICR
+
+    . = ALIGN(4);
+    .settings :
+    {
+        KEEP(*(.settings))
+    } > SETTINGS
+    
+    .text :
+    {
+        KEEP(*(.isr_vector))
+        KEEP(*(.Vectors))
+        *(.text*)
+        KEEP(*(.init))
+        KEEP(*(.fini))
+        *crtbegin.o(.ctors)
+        *crtbegin?.o(.ctors)
+        *(EXCLUDE_FILE(*crtend?.o *crtend.o) .ctors)
+        *(SORT(.ctors.*))
+        *(.ctors)
+        *crtbegin.o(.dtors)
+        *crtbegin?.o(.dtors)
+        *(EXCLUDE_FILE(*crtend?.o *crtend.o) .dtors)
+        *(SORT(.dtors.*))
+        *(.dtors)
+        *(.rodata*)
+        KEEP(*(.eh_frame*))
+    } > FLASH
+    
+    /* for NRF_LOG_XXX */
+    .log_const_data :
+    {
+      PROVIDE(__start_log_const_data = .);
+      KEEP(*(SORT(.log_const_data*)))
+      PROVIDE(__stop_log_const_data = .);
+    } > FLASH
+    
+    .sdh_ble_observers :
+    {
+      PROVIDE(__start_sdh_ble_observers = .);
+      KEEP(*(SORT(.sdh_ble_observers*)))
+      PROVIDE(__stop_sdh_ble_observers = .);
+    } > FLASH
+    .sdh_soc_observers :
+    {
+      PROVIDE(__start_sdh_soc_observers = .);
+      KEEP(*(SORT(.sdh_soc_observers*)))
+      PROVIDE(__stop_sdh_soc_observers = .);
+    } > FLASH
+    .pwr_mgmt_data :
+    {
+      PROVIDE(__start_pwr_mgmt_data = .);
+      KEEP(*(SORT(.pwr_mgmt_data*)))
+      PROVIDE(__stop_pwr_mgmt_data = .);
+    } > FLASH
+    .sdh_state_observers :
+    {
+      PROVIDE(__start_sdh_state_observers = .);
+      KEEP(*(SORT(.sdh_state_observers*)))
+      PROVIDE(__stop_sdh_state_observers = .);
+    } > FLASH
+    .sdh_stack_observers :
+    {
+      PROVIDE(__start_sdh_stack_observers = .);
+      KEEP(*(SORT(.sdh_stack_observers*)))
+      PROVIDE(__stop_sdh_stack_observers = .);
+    } > FLASH
+    .sdh_req_observers :
+    {
+      PROVIDE(__start_sdh_req_observers = .);
+      KEEP(*(SORT(.sdh_req_observers*)))
+      PROVIDE(__stop_sdh_req_observers = .);
+    } > FLASH
+
+    .ARM.extab :
+    {
+        *(.ARM.extab* .gnu.linkonce.armextab.*)
+        . = ALIGN(4);
+    } > FLASH
+    __exidx_start = .;
+    .ARM.exidx :
+    {
+        *(.ARM.exidx* .gnu.linkonce.armexidx.*)
+        . = ALIGN(4);
+    } > FLASH
+    __exidx_end = .;
+    __etext = .;
+    .data : AT (__etext)
+    {
+        __data_start__ = .;
+        *(vtable)
+        *(.data*)
+        . = ALIGN(4);
+        PROVIDE_HIDDEN (__preinit_array_start = .);
+        KEEP(*(.preinit_array))
+        PROVIDE_HIDDEN (__preinit_array_end = .);
+        . = ALIGN(4);
+        PROVIDE_HIDDEN (__init_array_start = .);
+        KEEP(*(SORT(.init_array.*)))
+        KEEP(*(.init_array))
+        PROVIDE_HIDDEN (__init_array_end = .);
+        . = ALIGN(4);
+        PROVIDE_HIDDEN (__fini_array_start = .);
+        KEEP(*(SORT(.fini_array.*)))
+        KEEP(*(.fini_array))
+        PROVIDE_HIDDEN (__fini_array_end = .);
+        
+        /* for NRF_LOG_XXX */
+        . = ALIGN(4);
+        PROVIDE(__start_log_dynamic_data = .);
+        KEEP(*(SORT(.log_dynamic_data*)))
+        PROVIDE(__stop_log_dynamic_data = .);
+
+        /* for NRF_LOG_XXX */
+        . = ALIGN(4);
+        PROVIDE(__start_log_filter_data = .);
+        KEEP(*(SORT(.log_filter_data*)))
+        PROVIDE(__stop_log_filter_data = .);
+        
+        . = ALIGN(4);
+        PROVIDE(__start_fs_data = .);
+        KEEP(*(.fs_data))
+        PROVIDE(__stop_fs_data = .);
+        *(.jcr)
+        . = ALIGN(4);
+        __data_end__ = .;
+    } > RAM
+    __edata = .;
+    .noinit :
+    {
+      PROVIDE(__start_noinit = .);
+      KEEP(*(.noinit))
+      PROVIDE(__stop_noinit = .);
+    } > RAM
+    .bss :
+    {
+        . = ALIGN(4);
+        __bss_start__ = .;
+        *(.bss*)
+        *(COMMON)
+        . = ALIGN(4);
+        __bss_end__ = .;
+    } > RAM
+    .heap (NOLOAD):
+    {
+        __end__ = .;
+        end = __end__;
+        *(.heap*);
+        ASSERT(. <= (ORIGIN(RAM) + LENGTH(RAM) - 0x800), "heap region overflowed into stack");
+        . += (ORIGIN(RAM) + LENGTH(RAM) - 0x800) - .;
+    } > RAM
+    __StackTop = ORIGIN(RAM) + LENGTH(RAM);
+    PROVIDE(__stack = __StackTop);
+}
+
diff --git a/lib/bootloader.o b/lib/no_softdevice/bootloader.o
similarity index 100%
rename from lib/bootloader.o
rename to lib/no_softdevice/bootloader.o
diff --git a/lib/mbr.o b/lib/no_softdevice/mbr.o
similarity index 100%
rename from lib/mbr.o
rename to lib/no_softdevice/mbr.o
diff --git a/lib/settings.o b/lib/no_softdevice/settings.o
similarity index 100%
rename from lib/settings.o
rename to lib/no_softdevice/settings.o
diff --git a/lib/uicr.o b/lib/no_softdevice/uicr.o
similarity index 100%
rename from lib/uicr.o
rename to lib/no_softdevice/uicr.o
diff --git a/lib/s113/bootloader.o b/lib/s113/bootloader.o
new file mode 100644
index 00000000..b4b8a09b
Binary files /dev/null and b/lib/s113/bootloader.o differ
diff --git a/lib/s113/mbr.o b/lib/s113/mbr.o
new file mode 100644
index 00000000..872db0f6
Binary files /dev/null and b/lib/s113/mbr.o differ
diff --git a/lib/s113/settings.o b/lib/s113/settings.o
new file mode 100644
index 00000000..5d588b58
Binary files /dev/null and b/lib/s113/settings.o differ
diff --git a/lib/softdevice.o b/lib/s113/softdevice.o
similarity index 100%
rename from lib/softdevice.o
rename to lib/s113/softdevice.o
diff --git a/lib/s113/uicr.o b/lib/s113/uicr.o
new file mode 100644
index 00000000..e8d97fc0
Binary files /dev/null and b/lib/s113/uicr.o differ
diff --git a/lib/s140/bootloader.o b/lib/s140/bootloader.o
new file mode 100644
index 00000000..b4b8a09b
Binary files /dev/null and b/lib/s140/bootloader.o differ
diff --git a/lib/s140/mbr.o b/lib/s140/mbr.o
new file mode 100644
index 00000000..872db0f6
Binary files /dev/null and b/lib/s140/mbr.o differ
diff --git a/lib/s140/settings.o b/lib/s140/settings.o
new file mode 100644
index 00000000..5d588b58
Binary files /dev/null and b/lib/s140/settings.o differ
diff --git a/lib/s140/softdevice.o b/lib/s140/softdevice.o
new file mode 100644
index 00000000..56ed5970
Binary files /dev/null and b/lib/s140/softdevice.o differ
diff --git a/lib/s140/uicr.o b/lib/s140/uicr.o
new file mode 100644
index 00000000..e8d97fc0
Binary files /dev/null and b/lib/s140/uicr.o differ