louvain-communities-dynamic--plots/insertions-runtime-all.plt at main · merferry/louvain-communities-dynamic--plots · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
set term pdf
set terminal pdf size 10in,6in font ",20"
set output 'insertions-runtime-all.pdf'


## Set global styles
set termoption dashed
set datafile separator ','
set title noenhanced
set style fill solid border lt -1
set style textbox opaque noborder
set lmargin 4.5
set tmargin 1
unset xtics
set logscale x 10
set logscale y 10
set format x "10^{%L}"
set grid   y
set key off
set multiplot layout 3,4 margins 0.07,0.98,0.10,0.95 spacing 0.06,0.07
# set xlabel  'Batch fraction'
# set ylabel  'Runtime (s)'


## Set line styles
set style line  1 linewidth 2 linetype 6 pointtype 5 dashtype 1
set style line  2 linewidth 2 linetype 7 pointtype 9 dashtype 1
set style line  3 linewidth 2 linetype 2 pointtype 2 dashtype 1
set style line  4 linewidth 2 linetype 8 pointtype 3 dashtype 1


## Draw plot
set label "Runtime (s)" at screen 0.01,0.5 center rotate font ",18"
set label "Batch fraction" at screen 0.5,0.02 center font ",18"
files='indochina-2004 arabic-2005 uk-2005 webbase-2001 it-2004 sk-2005 com-LiveJournal com-Orkut asia_osm europe_osm kmer_A2a kmer_V1r'
do for [i=1:words(files)] {
set title word(files, i) offset 0,-0.8
if (i>=9) { set xtics rotate by 45 right }
plot 'insertions/'.word(files, i).'.csv' \
       using 4:($5 /1000) title 'Static'            linestyle 1 with linespoints, \
    '' using 4:($6 /1000) title 'Naive-dynamic'     linestyle 2 with linespoints, \
    '' using 4:($7 /1000) title 'Delta-screening'   linestyle 3 with linespoints, \
    '' using 4:($8 /1000) title 'Dynamic Frontier'  linestyle 4 with linespoints
}
unset multiplot


## Names of CSV files.
# 01. indochina-2004
# 02. arabic-2005
# 03. uk-2005
# 04. webbase-2001
# 05. it-2004
# 06. sk-2005
# 07. com-LiveJournal
# 08. com-Orkut
# 09. asia_osm
# 10. europe_osm
# 11. kmer_A2a
# 12. kmer_V1r


## Columns in CSV file.
# 01. graph
# 02. batch_deletions_fraction
# 03. batch_insertions_fraction
# 04. batch_fraction
# 05. lousta-t
# 06. lounai-t
# 07. loudel-t
# 08. loufro-t
# 09. lousta-m
# 10. lounai-m
# 11. loudel-m
# 12. loufro-m