CLOCKS.HPB

1000 REM - CLOCKS
1020 REM - PEOPLES COMPUTER CENTER, MENLO PARK, CA.
1040 REM - CONCEPT :     BOB ALBRECHT
1060 REM - PROGRAMER:      RAY COOP
1080 REM - THANKS TO PETE SESSIONS AND GREG YOB
1100 REM - **************** 3/5/73************************
1120 PRINT "DO YOU WANT INSTRUCTIONS";
1140 INPUT 1$[1,1]
1160 IF 1$="N" THEN 1620
1180 REM *************INTRO.*******
1200 PRINT "";
1220 PRINT "I'M THINKING OF A TIME BETWEEN 0:01 (1 MIN.AFTER MIDNIGHT)"
1240 PRINT "AND 12:00 NOON. YOUR JOB IS TO TRY TO GUESS THE TIME I'M"
1260 PRINT "THINKING OF."
1280 PRINT
1300 PRINT "AFTER YOU ENTER YOUR GUESS, A SET OF CODE WORDS WILL"
1320 PRINT "TELL YOU HOW FAR YOUR GUESS IS FROM MY TIME."
1340 PRINT
1360 PRINT "CODE WORDS :"
1380 PRINT "     MEGA  - HOURS CORRECT."
1400 PRINT "     KILO  - MINUTES CORRECT."
1420 PRINT "     HECTO - HOURS OFF BY AT MOST + OR -2."
1440 PRINT "     DECA  - MIN. OFF BY AT MOST + OR - 2."
1460 PRINT "     DECI  - HOURS OFF BY AT MOST + OR - 5."
1480 PRINT "     CENTI - MIN. OFF BY AT MOST + OR - 5."
1500 PRINT "     MILLI - MIN. OFF BY AT MOST + OR - 10."
1520 PRINT "     MICRO - MIN. OFF BY AT MOST + OR - 20."
1540 PRINT "     BLA   - COMPLETELY OFF IN HOURS OR MIN."
1560 PRINT
1580 PRINT "  FORMAT : HH:MM OR H:MM ONLY."
1600 PRINT "";
1620 D1=INT(RND(0)*720)+1
1640 D=INT(D1/60)
1660 E=D1-D*60
1680 IF D=12 AND E=1 THEN 1620
1700 PRINT "O.K. I HAVE THOUGHT OF A TIME."
1720 DIM A[4]
1740 MAT Z=ZER
1760 DIM T$[10]
1780 R=M=0
1800 DIM C$[72]
1820 DIM Q$[1]
1840 T$="0123456789"
1860 DIM D$[10]
1880 REM ***************INPUT*********
1900 IF M>0 THEN 1960
1920 T=13
1940 GOTO 1980
1960 T=0
1980 PRINT TAB(T)"     YOUR GUESS";
2000 INPUT C$
2020 R=R+1
2040 M=M+1
2060 REM ***************PARSER*********
2080 LET I=1
2100 LET J=1
2120 D$=""
2140 IF I>LEN(C$) THEN 2280
2160 IF C$[I,I]=" " THEN 2240
2180 IF C$[I,I]=":" THEN 2240
2200 D$[J,J]=C$[I,I]
2220 J=J+1
2240 I=I+1
2260 GOTO 2140
2280 IF LEN(D$)=4 THEN 2360
2300 C$[1,1]="0"
2320 C$[2]=D$
2340 D$=C$
2260 FOR I=1 TO 4
2380 Q$=D$[I,I]
2400 FOR J=1 TO 10
2420 IF Q$#T$[J,J] THEN 2460
2440 A[I]=J-1
2460 NEXT J
2480 NEXT I
2500 REM ***************CONVERTED INPUT TIME*********
2520 A5=10*A[1]+A[2]
2540 A6=10*A[3]+A[4]
2560 REM ****************CODE WORDS********
2580 REM ****************HOURS*************
2600 IF A5=D AND A6=E THEN 3240
2620 IF A5=D THEN 2820
2640 F=ABS(A5-D)
2660 IF F<3 THEN 2780
2680 IF F<6 THEN 2740
2700 PRINT "BLA  ";
2720 GOTO 2860
2740 PRINT "DECI ";
2760 GOTO 2860
2780 PRINT "HECTO";
2800 GOTO 2860
2820 PRINT "MEGA ";
2840 REM ****************MINUTES***********
2860 IF A6=E THEN 3180
2880 F=ABS(A6-E)
2900 IF G<3 THEN 3140
2920 IF G<6 THEN 3100
2940 IF G<11 THEN 3060
2960 IF G<21 THEN 3020
2980 PRINT "   BLA  ";
3000 GOTO 1880
3020 PRINT "   MICRO";
3040 GOTO 1880
3060 PRINT "   MILLI";
3080 GOTO 1880
3100 PRINT "   CENTI";
3120 GOTO 1880
3140 PRINT "   DECA ";
3160 GOTO 1880
3180 PRINT "   KIL0 ";
3200 GOTO 1880
3220 REM ****************HUMAN ELEMENT*********
3240 PRINT "**************  YOU GOT IT!!!!!!!"
3260 IF R=1 THEN 3460
3280 IF R<5 THEN 3400
3300 IF R<10 THEN 3360
3320 PRINT "FINALLY, AFTER";R;" GUESSES YOU GOT IT!"
3340 GOTO 3420
3360 PRINT "   "R;"GUESSES THAT'S ABOUT PAR FOR THE COURSE"
3380 GOTO 3420
3400 PRINT R;"GUESSES: AREN'T WE GETTING GOOD!"
3420 PRINT "TRY TO BETTER YOUR SCORE NEXT TIME .."
3440 GOTO 3600
3460 PRINT "INCREDIBLE, YOU GOT IT IN O N E GUESS, THAT'S A"
3480 PRINT "PERFECT SCORE."
3500 PRINT "WE WOULD LIKE TO TELL YOU THAT: "
3520 PRINT "     THE WORLD IS PROUD OF YOU."
3540 PRINT "     YOUR COUNTRY IS PROUD OF YOU."
3560 PRINT "     DYMAX IS PROUD OF YOU."
3580 PRINT "     AND MOST OF ALL I'M PROUD OF YOU."
3600 PRINT "";
3620 PRINT "ONE MORE TIME";
3640 INPUT Q$
3660 IF Q$="Y" THEN 1620
3680 PRINT "";
3700 PRINT "SEE YOU LATER"
3720 END