Are these errors to be expected?

[Skgland]

The following each result in a error(syntax_error(incomplete_reduction),read_term/3:N) error when loading.

test() :- true.

test :- once(a;b).

a :- false.
b.

:- use_module(library(lists)).

test :- member(Key -> Value, [_]).

I encountered these constucts while tring to see what it would take to get plwm to run on scryer and swipl appears to accept these while scryer doesn't and I am not sure if this is a deficency in scryer of a deviation from the standard in swipl.

The first I am working around by just removing the parenthesis i.e. test :- true. and the second by wrapping the goal in parenthesis i.e. test :- once((a;b))., but the third is more difficult as it is used pervasively in the configuration of hooks and keybindings and will be found in user configs.

[triska]

Yes, all these syntax errors are expected:

6.3.3.1 Arguments

An argument (represented by arg in the syntax rules)
occurs as the argument of a compound term or element of
a list. It can be an atom which is an operator, or a term
with priority not greater than 999. When an argument is
an arbitrary term, its priority shall be less than the priority
of the ',' (comma) operator so that there is no conflict
between comma as an infix operator and comma as an
argument or list element separator.

We have:

?- current_op(Pri, Fix, ->).
   Pri = 1050, Fix = xfy.

and therefore we write for example:

test :- member((Key -> Value), [_]).

or consider using a different operator, such as for example -:

?- current_op(Pri, Fix, -).
   Pri = 500, Fix = yfx
;  Pri = 200, Fix = fy.

This is a key advantage of porting plwm to Scryer: Scryer reliably recognizes standard Prolog syntax, and the result will therefore also be easier to port to other Prolog systems.

[Skgland]

The explanation appears to not cover test() :- true. Though I would assume a different standard section would explain that.

[UWN]

Already a term test(). is invalid syntax.

[triska]

Yes indeed, I left this out on the grounds that it seemed already clear. We have:

A compound term written in functional notation has the
form f(A1,...,An) where each argument Ai is an arg
and they are separated by , (comma).

           term = atom, open ct, arg list, close
Abstract:  f(l)   f              l
Priority:  0

           arg list = arg ;
Abstract:  a          a

           arg list = arg, comma, arg list ;
Abstract:  a,l        a           l

[Skgland]

Another problem appears the line

default_set(ws_format_occupied,       "▘~w").

were I get

caught: error(syntax_error(missing_quote),read_term/3:173)
caught: error(syntax_error(input_output_error),load/1)

I suspect the ▘ isn't accepted/valid in strings.

[triska]

setting.pl parses without errors or warnings on my machine, if I correct the two types of syntax mistakes you mentioned in the original post, i.e., superfluous () and missing round brackets for arguments with priority greater than that of ,.

[Skgland]

% src/setting.pl

default_set(ws_format_occupied,       "▘~w").

$>  scryer-prolog -g "halt" src/setting.pl
caught: error(syntax_error(missing_quote),read_term/3:2)
?- 

[Skgland]

Ups, I had an old build of scryer-prolog installed. I apparently only updated it in the VM and on the desktop PC and forgot to update it on my laptop.

[triska]

OK perfect, I hoped that this was the issue. I was building the latest master to be extra certain that this now works, it definitely works with 9b293cf from 2 weeks ago and should still work also now.

[Skgland]

Install of latest master is complete and now it works. Sorry for the confusion.

[triska]

I would like to expand on syntax errors involving operators with priority greater than that of ,.

In the example, we have:

?- T = f(a->b).
   error(syntax_error(incomplete_reduction),read_term/3:1).

Now, why would someone not allow this? It seems clear that only the term f((a->b)) can ever be meant by it, right?

Right, and then in later stages of development, I add an argument, and write for example:

?- T = f(a->b, c).

Still clear, right?

---

Well, a->b, c is actually the term ->(a, (b,c)):

?- write_canonical((a->b,c)).
->(a,','(b,c))   true.

It therefore seems very welcome that the standard prevents this type of mistake.

[Skgland]

That makes sense.