Add Apache Avro wrap

Author: stephanlachnit

releases.json

@@ -232,6 +232,17 @@
       "0.4.1-1"
     ]
   },
+  "avro-cpp": {
+    "dependency_names": [
+      "avro-cpp"
+    ],
+    "program_names": [
+      "avrogencpp"
+    ],
+    "versions": [
+      "557891c38c6c90eeaa43f1cb78ae8c3ae088009f-1"
+    ]
+  },
   "backward-cpp": {
     "dependency_names": [
       "backward-cpp",

subprojects/avro-cpp.wrap

@@ -0,0 +1,10 @@
+[wrap-file]
+directory = avro-557891c38c6c90eeaa43f1cb78ae8c3ae088009f
+source_url = https://github.com/apache/avro/archive/557891c38c6c90eeaa43f1cb78ae8c3ae088009f.tar.gz
+source_filename = avro-557891c38c6c90eeaa43f1cb78ae8c3ae088009f.tar.gz
+source_hash = c75198e925c95719cdb8346445fc4571f0101ed31f6a422ccf831dc52ffc4987
+patch_directory = avro-cpp
+
+[provide]
+dependency_names = avro-cpp
+program_names = avrogencpp

subprojects/packagefiles/avro-cpp/lang/c++/meson.build

@@ -0,0 +1,107 @@
+avro_flags = []
+avro_deps = []
+avro_public_deps = []
+
+fmt_dep = dependency(
+  'fmt',
+  required: true,
+)
+avro_deps += fmt_dep
+avro_public_deps += fmt_dep
+
+zlib_dep = dependency(
+  'zlib',
+  required: true,
+)
+avro_deps += zlib_dep
+
+snappy_dep = dependency(
+  'snappy',
+  required: false,
+)
+if snappy_dep.found()
+  avro_flags += '-DSNAPPY_CODEC_AVAILABLE'
+  avro_deps += snappy_dep
+endif
+
+zstd_dep = dependency(
+  'libzstd',
+  required: false,
+)
+if zstd_dep.found()
+  avro_flags += '-DZSTD_CODEC_AVAILABLE'
+  avro_deps += zstd_dep
+endif
+
+# Set static and shared flags manually since Meson 1.3.0 is still too new
+avro_flags += '-DAVRO_SOURCE'
+if get_option('default_library') == 'shared'
+  avro_flags += '-DAVRO_DYN_LINK'
+elif get_option('default_library') == 'both'
+  error('Building both static and shared libraries is not possible')
+endif
+
+avro_inc = include_directories('include/avro')
+
+avro_src = files(
+  'impl/BinaryDecoder.cc',
+  'impl/BinaryEncoder.cc',
+  'impl/Compiler.cc',
+  'impl/CustomAttributes.cc',
+  'impl/DataFile.cc',
+  'impl/FileStream.cc',
+  'impl/Generic.cc',
+  'impl/GenericDatum.cc',
+  'impl/LogicalType.cc',
+  'impl/Node.cc',
+  'impl/NodeImpl.cc',
+  'impl/Resolver.cc',
+  'impl/ResolverSchema.cc',
+  'impl/Schema.cc',
+  'impl/Stream.cc',
+  'impl/Types.cc',
+  'impl/ValidSchema.cc',
+  'impl/Validator.cc',
+  'impl/Zigzag.cc',
+  'impl/json/JsonDom.cc',
+  'impl/json/JsonIO.cc',
+  'impl/parsing/JsonCodec.cc',
+  'impl/parsing/ResolvingDecoder.cc',
+  'impl/parsing/Symbol.cc',
+  'impl/parsing/ValidatingCodec.cc',
+)
+
+avro_lib = library(
+  'avrocpp',
+  sources: avro_src,
+  include_directories: avro_inc,
+  cpp_args: avro_flags,
+  dependencies: avro_deps,
+  version: meson.project_version(),
+  install: true,
+)
+
+install_subdir(
+  'include/avro',
+  install_dir: get_option('includedir'),
+  install_tag: 'devel',
+)
+
+avro_dep = declare_dependency(
+  include_directories: avro_inc,
+  link_with: avro_lib,
+  dependencies: avro_public_deps,
+)
+meson.override_dependency('avro-cpp', avro_dep)
+
+if get_option('build_executable')
+  avrogencpp_exe = executable(
+    'avrogencpp',
+    sources: ['impl/avrogencpp.cc'],
+    cpp_args: ['-DAVRO_VERSION="@0@"'.format(meson.project_version())],
+    dependencies: avro_dep,
+    install: true,
+    install_tag: 'devel',
+  )
+  meson.override_find_program('avrogencpp', avrogencpp_exe)
+endif

subprojects/packagefiles/avro-cpp/meson.build

@@ -0,0 +1,9 @@
+project(
+  'avro-cpp',
+  'cpp',
+  version: 'undefined',
+  license: 'Apache-2.0',
+  default_options: ['cpp_std=c++17'],
+)
+
+subdir('lang/c++')

subprojects/packagefiles/avro-cpp/meson_options.txt

@@ -0,0 +1,6 @@
+option(
+    'build_executable',
+    type: 'boolean',
+    value: true,
+    description: 'Build avrogencpp exectuable',
+)