python-databases: New package

Author: podsvirov

mingw-w64-python-databases/PKGBUILD

@@ -0,0 +1,44 @@
+# Maintainer: Konstantin Podsvirov <[email protected]>
+
+_realname=databases
+pkgbase=mingw-w64-python-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
+pkgver=0.7.0
+pkgrel=1
+pkgdesc='Async database support for Python (mingw-w64)'
+arch=('any')
+mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32' 'clangarm64')
+url='https://github.com/encode/databases'
+license=('BSD')
+depends=("${MINGW_PACKAGE_PREFIX}-python"
+         "${MINGW_PACKAGE_PREFIX}-python-sqlalchemy")
+makedepends=("${MINGW_PACKAGE_PREFIX}-python-setuptools"
+             "git")
+optdepends=("${MINGW_PACKAGE_PREFIX}-python-aiosqlite: sqlite support"
+            "${MINGW_PACKAGE_PREFIX}-python-asyncpg: postgresql support")
+#source=("${_realname}-$pkgver.tar.gz::${url}/archive/${pkgver}.tar.gz")
+#sha256sums=('c938f27865d1cb304838ac0962332b07ee738165b7fd4993907195df1165302c')
+
+# For more info see https://github.com/encode/databases/pull/540
+_databases_revision=ec987913b8ef815b68629d65ccbd3dc45143efcd
+source=("git+https://github.com/tarsil/databases.git#commit=$_databases_revision")
+sha256sums=('SKIP')
+
+prepare() {
+  #cp -r "${srcdir}/${_realname}-${pkgver}" "${srcdir}/python-build-${MSYSTEM}"
+  cp -r "${srcdir}/${_realname}" "${srcdir}/python-build-${MSYSTEM}" && cd "${srcdir}/python-build-${MSYSTEM}"
+}
+
+build() {
+  msg "Python build for ${MSYSTEM}"
+  cd "${srcdir}/python-build-${MSYSTEM}"
+  ${MINGW_PREFIX}/bin/python setup.py build
+}
+
+package() {
+  cd "${srcdir}/python-build-${MSYSTEM}"
+  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
+    ${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} --root="${pkgdir}" -O1 --skip-build
+
+  install -Dm644 LICENSE.md  ${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE.md
+}