Can't access input variable in publishDir

[noelnamai]

Hi.

I get the following error when I run this process. I would like to get my results published inside a patient/ directory:

No such variable: patient

I can't figure out where this is failing. Am running Nextflow version 21.10.6.

Thanks.

process foo {

    publishDir "$patient", mode: "copy"

    input:
    tuple val(patient), path(filtered_vcf), path(expression_file)

    output:
    tuple val(patient), path("${patient}.foo.filtered.vcf"), emit: vcf
   
    script:
    """	
    ${params.code}/filter.R \
    --input ${filtered_vcf} \
    --expression ${expression_file} \
    --output ${patient}.foo.filtered.vcf \
    """
}

[bentsherman]

Does it work if you use a closure?

    publishDir { patient }, mode: "copy"

[keiranmraine]

I can confirm this works, just be aware that you may end up having to define variables multiple times (e.g. script section and publishDir closure):

process complex {
    input:
        tuple val(groupId), val(types), val(ids), file(htsfiles), file(htsindexes)

    output:
        file('*.genotype.json')

    publishDir {
        def case_idx = types.indexOf('case')
        def ctrl_idx = types.indexOf('control')
        "${params.outdir}/${ids[case_idx]}_vs_${ids[ctrl_idx]}/genotype"
    }, mode: 'copy'

    script:
        def case_idx = types.indexOf('case')
        def ctrl_idx = types.indexOf('control')
        """
        compareBamGenotypes.pl \
            -j result.genotype.json \
            -tb ${htsfiles[case_idx]} -nb ${htsfiles[ctrl_idx]}
        """
}