Skip deployment from CLI for unchanged apps (#3116)

aleDsz · web-flow · commit 3e7f6b589a3b · 2026-01-14T15:28:57.000-03:00
diff --git a/lib/livebook/teams.ex b/lib/livebook/teams.ex
@@ -267,17 +267,17 @@ defmodule Livebook.Teams do
   @doc """
   Deploys the given app deployment to given deployment group using an org token.
   """
-  @spec deploy_app_from_cli(Team.t(), Teams.AppDeployment.t(), integer()) ::
-          {:ok, String.t()} | {:error, map()} | {:transport_error, String.t()}
+  @spec deploy_app_from_cli(Team.t(), Teams.AppDeployment.t(), integer(), keyword()) ::
+          {:ok, map()} | {:error, map()} | {:transport_error, String.t()}
   def deploy_app_from_cli(
         %Team{} = team,
         %Teams.AppDeployment{} = app_deployment,
-        deployment_group_id
+        deployment_group_id,
+        opts \\ []
       ) do
-    case Requests.deploy_app_from_cli(team, app_deployment, deployment_group_id) do
-      {:ok, %{"url" => url}} -> {:ok, url}
-      {:error, %{"errors" => errors}} -> {:error, errors}
-      any -> any
+    with {:error, %{"errors" => errors}} <-
+           Requests.deploy_app_from_cli(team, app_deployment, deployment_group_id, opts) do
+      {:error, errors}
     end
   end
 
diff --git a/lib/livebook/teams/app_deployment.ex b/lib/livebook/teams/app_deployment.ex
@@ -63,11 +63,20 @@ defmodule Livebook.Teams.AppDeployment do
     end
   end
 
-  def new(%Livebook.Notebook{} = notebook, source, files_dir) do
+  defp new(%Livebook.Notebook{} = notebook, source, files_dir) do
     with {:ok, files} <- build_and_check_file_entries(notebook, source, files_dir),
          {:ok, {_, zip_content}} <- :zip.create(~c"app_deployment.zip", files, [:memory]),
          :ok <- validate_size(zip_content) do
-      md5_hash = :crypto.hash(:md5, zip_content)
+      md5_hash =
+        :crypto.hash(
+          :md5,
+          files
+          |> Enum.sort()
+          |> Enum.map(fn {file, contents} ->
+            ["__FILE__", file, contents]
+          end)
+        )
+
       shasum = Base.encode16(md5_hash, case: :lower)
 
       {:ok,
diff --git a/lib/livebook/teams/requests.ex b/lib/livebook/teams/requests.ex
@@ -241,19 +241,22 @@ defmodule Livebook.Teams.Requests do
   @doc """
   Send a request to Livebook Team API to deploy an app using an org token.
   """
-  @spec deploy_app_from_cli(Team.t(), Teams.AppDeployment.t(), integer()) :: api_result()
-  def deploy_app_from_cli(team, app_deployment, deployment_group_id) do
+  @spec deploy_app_from_cli(Team.t(), Teams.AppDeployment.t(), integer(), keyword()) ::
+          api_result()
+  def deploy_app_from_cli(team, app_deployment, deployment_group_id, opts) do
     secret_key = Teams.derive_key(team.teams_key)
 
-    params = %{
-      title: app_deployment.title,
-      slug: app_deployment.slug,
-      multi_session: app_deployment.multi_session,
-      access_type: app_deployment.access_type,
-      app_folder_id: app_deployment.app_folder_id,
-      deployment_group_id: deployment_group_id,
-      sha: app_deployment.sha
-    }
+    params =
+      %{
+        title: app_deployment.title,
+        slug: app_deployment.slug,
+        multi_session: app_deployment.multi_session,
+        access_type: app_deployment.access_type,
+        app_folder_id: app_deployment.app_folder_id,
+        deployment_group_id: deployment_group_id,
+        sha: app_deployment.sha,
+        redeploy: opts[:redeploy] || false
+      }
 
     encrypted_content = Teams.encrypt(app_deployment.file, secret_key)
     upload("/api/v1/cli/org/apps", encrypted_content, params, team)
diff --git a/lib/livebook_cli/deploy.ex b/lib/livebook_cli/deploy.ex
@@ -37,7 +37,8 @@ defmodule LivebookCLI.Deploy do
     org_token: :string,
     teams_key: :string,
     deployment_group_id: :integer,
-    dry_run: :boolean
+    dry_run: :boolean,
+    redeploy: :boolean
   ]
 
   @impl true
@@ -47,6 +48,10 @@ defmodule LivebookCLI.Deploy do
     config = config_from_args(args)
     ensure_config!(config)
 
+    if config.redeploy? do
+      log_warning("Note: --redeploy flag set, all apps will be deployed regardless of changes.")
+    end
+
     team = authenticate_cli!(config)
     deploy_to_teams(team, config)
   end
@@ -59,7 +64,8 @@ defmodule LivebookCLI.Deploy do
       session_token: opts[:org_token],
       teams_key: opts[:teams_key],
       deployment_group_id: opts[:deployment_group_id],
-      dry_run?: opts[:dry_run] || false
+      dry_run?: opts[:dry_run] || false,
+      redeploy?: opts[:redeploy] || false
     }
   end
 
