LithicRivers/justfile.windows at release · meltingscales/LithicRivers · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
# Windows-specific justfile for LithicRivers
# Focused on core build and run functionality

# Set shell to use PowerShell
set shell := ["powershell.exe", "-NoProfile", "-Command"]

# Default toolchain (can be overridden)
toolchain := "stable"

# CPU count (PowerShell environment reference)
cpu_count := "$env:NUMBER_OF_PROCESSORS"

git-data:
    powershell.exe scripts/git-data.ps1

copy-config-data:
    powershell.exe scripts/copy-config-data.ps1

# remove artifacts/ folder but NOT cargo cache or target/ folder.
clean:
    powershell.exe scripts/clean.ps1

# Build in debug mode (default)
build: git-data copy-config-data
    cargo build --workspace -j {{cpu_count}}


stage-artifacts-legal:
    New-Item -ItemType Directory -Path artifacts
    Copy-Item -Path CHANGELOG.txt -Destination artifacts/
    Copy-Item -Path LICENSE -Destination artifacts/
    Copy-Item -Path THIRD-PARTY-NOTICES.txt -Destination artifacts/

stage-artifacts: clean build build-demos stage-artifacts-legal
    powershell.exe scripts/stage-artifacts.ps1

build-release: git-data copy-config-data build-demos-release
    cargo build --workspace --release -j {{cpu_count}}

stage-artifacts-release: clean build-release build-demos-release stage-artifacts-legal
    powershell.exe scripts/stage-artifacts-release.ps1

build-demos:
    cargo build -p lithicrivers-client --bin demo_inventory
    cargo build -p lithicrivers-client --bin demo_crafting
    cargo build -p lithicrivers-client --bin demo_body
    cargo build -p lithicrivers-client --bin demo_beezzaroll_color_test
    cargo build -p lithicrivers-client --bin demo_beezzaroll_sprite_test
    cargo build -p lithicrivers-client --bin demo_portrait_sprite_test
    cargo build -p lithicrivers-client --bin demo_combat_chrono_trigger

build-demos-release:
    cargo build -p lithicrivers-client --bin demo_inventory --release
    cargo build -p lithicrivers-client --bin demo_crafting --release
    cargo build -p lithicrivers-client --bin demo_body --release
    cargo build -p lithicrivers-client --bin demo_beezzaroll_color_test --release
    cargo build -p lithicrivers-client --bin demo_beezzaroll_sprite_test --release
    cargo build -p lithicrivers-client --bin demo_portrait_sprite_test --release
    cargo build -p lithicrivers-client --bin demo_combat_chrono_trigger --release

# Run debug build
client: build
    cargo run -p lithicrivers-client --bin lithicrivers-client -j {{cpu_count}}

# Run release build
client-release: build-release
    cargo run --release -p lithicrivers-client --bin lithicrivers-client -j {{cpu_count}}

test: build
    cargo test --workspace -j {{cpu_count}}

test-release: build-release
    cargo test --workspace -j {{cpu_count}} --release

# Install Rust toolchain
install:
    rustup toolchain install stable
    rustup default stable
    rustup target add wasm32-unknown-unknown