Add scala_toolchains macro for WORKSPACE, Bzlmod

Extracted a single `scala_toolchains` macro to share between `WORKSPACE`
and the `deps.bzl` module extension. This will make it easier to ensure
`WORKSPACE` compatibility, and to add a Bazel module extension as a thin
layer on top. Part of bazel-contrib#1482.

This change includes updates to `rules_scala_setup` and
`scala_repositories` to support this, while preserving compatibility
with existing `WORKSPACE` calls. The next commit will replace many
existing `WORKSPACE` calls with `scala_toolchains`.

Author: mbland

jmh/jmh.bzl

@@ -1,4 +1,5 @@
-load("//scala:scala.bzl", "scala_binary", "scala_library")
+load("//scala/private:rules/scala_binary.bzl", "scala_binary")
+load("//scala/private:rules/scala_library.bzl", "scala_library")
 load(
     "//scala:scala_cross_version.bzl",
     "default_maven_server_urls",

scala/private/macros/scala_repositories.bzl

@@ -24,7 +24,6 @@ dt_patched_compiler = repository_rule(
     },
     implementation = _dt_patched_compiler_impl,
 )
-
 _COMPILER_SOURCE_ALIAS_TEMPLATE = """alias(
     name = "src",
     visibility = ["//visibility:public"],
@@ -75,9 +74,13 @@ def dt_patched_compiler_setup(scala_version, scala_compiler_srcjar = None):
 
     if scala_major_version == "2.12":
         if minor_version >= 1 and minor_version <= 7:
-            patch = Label("//dt_patches:dt_compiler_%s.1.patch" % scala_major_version)
+            patch = Label(
+                "//dt_patches:dt_compiler_%s.1.patch" % scala_major_version,
+            )
         elif minor_version <= 11:
-            patch = Label("//dt_patches:dt_compiler_%s.8.patch" % scala_major_version)
+            patch = Label(
+                "//dt_patches:dt_compiler_%s.8.patch" % scala_major_version,
+            )
     elif scala_major_version.startswith("3."):
         patch = Label("//dt_patches:dt_compiler_3.patch")
 
@@ -114,7 +117,9 @@ def dt_patched_compiler_setup(scala_version, scala_compiler_srcjar = None):
             integrity = srcjar.get("integrity"),
         )
 
-def rules_scala_setup(scala_compiler_srcjar = None):
+def rules_scala_setup(
+        scala_compiler_srcjar = None,
+        setup_compiler_sources = True):
     if not native.existing_rule("bazel_skylib"):
         http_archive(
             name = "bazel_skylib",
@@ -167,8 +172,26 @@ def rules_scala_setup(scala_compiler_srcjar = None):
             url = "https://github.com/bazelbuild/rules_proto/releases/download/6.0.2/rules_proto-6.0.2.tar.gz",
         )
 
+    if setup_compiler_sources:
+        srcs = {version: scala_compiler_srcjar for version in SCALA_VERSIONS}
+        _setup_scala_compiler_sources(srcs)
+
+def _setup_scala_compiler_sources(srcjars = {}):
+    """Generates Scala compiler source repos used internally by rules_scala.
+
+    Args:
+        srcjars: optional dictionary of Scala version string to compiler srcjar
+            metadata dictionaries containing:
+            - exactly one "label", "url", or "urls" key
+            - optional "integrity" or "sha256" keys
+    """
     for scala_version in SCALA_VERSIONS:
-        dt_patched_compiler_setup(scala_version, scala_compiler_srcjar)
+        dt_patched_compiler_setup(scala_version, srcjars.get(scala_version))
+
+    compiler_sources_repo(
+        name = "scala_compiler_sources",
+        scala_versions = SCALA_VERSIONS,
+    )
 
     compiler_sources_repo(
         name = "scala_compiler_sources",
@@ -235,13 +258,19 @@ def scala_repositories(
         overriden_artifacts = {},
         load_dep_rules = True,
         load_jar_deps = True,
-        fetch_sources = False):
+        fetch_sources = False,
+        validate_scala_version = True,
+        scala_compiler_srcjars = {}):
     if load_dep_rules:
-        rules_scala_setup()
+        # When `WORKSPACE` goes away, so can this case.
+        rules_scala_setup(setup_compiler_sources = False)
+
+    _setup_scala_compiler_sources(scala_compiler_srcjars)
 
     if load_jar_deps:
         rules_scala_toolchain_deps_repositories(
             maven_servers,
             overriden_artifacts,
             fetch_sources,
+            validate_scala_version,
         )

scala/private/macros/toolchains.bzl

@@ -0,0 +1,75 @@
+"""Macro to instantiate @io_bazel_rules_scala_toolchains"""
+
+load(":macros/toolchains_repo.bzl", "scala_toolchains_repo")
+load("//scala/private:macros/scala_repositories.bzl", "scala_repositories")
+load("//scala:scala_cross_version.bzl", "default_maven_server_urls")
+
+def scala_toolchains(
+        maven_servers = default_maven_server_urls(),
+        overridden_artifacts = {},
+        load_rules_scala_dependencies = True,
+        load_scala_toolchain_dependencies = True,
+        fetch_sources = False,
+        validate_scala_version = True,
+        scala_compiler_srcjars = {},
+        scala = True):
+    """Instantiates @io_bazel_rules_scala_toolchains and all its dependencies.
+
+    Provides a unified interface to configuring rules_scala both directly in a
+    `WORKSPACE` file and in a Bazel module extension.
+
+    Instantiates the `@io_bazel_rules_scala_toolchains` repository. Under
+    `WORKSPACE`, you will need to call `register_toolchains` at some point.
+    Under Bzlmod, rules_scala does this automatically.
+
+    ```starlark
+    register_toolchains("@io_bazel_rules_scala_toolchains//...:all")
+    ```
+
+    All arguments are optional.
+
+    Args:
+        maven_servers: Maven servers used to fetch dependency jar files
+        overridden_artifacts: specific dependency jar files to use instead of
+            those from `maven_servers`, in the format:
+            ```starlark
+            "repo_name": {
+                "artifact": "<maven coordinates>",
+                "sha256": "<checksum>",
+                "deps": [
+                    "repository_names_of_dependencies",
+                ],
+            }
+            ```
+        load_rules_scala_dependencies: whether load rules_scala repository
+            dependencies
+        load_scala_toolchain_dependencies: whether to load repository
+            dependencies of the core Scala language toolchain
+        fetch_sources: whether to download dependency source jars
+        validate_scala_version: whether to check if the configured Scala version
+            matches the default version supported by rules_scala
+        scala_compiler_srcjars: optional dictionary of Scala version string to
+            compiler srcjar metadata dictionaries containing:
+            - exactly one "label", "url", or "urls" key
+            - optional "integrity" or "sha256" keys
+        scala: whether to instantiate the core Scala toolchain
+    """
+    num_toolchains = 0
+
+    if scala:
+        num_toolchains += 1
+        scala_repositories(
+            maven_servers = maven_servers,
+            # Note the internal macro parameter misspells "overriden".
+            overriden_artifacts = overridden_artifacts,
+            load_dep_rules = load_rules_scala_dependencies,
+            load_jar_deps = load_scala_toolchain_dependencies,
+            fetch_sources = fetch_sources,
+            validate_scala_version = validate_scala_version,
+            scala_compiler_srcjars = scala_compiler_srcjars,
+        )
+
+    if num_toolchains != 0:
+        scala_toolchains_repo(
+            scala = scala,
+        )

scala/private/extensions/toolchains.bzl renamed to scala/private/macros/toolchains_repo.bzl

@@ -1,4 +1,4 @@
-"""Creates a repo containing Scala toolchain packages"""
+"""Repository rule to instantiate @io_bazel_rules_scala_toolchains"""
 
 def _scala_toolchains_repo_impl(repository_ctx):
     repo_attr = repository_ctx.attr

scala/scala.bzl

@@ -3,7 +3,11 @@ load(
     _specs2_junit_dependencies = "specs2_junit_dependencies",
 )
 load(
-    "//scala/private/extensions:toolchains.bzl",
+    "//scala/private:macros/toolchains.bzl",
+    _scala_toolchains = "scala_toolchains",
+)
+load(
+    "//scala/private:macros/toolchains_repo.bzl",
     _scala_toolchains_repo = "scala_toolchains_repo",
 )
 load(
@@ -85,4 +89,5 @@ scala_test = _scala_test
 scala_test_suite = _scala_test_suite
 setup_scala_testing_toolchain = _setup_scala_testing_toolchain
 setup_scala_toolchain = _setup_scala_toolchain
+scala_toolchains = _scala_toolchains
 scala_toolchains_repo = _scala_toolchains_repo