The SHA-256 hash of this sentence begins with ...

[triska]

Motivated by a post on Mastodon:

:- use_module(library(crypto)).
:- use_module(library(lists)).
:- use_module(library(dcgs)).
:- use_module(library(format)).

sentence(Hs) --> "The SHA-256 hash of this sentence begins with ", hexs(Hs), ".".

hexs([]) --> [].
hexs([H|Hs]) --> hex(H), hexs(Hs).

hex(H) --> [H], { member(H, "0123456789abcdef") }.

Yielding:

?- length(Hs, L),
   portray_clause(L),
   once((phrase(sentence(Hs), Ls),
         crypto_data_hash(Ls, Hash, [algorithm(sha256)]),
         phrase((Hs,...), Hash))),
   portray_clause(Ls),
   false.
%@ 0.
%@ "The SHA-256 hash of this sentence begins with .".
%@ 1.
%@ "The SHA-256 hash of this sentence begins with a.".
%@ 2.
%@ 3.
%@ "The SHA-256 hash of this sentence begins with 263.".
%@ 4.
%@ 5.
%@ "The SHA-256 hash of this sentence begins with 2f64e.".
%@ 6.
%@ ...

Sample verification:

$ echo -n "The SHA-256 hash of this sentence begins with 2f64e." | sha256sum 
2f64e090436cc9931bf19a8fbebbf2abeb6e2c397ac764877abf02073950af50  -

[jjtolton]

WOW!!! 10 years ago you could've had a Prolog crypto miner with this!! Just replace "starts with" with "ends with <block difficulty> zeros" !!