@@ -160,10 +166,15 @@ defmodule LivebookCLI.Deploy do
           case Livebook.Teams.deploy_app_from_cli(
                  team,
                  app_deployment,
-                 config.deployment_group_id
+                 config.deployment_group_id,
+                 redeploy: config.redeploy?
                ) do
-            {:ok, url} ->
-              log_info([:green, "  * #{app_deployment.title} deployed successfully. (#{url})"])
+            {:ok, %{"url" => url, "state" => "deployed"}} ->
+              url = if url, do: " (#{url})", else: ""
+              log_info([:green, "  * #{app_deployment.title} deployed successfully.", url])
+
+            {:ok, %{"state" => "unchanged"}} ->
+              log_info([:blue, "  * #{app_deployment.title} unchanged, skipping"])
 
             {:error, errors} ->
               log_error("  * #{app_deployment.title} failed to deploy.")
diff --git a/test/livebook_teams/cli/deploy_test.exs b/test/livebook_teams/cli/deploy_test.exs
@@ -62,7 +62,46 @@ defmodule LivebookCLI.Integration.DeployTest do
                         app_folder_id: ^app_folder_id,
                         hub_id: ^hub_id,
                         deployed_by: "CLI"
-                      }}
+                      } = app_deployment}
+
+      assert_receive {:app_deployment_started, ^app_deployment}
+
+      # skip if app had no changes
+      output =
+        ExUnit.CaptureIO.capture_io(fn ->
+          assert deploy(
+                   key,
+                   team.teams_key,
+                   deployment_group.id,
+                   app_path
+                 ) == :ok
+        end)
+
+      assert output =~ "* Preparing to deploy notebook #{slug}.livemd"
+      assert output =~ "  * #{title} unchanged, skipping"
+
+      refute_receive {:app_deployment_started, ^app_deployment}
+
+      # should not show `(url/apps/slug)` in the app deployment output
+      {:ok, deployment_group} =
+        TeamsRPC.update_deployment_group(node, deployment_group, %{url: nil})
+
+      # force app to redeploy
+      output =
+        ExUnit.CaptureIO.capture_io(fn ->
+          assert deploy(
+                   key,
+                   team.teams_key,
+                   deployment_group.id,
+                   app_path,
+                   ["--redeploy"]
+                 ) == :ok
+        end)
+
+      assert output =~ "* Preparing to deploy notebook #{slug}.livemd"
+      assert output =~ "  * #{title} deployed successfully."
+
+      assert_receive {:app_deployment_started, ^app_deployment}
     end
 
     test "successfully deploys multiple notebooks from directory",
@@ -482,12 +521,8 @@ defmodule LivebookCLI.Integration.DeployTest do
       end)
     end
 
