[flang] DTIO: `stream` access with `pos=` specifier not working properly

[DanielCChen]

Consider the following code

module m
    type base
        integer(8), allocatable :: data(:)
    end type

    interface write(formatted)
        subroutine formattedWrite (dtv, unit, iotype, v_list, iostat, iomsg)
        import base
            class (base), intent(in) :: dtv
            integer, intent(in) :: unit
            character(*), intent(in) :: iotype
            integer, intent(in) :: v_list(:)
            integer, intent(out) :: iostat
            character(*), intent(inout) :: iomsg
        end subroutine
    end interface
end module


subroutine formattedWrite (dtv, unit, iotype, v_list, iostat, iomsg)
use m, only: base
    class (base), intent(in) :: dtv
    integer, intent(in) :: unit
    character(*), intent(in) :: iotype
    integer, intent(in) :: v_list(:)
    integer, intent(out) :: iostat
    character(*), intent(inout) :: iomsg

    flush (unit, iostat=iostat, iomsg=iomsg)

    if (iostat /= 0) return

    if (allocated (dtv%data)) then
        write (unit, *, iostat=iostat, iomsg=iomsg) dtv%data

        if (iostat /= 0) return
    end if

    flush (unit, iostat=iostat, iomsg=iomsg)

end subroutine

program fdtio057
use m
    integer stat
    class (base), allocatable :: b1, b2(:)

    integer(8) :: i1(8) = 9

    allocate (b1, source=base((/-1, -2/)))
    allocate (b2(0:1))

    allocate (b2(0)%data(1), source=100_8)
    allocate (b2(1)%data(0:1), source=(/10_8, 20_8/))

    open (10, file='fdtio057.data', access='stream', form='formatted', &
                status='new')

    write (10, *, pos=15) base ((/2,3,1/))

    write (10, *, pos=25) b1

    write (10, *, pos=1) b2

!    read (10, *, pos=1) i1(1:3)    !<-- 100, 10, 20
!    read (10, *, pos=15, iostat=stat) i1(4:6)   !<-- 2, 3, 1
!    read (10, *, pos=25, iostat=stat) i1(7:8)   !<-- -1, -2

!    print*, i1
!    if (any (i1 /= (/100, 10, 20, 2, 3, 1, -1, -2/))) ERROR STOP 1

!    close (10, status='delete')
end

The output file dtio057.data contains

 100 10 20

When the expected content is

 100 10 20
                2 3 1
               -1 -2

If I move the pos=1 write statement to be the first write statement, Flang produces the expected result.

[llvmbot]

@llvm/issue-subscribers-flang-runtime

Author: Daniel Chen (DanielCChen)

Consider the following code ``` module m type base integer(8), allocatable :: data(:) end type

interface write(formatted)
    subroutine formattedWrite (dtv, unit, iotype, v_list, iostat, iomsg)
    import base
        class (base), intent(in) :: dtv
        integer, intent(in) :: unit
        character(*), intent(in) :: iotype
        integer, intent(in) :: v_list(:)
        integer, intent(out) :: iostat
        character(*), intent(inout) :: iomsg
    end subroutine
end interface

end module

subroutine formattedWrite (dtv, unit, iotype, v_list, iostat, iomsg)
use m, only: base
class (base), intent(in) :: dtv
integer, intent(in) :: unit
character(), intent(in) :: iotype
integer, intent(in) :: v_list(:)
integer, intent(out) :: iostat
character(), intent(inout) :: iomsg

flush (unit, iostat=iostat, iomsg=iomsg)

if (iostat /= 0) return

if (allocated (dtv%data)) then
    write (unit, *, iostat=iostat, iomsg=iomsg) dtv%data

    if (iostat /= 0) return
end if

flush (unit, iostat=iostat, iomsg=iomsg)

end subroutine

program fdtio057
use m
integer stat
class (base), allocatable :: b1, b2(:)

integer(8) :: i1(8) = 9

allocate (b1, source=base((/-1, -2/)))
allocate (b2(0:1))

allocate (b2(0)%data(1), source=100_8)
allocate (b2(1)%data(0:1), source=(/10_8, 20_8/))

open (10, file='fdtio057.data', access='stream', form='formatted', &
            status='new')

write (10, *, pos=15) base ((/2,3,1/))

write (10, *, pos=25) b1

write (10, *, pos=1) b2

! read (10, *, pos=1) i1(1:3) !<-- 100, 10, 20
! read (10, *, pos=15, iostat=stat) i1(4:6) !<-- 2, 3, 1
! read (10, *, pos=25, iostat=stat) i1(7:8) !<-- -1, -2

! print*, i1
! if (any (i1 /= (/100, 10, 20, 2, 3, 1, -1, -2/))) ERROR STOP 1

! close (10, status='delete')
end

The output file `dtio057.data` contains

100 10 20

When the expected content is 

100 10 20
2 3 1
-1 -2

If I move the `pos=1` write statement to be the first write statement, Flang produces the expected result.

</details>

[klausler]

12.6.2.12 "If the file is connected for formatted stream access, the file position specified by POS= shall be equal to either 1
(the beginning of the file) or a value previously returned by a POS= specifier in an INQUIRE statement for the
file."

[DanielCChen]

@klausler
Right. This issue is indeed in the extension category. It seems Flang has already supported some of it as the first two write statements work as expected. The test case only failed when the 3rd write statement is executed only because it erased the first two write from the file.
XLF preserves the first two write and "inserted" the 3rd write.

[klausler]

character buff(4)*12
open(1, file='t.txt', access='stream', form='formatted', status='replace')
write(1,"(a)",pos=10) 'ABCDEFGH'
write(1,"(a)",pos=19) 'IJKLMNOP'
write(1,"(a)",pos=1)  'abcdefgh'
write(1,"(a)",pos=10) '01234567'
close(1)
open(1, file='t.txt', form='formatted', status='old')
buff=''
read(1,"(a)",end=2) (buff(j),j=1,4)
error stop
2 print "('>',a,'<')", buff
end

avoids the DTIO distraction and demonstrates that although the standards do not say anything about file truncation, most compilers do apply truncation in this case. I will make the truncation of repositioned output streams conditional on an environment variable.