Create source package information file

Add source-info.bbclass to create a JSON file which contains source package
information. This JSON file contains the following attributes:

- source_package_name
- source_from

The source_package_name attribute is automatically set from the ${PN} variable.
The source_from attribute is read from the ${EMLINUX_SOURCE_FROM} variable,
which should be defined in your recipe. For example, if the source code is
not a Debian source package, set it to "non-debian":

```
EMLINUX_SOURCE_FROM="non-debian"
```

Another example: if the DISTRO variable is "emlinux-bookworm" and the source code
is fetched from Debian Trixie, define the EMLINUX_SOURCE_FROM variable like this:

```
EMLINUX_SOURCE_FROM="trixie"
```

The source package information JSON file looks like the following format:

```
    "emlinux-customization": {
        "source_package_name": "emlinux-customization",
        "source_from": "non-debian",
    }
```

This JSON file is stored in the build/tmp/deploy/images/<MACHINE>/ directory.
The file name is all-source-info.json.

Signed-off-by: Masami Ichikawa <masami.ichikawa@miraclelinux.com>

Author: masami256

classes/source-info.bbclass

@@ -0,0 +1,51 @@
+
+python do_collect_source_info() {
+    import json
+
+    log_file = f"{d.getVar('T')}/source-info.json"
+
+    source_info = d.getVar("EMLINUX_SOURCE_FROM")
+    if source_info is None:
+        distro = d.getVar("DISTRO").split("-")[1]
+        source_info = distro
+
+    data = {
+        "source_package_name": d.getVar("PN"),
+        "source_from": source_info,
+    }
+
+    with open(log_file, "w") as f:
+        json.dump(data, f, indent=4)
+}
+
+python do_merge_source_info() {
+    import glob
+    import json
+
+    distro = d.getVar("DISTRO")
+    distro_arch = d.getVar("DISTRO_ARCH")
+
+    tmpdir = d.getVar("TMPDIR")
+
+    basepath = f"{tmpdir}/work/{distro}-{distro_arch}"
+    search_path = f"{basepath}/*/*/temp/source-info.json"
+
+    source_info = {}
+
+    for file in glob.glob(search_path):
+        with open(file) as f:
+            data = json.load(f)
+            pkg = data["source_package_name"]
+            source_info[pkg] = data
+
+    source_info = dict(sorted(source_info.items(), key=lambda x: x[0], reverse=False))
+
+    source_info_file = d.getVar("DEPLOY_DIR_IMAGE") + "/all-source-info.json"
+
+    with open(source_info_file, "w") as f:
+        json.dump(source_info, f, indent=4)
+
+}
+
+addtask collect_source_info after do_dpkg_source before do_dpkg_build
+addtask merge_source_info after do_image before do_deploy

conf/distro/emlinux-common.inc

@@ -11,7 +11,7 @@
 
 require include/security_flags.inc
 
-INHERIT += "sdk-installer"
+INHERIT += "sdk-installer source-info"
 
 DISTRO_KERNELS ?= "linux-cip"
 KERNEL_NAME ?= "cip"

recipes-core/emlinux-customization/emlinux-customization.bb

@@ -10,8 +10,9 @@
 #
 FILESEXTRAPATHS:prepend := "${FILE_DIRNAME}/files:"
 
+EMLINUX_SOURCE_FROM="non-debian"
 DESCRIPTION = "EMLinux 3.x specific customization"
-
+LICENSE = "MIT"
 DEBIAN_DEPENDS = "netbase"
 
 inherit dpkg-raw
@@ -26,4 +27,3 @@ do_install:append() {
         echo "PS1=\"${EMLINUX_ENVIRONMENT_VARIABLE_PS1}\"" > "${D}/etc/profile.d/ps1.sh"
     fi
 }
-

recipes-kernel/linux/includes/linux-cip-common.inc

@@ -17,3 +17,5 @@ SRC_URI[sha256sum] = "1caa1b8e24bcfdd55c3cffd8f147f3d33282312989d85c82fc1bc39b80
 KBUILD_DEPENDS:append = ", zstd"
 
 LIBSSL_DEP:armhf:trixie = "libssl3t64"
+
+EMLINUX_SOURCE_FROM="non-debian"