Introduce meson.build

Introduce meson.build to be used with the Meson build system,
which handles the dependency and advanced compiler options
for when used on various linux distributions.

The libftdi .so for example has different names on different
distribution, using meson makes sure we can handle those easily,
and easily integrate with other package build systems like
Yocto or Buildroot.

Signed-off-by: Neil Armstrong <[email protected]>

Author: superna9999

README

@@ -3,13 +3,21 @@ The CDBA control tool is used for remotely booting images on development boards
 attached using a CDB Assist [https://github.com/sonyxperiadev/CDB-Assist] or Conmux.
 
 = Dependencies
-sudo apt-get install libudev-dev libyaml-dev for debian systems
-dnf install systemd-devel libyaml-devel for fedora systems
+sudo apt-get install libudev-dev libyaml-dev libftdi1-dev for debian systems
+dnf install systemd-devel libyaml-devel libftdi1-devel for fedora systems
 
 = Device side
 On the host with the CDB Assist or Conmux attached the "cdba-server" executable is run
 from sandbox/cdba/cdba-server. Available devices are read from $HOME/.cdba
 
+= Build instructions
+
+Either use make directly:
+# make
+or use the Meson build system:
+# meson . build
+# ninja -C build
+
 = Client side
 The client is invoked as:
 

meson.build

@@ -0,0 +1,76 @@
+# SPDX-License-Identifier: GPL-2.0
+
+project('cdba',
+	'c',
+	default_options: [
+            'warning_level=2',	# sets -Wextra
+            'buildtype=release',
+        ])
+
+compiler = meson.get_compiler('c')
+
+# If compiler variables are detectable, add some selected ones
+if meson.version().version_compare('>=0.43.0')
+	base_cflags = ['-Wno-unused-parameter',
+		       '-Wno-unused-result',
+		       '-Wno-missing-field-initializers',
+		       '-Wno-sign-compare',
+		       '-Wundef',
+		       '-Wnull-dereference',
+		       '-Wdouble-promotion',
+		       '-Wshadow',
+		       '-Wpointer-arith',
+		       '-Wwrite-strings',
+		       '-Wstrict-overflow=4']
+
+	if compiler.get_id() == 'gcc'
+		compiler_cflags = ['-Werror',	# Only set it on GCC
+			           '-Wformat-signedness',
+				   '-Wduplicated-cond',
+				   '-Wduplicated-branches',
+				   '-Wvla-larger-than=1',
+				   '-Walloc-zero',
+				   '-Wunsafe-loop-optimizations',
+				   '-Wcast-align',
+				   '-Wlogical-op',
+				   '-Wjump-misses-init']
+	elif compiler.get_id() == 'clang'
+		# TODO add clang specific options
+		compiler_cflags = []
+	endif
+
+	add_global_arguments(compiler.get_supported_arguments(base_cflags),	
+			     compiler.get_supported_arguments(compiler_cflags),
+			     language: 'c')
+endif
+
+client_srcs = ['cdba.c',
+	       'circ_buf.c']
+executable('cdba',
+	   client_srcs,
+	   install : true)
+
+ftdi_dep = dependency('libftdi1', required: false)
+if not ftdi_dep.found()
+	ftdi_dep = dependency('libftdi')
+endif
+
+server_deps = [dependency('libudev'),
+	       dependency('yaml-0.1'),
+	       ftdi_dep]
+server_srcs = ['cdba-server.c',
+	       'cdb_assist.c',
+	       'circ_buf.c',
+	       'conmux.c',
+	       'device.c',
+	       'device_parser.c',
+	       'fastboot.c',
+	       'alpaca.c',
+	       'ftdi-gpio.c',
+	       'console.c',
+	       'qcomlt_dbg.c',
+	       'ppps.c']
+executable('cdba-server',
+	   server_srcs,
+	   dependencies : server_deps,
+	   install : true)