feat: add encrypt

Author: trueChazza

lib/web_push_elixir.ex

@@ -1,13 +1,79 @@
 defmodule WebPushElixir do
   require Logger
 
+  @auth_info "Content-Encoding: auth" <> <<0>>
+  @one_buffer <<1>>
+
   def gen_keypair do
     {public, private} = :crypto.generate_key(:ecdh, :prime256v1)
 
     fn ->
       Logger.info(%{:public_key => Base.url_encode64(public, padding: false)})
       Logger.info(%{:private_key => Base.url_encode64(private, padding: false)})
+
       Logger.info(%{:subject => "mailto:[email protected]"})
     end
   end
+
+  def encrypt(message, subscription) do
+    client_public_key = Base.url_decode64!(subscription.keys.p256dh, padding: false)
+    client_auth_secret = Base.url_decode64!(subscription.keys.auth, padding: false)
+
+    salt = :crypto.strong_rand_bytes(16)
+
+    {server_public_key, server_private_key} = :crypto.generate_key(:ecdh, :prime256v1)
+
+    shared_secret = :crypto.compute_key(:ecdh, client_public_key, server_private_key, :prime256v1)
+
+    prk = hkdf(client_auth_secret, shared_secret, @auth_info, 32)
+
+    context = create_context(client_public_key, server_public_key)
+
+    content_encryption_key_info = create_info("aesgcm", context)
+    content_encryption_key = hkdf(salt, prk, content_encryption_key_info, 16)
+
+    nonce_info = create_info("nonce", context)
+    nonce = hkdf(salt, prk, nonce_info, 12)
+
+    ciphertext = encrypt_payload(message, content_encryption_key, nonce)
+
+    %{ciphertext: ciphertext, salt: salt, server_public_key: server_public_key}
+  end
+
+  defp hkdf(salt, ikm, info, length) do
+    prk =
+      :crypto.mac_init(:hmac, :sha256, salt)
+      |> :crypto.mac_update(ikm)
+      |> :crypto.mac_final()
+
+    :crypto.mac_init(:hmac, :sha256, prk)
+    |> :crypto.mac_update(info)
+    |> :crypto.mac_update(@one_buffer)
+    |> :crypto.mac_final()
+    |> :binary.part(0, length)
+  end
+
+  defp create_context(client_public_key, server_public_key) do
+    <<0, byte_size(client_public_key)::unsigned-big-integer-size(16)>> <>
+      client_public_key <>
+      <<byte_size(server_public_key)::unsigned-big-integer-size(16)>> <> server_public_key
+  end
+
+  defp create_info(type, context) do
+    "Content-Encoding: " <> type <> <<0>> <> "P-256" <> context
+  end
+
+  defp encrypt_payload(plaintext, content_encryption_key, nonce) do
+    {cipher_text, cipher_tag} =
+      :crypto.crypto_one_time_aead(
+        :aes_128_gcm,
+        content_encryption_key,
+        nonce,
+        plaintext,
+        "",
+        true
+      )
+
+    cipher_text <> cipher_tag
+  end
 end

test/web_push_elixir_test.exs

@@ -3,10 +3,37 @@ defmodule WebPushElixirTest do
 
   import ExUnit.CaptureLog
 
+  @subscription_from_client '{"endpoint":"https://some.pushservice.com/something-unique","keys":{"p256dh":"BIPUL12DLfytvTajnryr2PRdAgXS3HGKiLqndGcJGabyhHheJYlNGCeXl1dn18gSJ1WAkAPIxr4gK0_dQds4yiI=","auth":"FPssNDTKnInHVndSTdbKFw=="}}'
+  @subscription_decoded %{
+    endpoint: "https://some.pushservice.com/something-unique",
+    keys: %{
+      auth: "FPssNDTKnInHVndSTdbKFw==",
+      p256dh:
+        "BIPUL12DLfytvTajnryr2PRdAgXS3HGKiLqndGcJGabyhHheJYlNGCeXl1dn18gSJ1WAkAPIxr4gK0_dQds4yiI="
+    }
+  }
+
+  @salt_length 16
+  @server_public_key_length 65
+
   test "it should gen keypair" do
     assert capture_log(WebPushElixir.gen_keypair()) =~ "public_key:"
     assert capture_log(WebPushElixir.gen_keypair()) =~ "private_key:"
     assert capture_log(WebPushElixir.gen_keypair()) =~ "subject:"
     assert capture_log(WebPushElixir.gen_keypair()) =~ "mailto:[email protected]"
   end
+
+  test "it should decode" do
+    assert Jason.decode!(@subscription_from_client, keys: :atoms) == @subscription_decoded
+  end
+
+  test "it should encrypt" do
+    response = WebPushElixir.encrypt("some message", @subscription_decoded)
+
+    assert is_binary(response.ciphertext)
+    assert is_binary(response.salt)
+    assert byte_size(response.salt) == @salt_length
+    assert is_binary(response.server_public_key)
+    assert byte_size(response.server_public_key) == @server_public_key_length
+  end
 end