smoke-tests/minder-tests/api-datasources.robot at 8aaa5983888bddb7755c2edeb857ff56eab52e2b · mindersec/smoke-tests · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
*** Settings ***
Documentation       Test suite for the Minder data sources REST API

Resource   resources/keywords.robot
Library    resources.datasources.DataSources

Suite Setup    Load Config

Test Setup    Default Setup
Test Teardown    Default Teardown

*** Keywords ***
Default Setup
    Set Project as Environment Variable with Test Name

Default Teardown
    Remove Project Environment Variable for Test

*** Test Cases ***
Test the List Data Sources API
    [Documentation]    Test that we can list data sources

    ${data_sources}=    When Client lists data sources
    Then data sources are empty    ${data_sources}

    [Teardown]    Run Keywords   Default Teardown

Test the Create Data Source API
    [Documentation]    Test that we can create a data source

    Given Client adds a data source    test-data-source
    ${data_sources}=    When Client lists data sources
    Then data sources are not empty    ${data_sources}

    [Teardown]    Run Keywords    Cleanup Minder Data Sources
    ...           AND    Default Teardown

Test the Update Data Source API
    [Documentation]    Test that we can modify an existing data source

    Given Client adds a data source    test-data-source
    Given Client updates a data source    test-data-source
    ${data_sources}=    When Client lists data sources
    Then data sources are not empty    ${data_sources}

    [Teardown]    Run Keywords    Cleanup Minder Data Sources
    ...           AND    Default Teardown