Track who created or edited script (#1838)

Adds `:created_by` and `:last_updated_by` to `Script` schema.

Author: elinol

lib/nerves_hub/accounts/remove_account.ex

@@ -19,6 +19,7 @@ defmodule NervesHub.Accounts.RemoveAccount do
   alias NervesHub.Firmwares.FirmwareDelta
   alias NervesHub.Firmwares.FirmwareTransfer
   alias NervesHub.Products.Product
+  alias NervesHub.Scripts.Script
 
   alias NervesHub.Repo
 
@@ -40,6 +41,8 @@ defmodule NervesHub.Accounts.RemoveAccount do
     |> Multi.update_all(:soft_delete_devices, &soft_delete_by_org_id(Device, &1), [])
     |> Multi.update_all(:soft_delete_org_users, &soft_delete_by_org_id(OrgUser, &1), [])
     |> Multi.update_all(:soft_delete_orgs, &soft_delete_orgs(&1), [])
+    |> Multi.update_all(:nilify_script_creations, &nilify_script_creations(&1), [])
+    |> Multi.update_all(:nilify_script_edits, &nilify_script_edits(&1), [])
     |> Multi.update(:soft_delete_user, &soft_delete_user/1)
     |> Repo.transaction()
   end
@@ -109,6 +112,18 @@ defmodule NervesHub.Accounts.RemoveAccount do
     |> update(set: [deleted_at: ^truncated_utc_now()])
   end
 
+  defp nilify_script_creations(%{user_id: user_id}) do
+    Script
+    |> where(created_by_id: ^user_id)
+    |> update(set: [created_by_id: nil])
+  end
+
+  defp nilify_script_edits(%{user_id: user_id}) do
+    Script
+    |> where(last_updated_by_id: ^user_id)
+    |> update(set: [last_updated_by_id: nil])
+  end
+
   defp query_by_org_id(queryable, %{org_ids: ids}) do
     query_by_org_id(queryable, ids)
   end

lib/nerves_hub/scripts.ex

@@ -57,24 +57,23 @@ defmodule NervesHub.Scripts do
 
   @spec create(Product.t(), User.t(), map()) :: {:ok, Script.t()} | {:error, Changeset.t()}
   def create(product, user, params) do
-    product
-    |> Ecto.build_assoc(:scripts)
-    |> Script.changeset(params)
+    %Script{}
+    |> Script.create_changeset(product, user, params)
     |> Repo.insert()
     |> case do
       {:ok, script} ->
         ProductTemplates.audit_script_created(user, product, script)
         {:ok, script}
 
-      err ->
-        err
+      {:error, changeset} ->
+        {:error, changeset}
     end
   end
 
   @spec update(Script.t(), User.t(), map()) :: {:ok, Script.t()} | {:error, Changeset.t()}
   def update(script, user, params) do
     script
-    |> Script.changeset(params)
+    |> Script.update_changeset(user, params)
     |> Repo.update()
     |> case do
       {:ok, script} ->
@@ -84,8 +83,8 @@ defmodule NervesHub.Scripts do
 
         {:ok, script}
 
-      err ->
-        err
+      {:error, changeset} ->
+        {:error, changeset}
     end
   end
 end

lib/nerves_hub/scripts/script.ex

@@ -3,23 +3,39 @@ defmodule NervesHub.Scripts.Script do
 
   import Ecto.Changeset
 
+  alias NervesHub.Accounts.User
   alias NervesHub.Products.Product
 
   @type t :: %__MODULE__{}
+  @required [:name, :text]
 
   schema "scripts" do
     belongs_to(:product, Product)
+    belongs_to(:created_by, User, where: [deleted_at: nil])
+    belongs_to(:last_updated_by, User, where: [deleted_at: nil])
 
     field(:name, :string)
     field(:text, :string)
 
     timestamps()
   end
 
-  def changeset(struct, params) do
+  def create_changeset(%__MODULE__{} = struct, product, created_by, params) do
     struct
-    |> cast(params, [:name, :text])
-    |> validate_required([:name, :text])
+    |> cast(params, @required)
+    |> put_assoc(:product, product)
+    |> put_assoc(:created_by, created_by)
+    |> validate_required(@required ++ [:created_by])
     |> validate_length(:name, lte: 255)
+    |> foreign_key_constraint(:created_by_id)
+  end
+
+  def update_changeset(%__MODULE__{} = struct, edited_by, params \\ %{}) do
+    struct
+    |> cast(params, @required)
+    |> put_change(:last_updated_by_id, edited_by.id)
+    |> validate_required(@required)
+    |> validate_length(:name, lte: 255)
+    |> foreign_key_constraint(:last_updated_by_id)
   end
 end

lib/nerves_hub_web/live/support_scripts/edit.ex

@@ -2,20 +2,19 @@ defmodule NervesHubWeb.Live.SupportScripts.Edit do
   use NervesHubWeb, :updated_live_view
 
   alias NervesHub.Scripts
-  alias NervesHub.Scripts.Script
 
   @impl Phoenix.LiveView
   def mount(
         %{"script_id" => script_id},
         _session,
-        %{assigns: %{product: product}} = socket
+        %{assigns: %{org: org, product: product}} = socket
       ) do
     script = Scripts.get_by_product_and_id!(product, script_id)
 
     socket
-    |> page_title("Edit Support Script - #{socket.assigns.org.name}")
+    |> page_title("Edit Support Script - #{org.name}")
     |> sidebar_tab(:support_scripts)
-    |> assign(:form, to_form(Script.changeset(script, %{})))
+    |> assign(:form, to_form(Ecto.Changeset.change(script)))
     |> assign(:script, script)
     |> ok()
   end

lib/nerves_hub_web/live/support_scripts/new.ex

@@ -9,7 +9,7 @@ defmodule NervesHubWeb.Live.SupportScripts.New do
     socket
     |> page_title("New Support Script - #{socket.assigns.org.name}")
     |> sidebar_tab(:support_scripts)
-    |> assign(:form, to_form(Script.changeset(%Script{}, %{})))
+    |> assign(:form, to_form(Ecto.Changeset.change(%Script{})))
     |> ok()
   end
 

priv/repo/migrations/20250124144709_add_created_and_last_updated_by_to_script.exs

@@ -0,0 +1,10 @@
+defmodule NervesHub.Repo.Migrations.AddCreatedAndLastUpdatedByToScript do
+  use Ecto.Migration
+
+  def change do
+    alter table(:scripts) do
+      add(:created_by_id, references(:users))
+      add(:last_updated_by_id, references(:users))
+    end
+  end
+end

test/nerves_hub/scripts_test.exs

@@ -1,15 +1,17 @@
 defmodule NervesHub.ScriptsTest do
+  alias NervesHub.Accounts
   use NervesHub.DataCase
 
   alias NervesHub.Fixtures
   alias NervesHub.Scripts
 
   setup do
     user = Fixtures.user_fixture()
+    user2 = Fixtures.user_fixture()
     org = Fixtures.org_fixture(user)
     product = Fixtures.product_fixture(user, org)
 
-    %{user: user, org: org, product: product}
+    %{user: user, user2: user2, org: org, product: product}
   end
 
   describe "creating a script" do
@@ -21,6 +23,63 @@ defmodule NervesHub.ScriptsTest do
         })
 
       assert script.product_id == product.id
