bdx: Add a command to find symbol definition

* bdx.el (bdx-find-definition): New command.
* bdx-test.el (bdx-find-definition): New test.

Author: mkcms

bdx-test.el

@@ -475,6 +475,33 @@ int quux(int x) { return x+1; }
       (goto-char (point-min))
       (should (re-search-forward "<foo>:")))))
 
+(ert-deftest bdx-find-definition ()
+  (bdx-test--with-files
+      `(("foo.c" "
+int foo() { return 128; }
+int quux(int x) { return x+1; }
+" :args ("-c" "-g"))
+        ("bar.c" "
+int bar(int x) { return x+1; }
+int baz(int x) { return x+1; }
+" :args ("-c" "-g")))
+    (bdx-test--index)
+
+    (pcase-let ((`(,file . ,line)
+                 (bdx-find-definition
+                  (car (bdx--search "name:quux" :limit 1)))))
+      (should (stringp file))
+      (find-file file)
+      (should (numberp line))
+      (should (looking-at-p "int quux")))
+    (pcase-let ((`(,file . ,line)
+                 (bdx-find-definition
+                  (car (bdx--search "name:baz" :limit 1)))))
+      (should (stringp file))
+      (find-file file)
+      (should (numberp line))
+      (should (looking-at-p "int baz")))))
+
 (ert-deftest bdx-generate-graph ()
   (bdx-test--with-files
       '(("foo.c" "

bdx.el

@@ -740,6 +740,44 @@ to the length of `bdx-disassembly-stack'."
   :lighter " bdx"
   :keymap bdx-disassembly-mode-map)
 
+
+;; Find definition
+
+(defun bdx-find-definition (symbol-plist)
+  "Find file containing definition of SYMBOL-PLIST and go to definition line.
+The return value is a cons (FILE . LINE)."
+  (interactive (list (bdx-query "Find definition: "
+                                :require-match t)))
+  (pcase-let (((map :name :demangled :path :section) symbol-plist))
+    (let ((command
+           (apply #'bdx--command "find-definition"
+                  (append (list "-n" "1")
+                          (list
+                           (and name (format "fullname:\"%s\"" name))
+                           (and demangled
+                                (format "demangled:\"%s\"" demangled))
+                           (and path (format "path:\"%s\"" path))
+                           (and section
+                                (format "section:\"%s\"" section))))))
+          file line sym)
+      (with-temp-buffer
+        (apply #'call-process (car command)
+               nil (current-buffer) nil (cdr command))
+
+        (goto-char (point-min))
+        (if (looking-at "^\\(.*\\):\\([0-9]+\\): \\(.*\\)")
+            (setq file (match-string 1)
+                  line (string-to-number (match-string 2))
+                  sym (match-string 3))
+          (error "No definition found")))
+      (when (equal sym name)
+        (with-current-buffer (find-file-noselect file)
+          (goto-char (point-min))
+          (forward-line (1- line))
+          (pop-to-buffer (current-buffer))
+          (pulse-momentary-highlight-one-line)
+          (cons file line))))))
+
 
 ;; Graphs