Use memref.reinterpret_cast to cast tptr.to_memref output to dynamic memref (#313)

In the current implementation, we use memref.cast to cast the statically
shaped output of tptr.to_memref to a dynamic memref. However, the cast
from static to dynamic memref is considered a noop by the Mlir
canonicalizer. This PR updates the ReconcilePtrCastsPass to use
memref.reinterpret_cast instead, which will not be removed by the
canonicalizer.

Here's an example showing that the canonicalizer removing the
memref.cast:
Input:
```mlir
func.func @check_cast_canonicalizer(%arg: memref<32xi64>, %index: index) -> bf16 {
    %ptr = tptr.from_memref %arg : memref<32xi64> to <#tptr.default_memory_space>
    %memref = tptr.to_memref %ptr : <#tptr.default_memory_space> to memref<1xbf16>
    %cast = memref.cast %memref : memref<1xbf16> to memref<?xbf16>
    %load = memref.load %cast[%index] : memref<?xbf16>
    return %load : bf16
}

func.func @check_reinterpret_cast_canonicalizer(%arg: memref<32xi64>, %index: index) -> bf16 {
    %ptr = tptr.from_memref %arg : memref<32xi64> to <#tptr.default_memory_space>
    %memref = tptr.to_memref %ptr : <#tptr.default_memory_space> to memref<1xbf16>
    %reinterpret_cast = memref.reinterpret_cast %memref to offset: [0], sizes: [1], strides: [1] : memref<1xbf16> to memref<?xbf16>
    %load = memref.load %reinterpret_cast[%index] : memref<?xbf16>
    return %load : bf16
}
```
`--canonicalize` output:
```mlir
module {
  func.func @check_cast_canonicalizer(%arg0: memref<32xi64>, %arg1: index) -> bf16 {
    %0 = tptr.from_memref %arg0 : memref<32xi64> to <#tptr.default_memory_space>
    %1 = tptr.to_memref %0 : <#tptr.default_memory_space> to memref<1xbf16>
    // note that the memref.cast is removed here
    %2 = memref.load %1[%arg1] : memref<1xbf16>
    return %2 : bf16
  }
  func.func @check_reinterpret_cast_canonicalizer(%arg0: memref<32xi64>, %arg1: index) -> bf16 {
    %0 = tptr.from_memref %arg0 : memref<32xi64> to <#tptr.default_memory_space>
    %1 = tptr.to_memref %0 : <#tptr.default_memory_space> to memref<1xbf16>
    %reinterpret_cast = memref.reinterpret_cast %1 to offset: [0], sizes: [1], strides: [1] : memref<1xbf16> to memref<?xbf16>
    %2 = memref.load %reinterpret_cast[%arg1] : memref<?xbf16>
    return %2 : bf16
  }
}
```

Author: ShujianQian

lib/Conversion/TritonToLinalgExperimental/ReconcilePtrCastsPass.cpp

@@ -131,9 +131,11 @@ struct ToMemrefConverter : public OpRewritePattern<UnrealizedConversionCastOp> {
       auto ptrToMemref = rewriter.create<tptr::ToMemrefOp>(
           op->getLoc(), MemRefType::get({1}, elemType), input);
 
-      auto newUnrankedMemref = rewriter.create<memref::CastOp>(
-          op.getLoc(), MemRefType::get({ShapedType::kDynamic}, elemType),
-          ptrToMemref);
+      SmallVector<OpFoldResult> sizes = {rewriter.getIndexAttr(1)};
+      SmallVector<OpFoldResult> newStrides = {rewriter.getIndexAttr(1)};
+      auto newUnrankedMemref = rewriter.create<memref::ReinterpretCastOp>(
+          op->getLoc(), MemRefType::get({ShapedType::kDynamic}, elemType),
+          ptrToMemref, rewriter.getIndexAttr(0), sizes, newStrides);
 
       rewriter.replaceAllUsesWith(output, newUnrankedMemref);
       rewriter.eraseOp(op);