Process only executing once despite multiple inputs

[anoronh4]

Bug report

When passing multiple channels to a process I am finding that the process doesn't run as many times as i expect

Expected behavior and actual behavior

I have the following code:

PICARD_COLLECTRNASEQMETRICS(
        bam.view(),
        refflat.map{ it -> it[1]},
        fasta,
        rrna_intervals.map{ it -> it[1]}
    )

With my inputs, the view shows 4 emits from the bam channel (4 lines of output)— however, PICARD_COLLECTRNASEQMETRICS only runs once. I expect it to run all 4 times!

Steps to reproduce the problem

https://github.com/anoronh4/minimal_bug <- here is my "minimal" reproducible example. i am trying to work with nf-core tools, therefore i have a few installations of nf-core modules. i ran the following CLI command:
/path/to/nextflow/nextflow-22.10.3 run main.nf --input assets/samplesheet.csv --outdir results -profile singularity. i expect PICARD_COLLECTRNASEQMETRICS to run twice, as i provide two bams in the bam_ch channel -- but it only runs once.

Program output

There's no error or warning, i just see from the trace that only 1 process finished. But I am attaching the log!
nextflow.log

Environment

• Nextflow version: 22.10.3
• Java version: 11
• Operating system: Linux
• Bash version: GNU bash, version 4.2.46(2)-release (x86_64-redhat-linux-gnu)

[anoronh4]

Just to update, after to talking to someone on the nf-core slack i've learned that this is actually expected behavior and not a bug. the issue arises from the fact that one of my channels is a queue channel, not a value channel. so now my question is: what's the best way to turn a queue channel into a value channel? I have this workaround:

my_value_ch = Channel.value()
my_queue_ch.subscribe{ my_value_ch << it }

is that the only way to do it?

[mribeirodantas]

It was me 😄

You can convert queue channels to value channels through operators returning a single value, such as first, last, collect, count, min, max, reduce, and sum. Regular variables passed as inputs to Nextflow processes will also automatically be converted to value channels. You can see there is no poison pill because the process below spans 3 tasks, even though the second input is a single value:

process FOO {
  debug true
  input:
    val x
    val y
  output:
    stdout
  """
  echo $x $y
  """
}

workflow {
  FOO(Channel
    .of(1,
        2,
        3),
    'a')
}

The output is:

N E X T F L O W  ~  version 22.10.4
Launching `ex2.nf` [distracted_minsky] DSL2 - revision: 8401e42b5a
executor >  local (3)
[4b/777e3b] process > FOO (2) [100%] 3 of 3 ✔
1 a

3 a

2 a

If it was a queue channel, as in:

process FOO {
  debug true
  input:
    val x
    val y
  output:
    stdout
  """
  echo $x $y
  """
}

workflow {
  FOO(Channel
    .of(1,
        2,
        3),
      Channel
    .of('a'))
}

The output would be:

N E X T F L O W  ~  version 22.10.4
Launching `ex2.nf` [goofy_montalcini] DSL2 - revision: 4a742c2dcd
executor >  local (1)
[c0/90dae3] process > FOO (1) [100%] 1 of 1 ✔
1 a