[new package] python-databases 0.9.0

Author: podsvirov

mingw-w64-python-databases/PKGBUILD

@@ -0,0 +1,39 @@
+# Maintainer: Konstantin Podsvirov <[email protected]>
+
+_realname=databases
+pkgbase=mingw-w64-python-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
+pkgver=0.9.0
+pkgrel=1
+pkgdesc='Async database support for Python (mingw-w64)'
+arch=('any')
+mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
+url='https://www.encode.io/databases/'
+msys2_repository_url='https://github.com/encode/databases'
+license=('spdx:BSD-3-Clause')
+depends=("${MINGW_PACKAGE_PREFIX}-python"
+         "${MINGW_PACKAGE_PREFIX}-python-sqlalchemy")
+makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
+             "${MINGW_PACKAGE_PREFIX}-python-installer"
+             "${MINGW_PACKAGE_PREFIX}-python-setuptools")
+optdepends=("${MINGW_PACKAGE_PREFIX}-python-aiosqlite: sqlite support"
+            "${MINGW_PACKAGE_PREFIX}-python-asyncpg: postgresql support")
+options=('!strip')
+source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
+sha256sums=('d2f259677609bf187737644c95fa41701072e995dfeb8d2882f335795c5b61b0')
+
+build() {
+  cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"
+
+  python -m build --wheel --skip-dependency-check --no-isolation
+}
+
+package() {
+  cd "python-build-${MSYSTEM}"
+
+  MSYS2_ARG_CONV_EXCL="--prefix=" \
+    python -m installer --prefix=${MINGW_PREFIX} \
+    --destdir="${pkgdir}" dist/*.whl
+
+  install -Dm644 LICENSE.md "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE.md"
+}