Generating text with read/1 (quick, dirty, imperative; a personal note)

[haijinSk]

Recently I discovered the power of read/1. Yes, Markus @triska mentioned read/1 on various occasions/places, but I wasn't prepared then. Now, at least, I can transform my Prolog factoids/datasets from one form to another in a direct way. Or, I can do some crazy, impulsive things...

I wanted to write something again, now in a style/spirit of a demoscene, and very quickly and playfully. Except, I'm only a naive Prolog user and a computing layman.

As an old personal "project" I have a small website "featuring" some Chinese characters (and words, even proverbs and old forms of characters).

I wrote that in PHP (the first PHP versions of my web were in many ways my first steps in programming, using ideas from Jackson structured programming. Later, still PHP, using ideas from How to Design Classes (PDF, 2.8 MB)), then, after some exposure to htdp.org, in Miranda (generated as a static site).

And recently, partly to re-understand my Miranda code (how it works conceptually, in order to add new concepts, new relations/views between Chinese characters and words on my website, and to explore the relations in my datasets), I rewrote it in Prolog (my code works in Scryer and Trealla).

All of that after exposure to The Power of Prolog. And I was exposed to some parts/aspects more than to others. In fact, as I see it, I use only few things of Prolog for my Prolog programming. I can (thanks to the power) create something using "nothing" but few concepts. Though, I'm not saying that the concepts are obvious at first sight in all its beauty, as for me.

Almost non-programmer, but paradoxically interested in programming languages and in program design methodologies, I had working prototypes written in constraint handling rules and then in answer set programming, in combination with Prolog. It was exciting for me, I felt the power (and I still like those two formalisms), yet, at the end of the day, it taught me to appreciate Prolog more than before.

---

There are problems with Scryer when using Linux pipes: #2866, but my "demo" is possible:

My demo program:

:- use_module(library(dcgs)).
:- use_module(library(format)).
:- use_module(library(dif)).

run :-
  read(E),
  dif(E,end_of_file),
  phrase(E,Str),
  format("~s",[Str]),
  run.
run :- read(end_of_file).

gr_t_str(Gr,Template,String) :- phrase(Gr,Str), phrase(format_(Template,[Str]),String).

h1(Gr) --> { gr_t_str(Gr,"<h1>~s</h1>~n",String) }, String.

p(Gr) --> { gr_t_str(Gr,"<p>~s</p>~n",String) }, String.

div(Gr) --> { gr_t_str(Gr,"<div>~n~s</div>~n",String) }, String.

link(Url,Gr) -->
  { phrase(format_("<a href=\"~s\">~~s</a>",[Url]),StrTemplate),
    gr_t_str(Gr,StrTemplate,String) },
    String.

My input file:

h1("A demo page").

p("Grammars can be nested and a sequence of grammars/strings can be concatenated using parenthesis and commas: they are DCGs.").

div(
 (
   p( (link("https://en.wikipedia.org/wiki/Unix_philosophy","They"), " said: make every program a filter.") ),
   p("Yes, but what about maps?"),
   p("Or, is this a preprocessor? Small and useless...")
 )
).

The pipe and output (can be redirected to a file):

cat input-file.pl | scryer-prolog -g 'run,halt' demo-program.pl

<h1>A demo page</h1>
<p>Grammars can be nested and a sequence of grammars/strings can be concatenated using parenthesis and commas: they are DCGs.</p>
<div>
<p><a href="https://en.wikipedia.org/wiki/Unix_philosophy">They</a> said: make every program a filter.</p>
<p>Yes, but what about maps?</p>
<p>Or, is this a preprocessor? Small and useless...</p>
</div>

Two caveats:

1. run :- read(end_of_file). has to be second in this imperative definition of run/0. I know, I could use if_/3 from reif library, something like:

run :-
  read(E),
  if_(E = end_of_file,
       true,
      (phrase(E,Str),
       format("~s",[Str]),
       run)).

And it's still a quick, dirty, imperative I/O, not a bi-directional relation, so I could use the traditional If-Then-Else ( condition -> then_clause ; else_clause ) construct, but I like solutions without it more (I like you dif/2) and I don't have many situations, in my noncritical programming in small, where I definitely need to use that construct.

