hmmscan does not run within nexflow (HMM file not found error)

[pavlohrab]

Hello, community,

Trying to lean nexflow, hence tried to encapsulate my bash one-liners, I used for an analysis. However, I stumbled upon interesting issue I am not sure how to tackle,

It seems that hmmscan doesn't see the HMM file I created, if run within nexflow. If run from the shell, everything is just fine.

Command error:
  
  Error: File existence/permissions problem in trying to open HMM file ./data/dbcan_data/dbCAN-fam-HMMs.txt.
  HMM file ./data/dbcan_data/dbCAN-fam-HMMs.txt not found (nor an .h3m binary of it); also looked in PFAMDB

My nf file:

params.outdir = 'results'

process CAZY_DBCAN {
	
	publishDir params.outdir, mode: 'copy'
	conda "envs/dbcan.yml"

	input:
	path faa_file

	output:
	path "${faa_file}.dm"

	script:
	"""
    hmmscan --domtblout ${faa_file}.dm ./data/dbcan_data/dbCAN-fam-HMMs.txt $faa_file > result.out
	"""
}

process CAZY_DBCAN_FILTER {

	publishDir params.outdir, mode: 'copy'
	conda "envs/dbcan.yml"

	input:
	path file

	output:
	path "$publishDir/*.ps"
	path "$publishDir/*.filtered"

	script:
	"""
	sh hmmscan-parser.sh $file > file.dm.ps && cat ${file}.ps | awk '\$10 >= 0.35' | awk '\$5 <= 1e-18' > ${file}.filtered
	"""

}



workflow { 
	inputs = Channel.fromPath(params.input_file)
	dbcan = CAZY_DBCAN(inputs)
	CAZY_DBCAN_FILTER(dbcan)
}

[jemunro]

Where is ./data/dbcan_data/dbCAN-fam-HMMs.txt located? To use it in your process you need to include it in as an input to your process:

process CAZY_DBCAN {
	
	publishDir params.outdir, mode: 'copy'
	conda "envs/dbcan.yml"

	input:
	path faa_file
	path HMMs

	output:
	path "${faa_file}.dm"

	script:
	"""
        hmmscan --domtblout ${faa_file}.dm $HMMs $faa_file > result.out
	"""
}

workflow { 
	inputs = Channel.fromPath(params.input_file)
        HMMs = Channel.fromPath('./data/dbcan_data/dbCAN-fam-HMMs.txt')
	dbcan = CAZY_DBCAN(inputs, HMMs)
	CAZY_DBCAN_FILTER(dbcan)
}

[pavlohrab]

Thank you, worked like a charm!

The only thing is that the program also needed directory alongside the file, so configuration like that worked:

process CAZY_DBCAN {
	
	publishDir params.outdir, mode: 'copy'
	conda "envs/dbcan.yml"

	input:
	path faa_file
	path HMMs

	output:
	path "${faa_file}.dm"

	script:
	"""
    hmmscan --domtblout ${faa_file}.dm ${HMMs}/dbCAN-fam-HMMs.txt $faa_file > result.out
	"""
}

With directory as an input for the channel in the workflow:

workflow { 
	inputs = Channel.fromPath(params.input_file)
    HMMs = Channel.fromPath('./data/dbcan_data', type: 'dir', relative: true)
	dbcan = CAZY_DBCAN(inputs, HMMs)
	CAZY_DBCAN_FILTER(dbcan)
}