-    test "successfully runs without deploying when dry run requested", %{
-      team: team,
-      node: node,
-      org: org,
-      tmp_dir: tmp_dir
-    } do
+    test "successfully runs without deploying when dry run requested",
+         %{team: team, node: node, org: org, tmp_dir: tmp_dir} do
       title = "Test CLI Deploy App"
       slug = Utils.random_short_id()
       app_path = Path.join(tmp_dir, "#{slug}.livemd")
diff --git a/test/livebook_teams/teams_test.exs b/test/livebook_teams/teams_test.exs
@@ -298,50 +298,49 @@ defmodule Livebook.TeamsTest do
     end
   end
 
-  describe "deploy_app_from_cli/2" do
+  describe "deploy_app_from_cli/4" do
     @describetag teams_for: :user
+    @describetag :tmp_dir
 
-    @tag :tmp_dir
-    test "deploys app to Teams using a CLI session",
-         %{team: team, node: node, tmp_dir: tmp_dir, org: org} do
-      %{id: id} =
-        TeamsRPC.create_deployment_group(node,
-          name: "angry-cat-#{Ecto.UUID.generate()}",
-          url: "http://localhost:4123",
-          mode: :online,
-          org: org
-        )
-
-      id = to_string(id)
-      hub_id = "team-#{org.name}"
-      slug = Utils.random_short_id()
-      title = "MyNotebook-#{slug}"
-      app_settings = %{Notebook.AppSettings.new() | slug: slug}
+    setup %{team: team, test: test, node: node, org: org, tmp_dir: tmp_dir} do
+      deployment_group = TeamsRPC.create_deployment_group(node, mode: :online, org: org)
+      id = to_string(deployment_group.id)
+      assert_receive {:deployment_group_created, %{id: ^id}}
 
       notebook = %{
         Notebook.new()
-        | app_settings: app_settings,
-          name: title,
-          hub_id: hub_id,
-          deployment_group_id: id
+        | app_settings: %{Notebook.AppSettings.new() | slug: Utils.random_short_id()},
+          name: to_string(test),
+          hub_id: "team-#{org.name}",
+          deployment_group_id: to_string(deployment_group.id)
       }
 
       files_dir = FileSystem.File.local(tmp_dir)
 
-      # stamp the notebook
-      assert {:ok, app_deployment} = Teams.AppDeployment.new(notebook, files_dir)
+      # export to livemd to stamp the notebook (must be done before CLI session)
+      {source, []} = Livebook.LiveMarkdown.notebook_to_livemd(notebook)
+
+      # create the app deployment from stamped source
+      assert {:ok, app_deployment} = Teams.AppDeployment.new(source, files_dir)
 
       # fetch the cli session
       {key, _org_token} = TeamsRPC.create_org_token(node, org: org)
       config = %{teams_key: team.teams_key, session_token: key}
       assert {:ok, team} = Teams.fetch_cli_session(config)
 
-      # deploy the app
-      assert {:ok, _url} = Teams.deploy_app_from_cli(team, app_deployment, id)
+      %{app_deployment: app_deployment, team: team, source: source, files_dir: files_dir}
+    end
+
+    test "deploys app to Teams using a CLI session",
+         %{app_deployment: app_deployment, team: team} = ctx do
+      id = app_deployment.deployment_group_id
+      assert {:ok, %{"state" => "deployed"}} = Teams.deploy_app_from_cli(team, app_deployment, id)
 
+      slug = app_deployment.slug
+      title = app_deployment.title
       sha = app_deployment.sha
