Decoding JSONB to Aeson.Value

[magthe]

I have a query with the following type

sql :: Query '[] with MySchema '[ 'NotNull 'PGint4] '["id" ::: 'NotNull 'PGint4, "vals" ::: 'NotNull 'PGjsonb]

that I then want to turn into a Statement

getValues :: Statement MySchema Int32 (Int32, Aeson.Value)
getValues = Query encode decode sql
  where
    encode = (\x -> x) .* nilParams
    decode = (,) <$> #id <*> #vals

This gives me the following error though

* Couldn't match type `PGjsonb' with `PGjson'
    arising from the overloaded label `#vals'
* In the second argument of `(<*>)', namely `#vals'
  In the expression: (,) <$> #id <*> #vals
  In an equation for `decode': decode = (,) <$> #id <*> #vals

which confuses me. The schema says the field is PGjsonb, the query typechecks and the value is PGjsonb, so where does PGjson come in? How do I convert a PGjsonb field to an Aeson.Value? I'm clearly missing something here, but what?

[magthe]

I posted the same question on the Haskell discourse too.

[magthe]

Based on some suggestions on the discourse, and a bit of stubbornness on my side (it just didn't feel like using JSONB should require writing my own newtype wrappers, it ought to have support in squeal already) I came up with this modified definition of getValues:

getValues :: Statement MySchema Int32 (Int32, Aeson.Value)
getValues = Query encode decode sql
  where
    encode = (\x -> x) .* nilParams
    decode = mkResult <$> #id <*> #vals
    mkResult id_ vals = (id_, getJsonb vals)

Is that a good way to solve it, or is there a more idiomatic way?

[echatav]

Yes that's right. The way you specify that you're storing an Aeson.Value as a jsonb is to wrap it with Jsonb, which means you need to unwrap it with getJsonb.

getValues :: Statement MySchema Int32 (Int32, Aeson.Value)
getValues = Query encode decode sql
  where
    encode = aParam
    decode = (,) <$> #id <*> (getJsonb <$> #vals)

By the way, the reason Squeal was looking for a PGjson instead of a PGjsonb is that PG Aeson.Value ~ PGjson. By default Squeal assumes that an Aeson.Value will be stored as json. That's why you need to wrap it in a Jsonb because PG (Jsonb Aeson.Value) ~ PGjsonb. In general, you can wrap any Haskell type with Jsonb and as long as it has Aeson instances, it can be decoded/encoded to JSONB.