Linting scripts for brace, square bracket and parenthesis imbalance

[geoff1111]

Here is a simple linter for JimTcl or Tcl which checks for unmatched braces, square brackets and parenthesis. Type jimsh lint.tcl -h for help. This script might save you precious time if your editor does not identify these problems for you. Script for lint.tcl below:

#! ./jimsh

if {$argc==0 || $argc>1} {
  puts "USAGE:\n  $argv0 FILE.tcl\n  cat FILE.tcl | $argv0 -\n  $argv0 --help"
  exit 1
} elseif {$argv in {-h -? --help}} {
  puts {
Lint.tcl is a simple delimiter (curly brace, parenthesis and square bracket)
checker for Tcl and JimTcl.

It checks that:

1. delimiters match in number and type, and are correctly nested
2. that when each Tcl command is complete (or when a series of contiguous
   comment lines end) there are no unmatched delimiters.

In relation to (1), odd numbers of backslashes immediately prior to a
delimiter are taken into account.

Being relatively simple, perhaps the checker may miss some errors, and falsely
identify some non-errors as errors. For instance, the regular expression
{[[]+} is legal, but contains an unbalanced square bracket. This unusual
type of imbalance is unwieldy to approve automatically.

To suppress an identified non-error, it is suggested to add a rarely used
symbol in Tcl (such as an "at" symbol) associated with a balancing temporary
fix. The purpose of the "at" symbol is to highlight the temporary fix and
permit these fixes to be located easily for deletion once linting is
complete. (Examples of "at" symbol use might include "@[", "@]", "@{" or
"@}".)
  }
} else {
  set f [expr {$argv ne "-" ? [open $argv r] : "stdin"}]
  set err {}
  set stack {}
  set lineno 0
  set scriptlno 1
  set backslashes 0
  set incomment 0
  set finished 0
  while 1 {
    gets $f line
    if {[eof $f]} {
      if {!$incomment} {
        break
      } else {
        set finished 1
      }
    } else {
      incr lineno
      puts -nonewline "$lineno: "
      foreach char [split $line {}] {
        if {$char eq "\[" && $backslashes % 2 != 1} {
          lappend stack bracket
        } elseif {$char eq "\{" && $backslashes % 2 != 1} {
          lappend stack brace
        } elseif {$char eq "\(" && $backslashes % 2 != 1} {
          lappend stack paren
        } elseif {$char eq "\]" && $backslashes % 2 != 1} {
          if {[lindex $stack end] eq "bracket"} {
            set stack [lrange $stack 0 end-1]
          } elseif {[llength $stack] > 0} {
            set err "Error: expected [lindex $stack end], got close bracket; last \
                \ncomplete script at line $scriptlno"
          } else {
            set err "Error: stack empty, unmatched close bracket; last complete \
                 \nscript at line $scriptlno"
          }
        } elseif {$char eq "\}" && $backslashes % 2 != 1} {
          if {[lindex $stack end] eq "brace"} {
            set stack [lrange $stack 0 end-1]
          } elseif {[llength $stack] > 0} {
            set err "Error: expected [lindex $stack end], got close brace; last \
                \ncomplete script at line $scriptlno"
          } else {
            set err "Error: stack empty, unmatched close brace; last complete \
                 \nscript at line $scriptlno"
          }
        } elseif {$char eq "\)" && $backslashes % 2 != 1} {
          if {[lindex $stack end] eq "paren"} {
            set stack [lrange $stack 0 end-1]
          } elseif {[llength $stack] > 0} {
            set err "Error: expected [lindex $stack end], got close parenthesis; \
                \nlast complete script at line $scriptlno"
          } else {
            set err "Error: stack empty, unmatched close parenthesis; last complete \
                 \nscript at line $scriptlno"
          }
        }
        if {$char eq "\\"} {
          incr backslashes
        } else {
          set backslashes 0
        }
        puts -nonewline $char
        flush stdout
        if {$err ne {}} {
          puts stderr "\n$err"
          exit 1
        }
      }
      set backslashes 0
      append script "$line\n"
    }
    set incomment [expr {[lindex [string trimleft $script] 0] eq "#"}]
    if {[info complete $script] && !$incomment || ($incomment && $finished)} {
      set script {}
      set scriptlno $lineno
      if {[llength $stack] != 0} {
        # whenever a script is complete, the stack should be empty.
        puts stderr "\nError: script \"complete\"; last complete script at line\
              $scriptlno,\nbut script contains unbalanced [lindex $stack end]"
        exit 1
      } else {
        puts "\nLast complete script at line $scriptlno"
      }
    }
    if {$finished} {
      break
    }
    puts ""
    flush stdout
  }
  if {$argc == 1} {close $f}
}

[sgbeal]

Thank you for this! Seeing the error "missing brace" in a thousand-line script is disheartening.