#359 New CallResourceTask for creating tasks that talk to resources

Author: rjrudin

src/main/groovy/com/marklogic/gradle/task/client/CallResourceTask.groovy

@@ -0,0 +1,63 @@
+package com.marklogic.gradle.task.client
+
+import com.marklogic.gradle.task.MarkLogicTask
+import org.gradle.api.tasks.TaskAction
+
+/**
+ * Intended to simplify calling a custom resource - e.g. something under /v1/resources/(resourceName).
+ */
+class CallResourceTask extends MarkLogicTask {
+
+	def params = [:]
+	def method = "GET"
+	def client = newClient()
+	def mimeType = "application/json"
+	String resourceName
+	String body
+	String outputFilePath
+
+	@TaskAction
+	void callResource() {
+		def mgr = new GenericResourceManager()
+		if (resourceName == null || resourceName.trim().length() == 0) {
+			throw new IllegalArgumentException("Must set the value of the 'resourceName' property on this task to the name of the resource to connect to")
+		}
+
+		if (client == null) {
+			client = newClient()
+		}
+
+		client.init(resourceName, mgr)
+		method = method.toUpperCase()
+
+		try {
+			switch (method) {
+				case "GET": handleOutput(mgr.get(params)); break
+				case "POST": handleOutput(mgr.post(params, body, mimeType)); break
+				case "PUT": handleOutput(mgr.put(params, body, mimeType)); break
+				case "DELETE": handleOutput(mgr.delete(params)); break
+				default: throw new IllegalArgumentException("Unsupported method " + method);
+			}
+		} finally {
+			client.release()
+		}
+	}
+
+	def handleOutput(result) {
+		if (outputFilePath) {
+			writeToFile(result)
+		} else {
+			println result
+		}
+	}
+
+	def writeToFile(result) {
+		def file = new File(outputFilePath)
+		if (file.parentFile) {
+			file.parentFile.mkdirs()
+		}
+		file.write result
+		println "Wrote output to " + outputFilePath;
+	}
+
+}

src/main/groovy/com/marklogic/gradle/task/client/GenericResourceManager.groovy

@@ -0,0 +1,32 @@
+package com.marklogic.gradle.task.client
+
+import com.marklogic.client.extensions.ResourceManager
+import com.marklogic.client.io.StringHandle
+import com.marklogic.client.util.RequestParameters
+
+class GenericResourceManager extends ResourceManager {
+
+	def get(Map<String, ?> params) {
+		return services.get(buildRequestParameter(params), new StringHandle()).get();
+	}
+
+	def post(params, body, mimeType) {
+		return services.post(buildRequestParameter(params), new StringHandle(body).withMimetype(mimeType), new StringHandle()).get();
+	}
+
+	def put(params, body, mimeType) {
+		return services.put(buildRequestParameter(params), new StringHandle(body).withMimetype(mimeType), new StringHandle()).get();
+	}
+
+	def delete(params) {
+		return services.delete(buildRequestParameter(params), new StringHandle()).get();
+	}
+
+	def buildRequestParameter(Map<String, ?> params) {
+		def requestParams = new RequestParameters()
+		for (String key : params.keySet()) {
+			requestParams.put(key, params.get(key))
+		}
+		return requestParams
+	}
+}