feat: destroy_account_from function to decommission core resources account

Author: andygolay

aptos-move/framework/aptos-framework/sources/account.move

@@ -240,6 +240,28 @@ module aptos_framework::account {
         new_account
     }
 
+    /// Destroy the Account resource from a given account.
+    /// Used to destroy the core resources account on mainnet.
+    public fun destroy_account_from(account: &signer, from: address) acquires Account {
+        system_addresses::assert_aptos_framework(account);
+
+        let Account {
+            authentication_key: _,
+            sequence_number: _,
+            guid_creation_num: _,
+            coin_register_events,
+            key_rotation_events,
+            rotation_capability_offer,
+            signer_capability_offer,
+        } = move_from<Account>(from);
+
+        event::destroy_event_handle(account, coin_register_events);
+        event::destroy_event_handle(account, key_rotation_events);
+
+        let CapabilityOffer { for: _ } = rotation_capability_offer;
+        let CapabilityOffer { for: _ } = signer_capability_offer;
+    }
+
     #[view]
     public fun exists_at(addr: address): bool {
         exists<Account>(addr)
@@ -953,6 +975,26 @@ module aptos_framework::account {
         );
     }
 
+    #[test(aptos_framework = @aptos_framework, from = @0xdead)]
+    public entry fun test_destroy_account_from(
+        aptos_framework: &signer,
+        from: &signer,
+    ) acquires Account {
+        // Ensure the Account resource exists under the from account
+        if (!exists<Account>(signer::address_of(from))) {
+            create_account(signer::address_of(from));
+        };
+
+        // Confirm it now exists
+        assert!(exists<Account>(signer::address_of(from)), 1);
+
+        // Destroy the Account resource
+        destroy_account_from(aptos_framework, signer::address_of(from));
+
+        // Confirm the resource has been removed
+        assert!(!exists<Account>(signer::address_of(from)), 2);
+    }
+
     #[test_only]
     struct DummyResource has key {}
 

aptos-move/framework/aptos-framework/sources/event.move

@@ -6,6 +6,8 @@ module aptos_framework::event {
     use std::bcs;
 
     use aptos_framework::guid::GUID;
+    use aptos_framework::system_addresses;
+    use aptos_framework::guid;
 
     friend aptos_framework::account;
     friend aptos_framework::object;
@@ -38,6 +40,12 @@ module aptos_framework::event {
         guid: GUID,
     }
 
+    public fun destroy_event_handle<T: drop + store>(account: &signer, handle: EventHandle<T>) {
+        system_addresses::assert_aptos_framework(account);
+
+        let EventHandle { counter: _, guid: _ } = handle;
+    }
+
     #[deprecated]
     /// Use EventHandleGenerator to generate a unique event handle for `sig`
     public(friend) fun new_event_handle<T: drop + store>(guid: GUID): EventHandle<T> {
@@ -89,4 +97,21 @@ module aptos_framework::event {
         use std::vector;
         vector::contains(&emitted_events_by_handle(handle), msg)
     }
+
+    #[test_only]
+    struct TestEvent has drop, store {}
+
+    #[test_only]
+    public fun create_test_event_handle<T: drop + store>(): EventHandle<T> {
+        let dummy_address = @0x1;
+        let dummy_creation_num = 0;
+        let guid = guid::create(dummy_address, &mut dummy_creation_num);
+        new_event_handle<T>(guid)
+    }
+
+    #[test(account = @0x1)]
+    public entry fun test_destroy_event_handle(account: signer) {
+        let handle = create_test_event_handle<TestEvent>();
+        destroy_event_handle(&account, handle);
+    }
 }

aptos-move/framework/aptos-framework/sources/guid.move

@@ -2,6 +2,7 @@
 module aptos_framework::guid {
     friend aptos_framework::account;
     friend aptos_framework::object;
+    friend aptos_framework::event;
 
     /// A globally unique identifier derived from the sender's address and a counter
     struct GUID has drop, store {