-      multi_session = app_settings.multi_session
-      access_type = app_settings.access_type
+      multi_session = app_deployment.multi_session
+      access_type = app_deployment.access_type
 
       assert_receive {:app_deployment_started,
                       %Livebook.Teams.AppDeployment{
@@ -352,14 +351,60 @@ defmodule Livebook.TeamsTest do
                         multi_session: ^multi_session,
                         access_type: ^access_type,
                         deployment_group_id: ^id
-                      } = app_deployment2}
+                      } = app_deployment_from_ws}
+
+      # force app deployment to be stopped
+      TeamsRPC.toggle_app_deployment(ctx.node, app_deployment_from_ws.id, team.org_id)
+      assert_receive {:app_deployment_stopped, ^app_deployment_from_ws}
+    end
+
+    test "skips if the is still the same version, unless forced to redeploy",
+         %{app_deployment: app_deployment, team: team} = ctx do
+      id = app_deployment.deployment_group_id
+      assert {:ok, %{"state" => "deployed"}} = Teams.deploy_app_from_cli(team, app_deployment, id)
+
+      app_deployment_from_ws = assert_app_deployment_started(app_deployment)
+
+      # must skip
+      {:ok, regenerated_app_deployment} = Teams.AppDeployment.new(ctx.source, ctx.files_dir)
+      assert app_deployment.sha == regenerated_app_deployment.sha
+
+      assert {:ok, %{"state" => "unchanged"}} =
+               Teams.deploy_app_from_cli(team, regenerated_app_deployment, id)
+
+      refute_receive {:app_deployment_started, ^app_deployment_from_ws}
+
+      # must redeploy
+      {:ok, app_deployment} = Teams.AppDeployment.new(ctx.source, ctx.files_dir)
+
+      assert {:ok, %{"state" => "deployed"}} =
+               Teams.deploy_app_from_cli(team, app_deployment, id, redeploy: true)
+
+      app_deployment_from_ws = assert_app_deployment_started(app_deployment)
+
+      # force app deployment to be stopped
+      TeamsRPC.toggle_app_deployment(ctx.node, app_deployment_from_ws.id, team.org_id)
+      assert_receive {:app_deployment_stopped, ^app_deployment_from_ws}
+
+      # must redeploy because now the app is inactive
+      {:ok, app_deployment} = Teams.AppDeployment.new(ctx.source, ctx.files_dir)
+      assert {:ok, %{"state" => "deployed"}} = Teams.deploy_app_from_cli(team, app_deployment, id)
+
+      assert_app_deployment_started(app_deployment)
+    end
+
+    test "returns error when has invalid data", %{app_deployment: app_deployment, team: team} do
+      id = app_deployment.deployment_group_id
 
       assert Teams.deploy_app_from_cli(team, app_deployment, 999) ==
                {:error, %{"deployment_group_id" => ["does not exist"]}}
 
       assert Teams.deploy_app_from_cli(team, %{app_deployment | slug: "@abc"}, id) ==
                {:error, %{"slug" => ["should only contain alphanumeric characters and dashes"]}}
 
+      assert Teams.deploy_app_from_cli(team, %{app_deployment | title: nil}, id) ==
+               {:error, %{"title" => ["can't be blank"]}}
+
       assert Teams.deploy_app_from_cli(team, %{app_deployment | multi_session: nil}, id) ==
                {:error, %{"multi_session" => ["can't be blank"]}}
 
@@ -368,10 +413,30 @@ defmodule Livebook.TeamsTest do
 
       assert Teams.deploy_app_from_cli(team, %{app_deployment | access_type: :abc}, id) ==
                {:error, %{"access_type" => ["is invalid"]}}
-
-      # force app deployment to be stopped
-      TeamsRPC.toggle_app_deployment(node, app_deployment2.id, team.org_id)
-      assert_receive {:app_deployment_stopped, ^app_deployment2}
     end
   end
+
+  defp assert_app_deployment_started(app_deployment) do
+    id = app_deployment.deployment_group_id
+    slug = app_deployment.slug
+    title = app_deployment.title
+    sha = app_deployment.sha
+    multi_session = app_deployment.multi_session
+    access_type = app_deployment.access_type
+
+    assert_receive {:app_deployment_started,
+                    %Livebook.Teams.AppDeployment{
+                      slug: ^slug,
+                      sha: ^sha,
+                      title: ^title,
+                      deployed_by: "CLI",
+                      multi_session: ^multi_session,
+                      access_type: ^access_type,
+                      deployment_group_id: ^id
+                    } = app_deployment_from_ws}
+
+    assert_receive {:app_deployment_started, ^app_deployment_from_ws}
+
+    app_deployment_from_ws
+  end
 end
