Missing output files(s) expected by process

[lpembleton]

Hi, I am running into the following error in one of my nextflow processes.

Error executing process > 'genotype'

Caused by:
Missing output file(s) *multi.vcf expected by process genotype

process genotype {
    errorStrategy 'retry'
    maxRetries 2
    maxForks 1

    publishDir "my-results/" , pattern: '*multi.vcf ', mode: 'copy', overwrite: true
    

    input:
    path(gvcf) from gvcf_ch.collect()
    path(gvcf_tbi) from gvcf_tbi_ch.collect()
    path reference from params.reference

    output:
    file("*multi.vcf ") into vcf_ch

    script:
    """

    paste <(echo ${gvcf} | tr " " "\n" | cut -d '.' -f 1) <(echo ${gvcf} | tr " " "\n") > cohort.sample_map

    gatk CreateSequenceDictionary -R ${reference}
    samtools faidx ${reference}
    awk -v FS="\t" -v OFS="\t" '{print \$1 FS "0" FS (\$2-0)}' ${reference}.fai > regions.bed
    gatk BedToIntervalList -I regions.bed -O regions.interval_list -SD *.dict
    
    gatk GenomicsDBImport --sample-name-map cohort.sample_map --genomicsdb-workspace-path my_database --merge-contigs-into-num-partitions 20 -L regions.interval_list
    chmod -R 777 my_database/
    gatk GenotypeGVCFs -R ${reference} -V gendb://my_database -O test_output.vcf

    gatk LeftAlignAndTrimVariants -R ${reference} -V test_output.vcf -O test_output.split-multi.vcf --split-multi-allelics

    """

}

Although nextflow is reporting that it cannot find the test_output.split-multi.vcf file, when I manually navigate to the work dir I can see that the test_output.split-multi.vcf file was created correctly.

Any suggestions would be greatly appreciated. Thanks.

[lpembleton]

All good, I have found the error. I had a space at the end of the search pattern *multi.vcf in the output and publishDir sections 🤦‍♂️