+      assert script.created_by_id == user.id
+    end
+  end
+
+  describe "updating a script" do
+    test "successful update", %{product: product, user: user} do
+      {:ok, script} =
+        Scripts.create(product, user, %{
+          name: "MOTD",
+          text: "NervesMOTD.print()"
+        })
+
+      {:ok, script} =
+        Scripts.update(script, user, %{name: "New Name"})
+
+      assert script.name == "New Name"
+      assert script.last_updated_by_id == user.id
+    end
+
+    test "other user updates script", %{
+      product: product,
+      user: user,
+      user2: user2
+    } do
+      {:ok, script} =
+        Scripts.create(product, user, %{
+          name: "MOTD",
+          text: "NervesMOTD.print()"
+        })
+
+      {:ok, script} =
+        Scripts.update(script, user, %{name: "New Name"})
+
+      {:ok, script} =
+        Scripts.update(script, user2, %{text: "New text"})
+
+      assert script.text == "New text"
+      assert script.last_updated_by_id == user2.id
+    end
+  end
+
+  describe "user removal" do
+    test "user is removed - editor fields are nilified", %{product: product, user: user} do
+      {:ok, script} =
+        Scripts.create(product, user, %{
+          name: "MOTD",
+          text: "NervesMOTD.print()"
+        })
+
+      {:ok, _script} =
+        Scripts.update(script, user, %{name: "New Name"})
+
+      Accounts.remove_account(user.id)
+
+      script = Scripts.get!(script.id)
+      assert script.created_by_id == nil
+      assert script.last_updated_by_id == nil
     end
   end
 end

test/nerves_hub_web/live/support_scripts_test.exs

@@ -65,7 +65,8 @@ defmodule NervesHubWeb.Live.SupportScriptsTest do
 
   describe "edit" do
     test "requires a name and text", %{conn: conn, org: org, product: product, user: user} do
-      {:ok, script} = Scripts.create(product, user, %{name: "MOTD", text: "NervesMOTD.print()"})
+      {:ok, script} =
+        Scripts.create(product, user, %{name: "MOTD", text: "NervesMOTD.print()"})
 
       conn
       |> visit("/org/#{org.name}/#{product.name}/scripts/#{script.id}/edit")