Not mentioning the cut, that I never use, because: 1. I'm not that clever programmer, 2. I don't write programs for situations where computational efficiency is important, 3. I try to use Prolog as a declarative/relational programming, when I can/know how to do it (and when I'm not doing "impulsive programming").

2. An input file has to end without empty lines.

Thank you.

P.S.: This is not how my website is generated. This is not how to write and use Prolog. This is a quick-dirty-crazy "micro-demo" to be criticized, and maybe I might learn something. This is a personal note and the "demo" is a MacGuffin, I'm afraid...

---

P.S.2: For example, when I'm generating pages for my website, to save one page (stránka) to a file (súbor), I use this:

strankaSubor(UrlKw) :-
  phrase(strankaStringHTML(UrlKw),String),
  append(UrlKw,".html",File),
  append("web/znaky/",File,Path),
  phrase_to_file(seq(String),Path).

Of course, before that, I need to process page data:

stranka(sekRozne,"slnko","slnko",[frZH("日"), ixzh('日'), ijgw('日')],["jin-jang","japonsko"]).
stranka(sekRozne, "wu-wei", "wu-wej", [frZH("無為")], ["tao", "te"]).
stranka(sekRozne,"laska","láska",[frZH("愛"), frZH("愛情"), frZH("愛人"), frZH("永恆的愛情")],[]).
stranka(sekRozne,"milujem-ta","milujem ťa",[frZH("我愛你")],["vasen", "sex"]).
stranka(sekPod("milujem-ta"),"sex","sex",[frZH("性交")],[]).
stranka(sekPod("milujem-ta"),"vasen","vášeň",[frZH("激情")],[]).
stranka(sekRozne,"stastie","šťastie",[frZH("福"), frZH("幸福"), frZH("幸運")],["peniaze"]).
stranka(sekPod("stastie"),"peniaze","peniaze",[frZH("錢")],[]).
stranka(sekRozne,"priatelstvo","priateľstvo",[frZH("友情"), frZH("朋友"), frZH("朋友們")],[]).
stranka(sekRozne,"drak","drak",[frZH("龍"), frJP("竜"), ixzh('龍'), ijgw('龍')],[]).
stranka(sekRozne,"tiger","tiger",[frZH("虎"), ixzh('虎'), ijgw('虎')],[]).
stranka(sekRozne,"zdravie","zdravie",[frZH("健康")],["dlhovekost"]).
stranka(sekPod("zdravie"),"dlhovekost","dlhovekosť (dlhý život)",[frZH("長壽")],[]).
stranka(sekRozne,"rodina","rodina",[frZH("家"), frZH("家和萬事興"), frZH("家庭"), frJP("家族"), frZH("族")],["rodicia", "dieta-deti", "sestra"]). 
[...]

And (among other things) dictionary (slovník) data:

slovnik(zh,trad_simp("日",""),"ri [ž’]","slnko; deň","").
slovnik(jp,"日","hi; nichi [niči]","slnko, slnečný svit; deň","").
slovnik(zh,trad_simp("愛","爱"),"ai","láska, milovať, mať rád, mať v obľube","").
slovnik(jp,"愛","ai","láska","").
slovnik(zh,trad_simp("情",""),"","cit, láskavosť, situácia, okolnosti","").
slovnik(zh,trad_simp("愛情","爱情"),"aiqing","láska (medzi mužom a ženou)","").
slovnik(zh,trad_simp("人",""),"ren","človek, osoba","").
slovnik(zh,trad_simp("愛人","爱人"),"airen","manžel/manželka, milý/milá","").
slovnik(zh,trad_simp("永恆的愛情","永恒的爱情"),"yongheng de aiqing","večná láska","").
slovnik(zh,trad_simp("我愛你","我爱你"),"wo ai ni","milujem ťa","").
slovnik(zh,trad_simp("我",""),"wo","ja","").
slovnik(zh,trad_simp("你",""),"ni","ty","").
slovnik(zh,trad_simp("激情",""),"jiqing","vášeň, prudký cit, hlboké vzrušenie, pátos","").
slovnik(jp,"激情","gekijó [gekidžó]","silné emócie, silné vzrušenie, vášne, afekt, výbuch","").
slovnik(zh,trad_simp("激",""),"jiqing","vzdúvať, vzbudzovať, vyvolávať, podnecovať, prudký, s veľkou intenzitou","").
slovnik(zh,trad_simp("福",""),"fu","šťastie, zdar (znak symbolizuje a privoláva šťastie a blahobyt)","").
slovnik(zh,trad_simp("幸福",""),"xingfu","šťastie, (byť) šťastný, požehnanie, blaženosť","").
slovnik(zh,trad_simp("幸運","幸运"),"xingyun","šťastena, šťastný osud","").
[...]

Speaking of if_/3 and processing, at various places I use if_/3 (and other things), like here:

adeptiZnaky([],_,_,ZnAku,ZnAku) --> [].
adeptiZnaky([Zn|Slovo],SlovaZHJP,Index,ZnAku,A2) -->
 { Index2 #= Index + 1,
   if_((memberd_t([Zn],SlovaZHJP) ; memberd_t(Zn,ZnAku)),
         (Aku = ZnAku, E = []),
         (Aku = [Zn|ZnAku], E = [znak(Index,[Zn])])
      )}, E, adeptiZnaky(Slovo,SlovaZHJP,Index2,Aku,A2).

Or:

prekladyZnakovHTML([],[]) --> "".
prekladyZnakovHTML([znak(Index,Zn)|Znaky],[PrekladSk0|PrekladySk]) -->
  { typo(PrekladSk0,PrekladSk),
    prveObrFrazy1znakove(UrlZnakPary),
    maplist(\Par^Z^(Par=_-Z),UrlZnakPary,IbaZnaky),
    if_(memberd_t(Zn,IbaZnaky),
         ( member(Url-Zn,UrlZnakPary), phrase(format_("~d. <a href=\"~s.html\">znak ~s</a>: ~s",[Index,Url,Zn,PrekladSk]),Str) ),
         phrase(format_("~d. znak ~s: ~s",[Index,Zn,PrekladSk]),Str)
    )},
  "<li>",Str,"</li>",nL,
  prekladyZnakovHTML(Znaky,PrekladySk).

Yes, I need to rewrite my code, like everything, one day; it was written quickly... I was afraid, whether I can write it in Prolog...

At first, I started slowly, with tests:

test :-
  portray_clause("Test: ZH Adepti na preklad jednotlivých znakov."),
  frStranka_adeptiPreFrazyZH([frZH("家"), frZH("家和萬事興"), frZH("家庭"), frJP("家族"), frZH("族")],Adepti),
  Adepti = [slovo("家",[]),slovo("家和萬事興",[znak(2,"和"),znak(3,"萬"),znak(4,"事"),znak(5,"興")]),slovo("家庭",[znak(2,"庭")]),slovo("族",[])],
  portray_clause("Test: JP Adepti na preklad jednotlivých znakov."),
  frStranka_adeptiPreFrazyJP([frZH("家"), frZH("家和萬事興"), frZH("家庭"), frJP("家族"), frZH("族")],AdeptiJP),
  AdeptiJP = [slovo("家族",[])],
  portray_clause("Testy OK").