In DSL2: Process only executed once even though channel is populated by 8 filepairs.

[max-baer]

In DSL2: Process only executed once even though channel is populated by 8 filepairs.

I have the following short script which I want to use to trim my fastq files, however it only processes the first filepair (sample1), any idea why?

nextflow.enable.dsl=2
params.reads = "$baseDir/Fastq/*_R{1,2}_001.fastq"
params.trimmomatic = "$baseDir/packages/Trimmomatic-0.39/trimmomatic-0.39.jar"
params.outdir = "$baseDir/output_test/"

log.info """\

==========================
SWISS-TPH WHOLE-GENOME-PIPELINE
==========================
reads directory: 	${params.reads}
output directory: 	${params.outdir}
reference directory: 	Yet to come
"""
.stripIndent()

process trimming {

input:
path trimmomatic
tuple val(pair_id), path(reads)

script:
"""
java -jar $trimmomatic PE -phred33\
	${reads[0]}\
	${reads[1]}\
	${pair_id}_trimmed_forward.fastq\
	${pair_id}_trimmed_forward_unpaired.fastq\
	${pair_id}_trimmed_reversed.fastq\
	${pair_id}_trimmed_reversed_unpaired.fastq\
	ILLUMINACLIP:TruSeq3-PE.fa:2:30:10 LEADING:3 TRAILING:3 SLIDINGWINDOW:4:20 MINLEN:50
"""

}

workflow {
trimming_ch = channel.fromPath(params.trimmomatic)
read_pairs_ch = channel.fromFilePairs(params.reads, checkIfExists: true) | view ()
trimming(trimming_ch, read_pairs_ch)
}

[J-81]

trimming_ch has one item in the channel.
read_pairs_ch has 8 items (each a pair of files)

The first task of this process consumes the first item from trimming_ch and the first item from read_pairs_ch.

This results in the trimming_ch having zero items and the read_pairs_ch having 7 items.

Since trimming_ch is empty, no additional tasks start.

At least this is my hunch without testing but based on prior experience.

[mribeirodantas]

@J-81 is correct above. You have two queue channels as input to your process and one of them has a single element, which means the process will not generate a task as long as there aren't elements for both inputs to be consumed.

One solution is to have the single-element channel as a value channel. Value channels are single-element channels that can be consumed indefinitely. You can do trimming_ch.first() to turn it into a value channel, for example.

[max-baer]

Hey @J-81, hey @mribeirodantas ,

It was as you suspected, that the trimming channel only had only 1 item in the channel. Thanks for the help, it's running nicely now!

Best,
Max