dist.nuget.bat

@echo off
setlocal

set "PROJECT=src\DotNetSphinx\DotNetSphinx.csproj"
set "OUT_DIR=%~dp0nupkg"
set "GITVERSION_DLL=%USERPROFILE%\.nuget\packages\gitversion.msbuild\6.4.0\tools\net8.0\gitversion.dll"
set "TOOLS_DIR=%~dp0tools\nuget"
set "NUGET_EXE=%TOOLS_DIR%\nuget.exe"

for /f "usebackq tokens=*" %%v in (`dotnet --roll-forward Major "%GITVERSION_DLL%" "%~dp0src\DotNetSphinx" /showvariable SemVer`) do set "VERSION=%%v"
if not defined VERSION (
  echo Failed to determine package version from GitVersion.
  exit /b 1
)

echo Packing %PROJECT% with version %VERSION%...
dotnet pack "%PROJECT%" -c Release /p:PackageVersion=%VERSION% -o "%OUT_DIR%"
if errorlevel 1 (
  echo dotnet pack failed.
  exit /b 2
)

echo Signing packages...
powershell -NoProfile -ExecutionPolicy Bypass -File "%~dp0sign.ps1" "%OUT_DIR%"
if errorlevel 1 (
  echo Package signing failed.
  exit /b 3
)

if not exist "%TOOLS_DIR%" mkdir "%TOOLS_DIR%"
if not exist "%NUGET_EXE%" (
  echo Downloading nuget.exe...
  powershell -NoProfile -Command "Invoke-WebRequest -Uri 'https://dist.nuget.org/win-x86-commandline/latest/nuget.exe' -OutFile '%NUGET_EXE%'" >nul 2>&1
  if errorlevel 1 (
    echo Failed to download nuget.exe.
    exit /b 4
  )
)

for %%F in ("%OUT_DIR%\*.nupkg") do (
  echo Pushing %%~nxf ...
  "%NUGET_EXE%" push "%%F" -Source https://www.nuget.org/api/v2/package
  if errorlevel 1 (
    echo nuget push failed for %%~nxf.
    exit /b 5
  )
)

echo Done.
endlocal