Convert a value channel containing a list to queue channel

[ArchKudo]

I have a process which fetches the runs for a ncbi bioproject and saves them to a file,
I want to then read this file line by line extracting the run accessions for downloading the sra files
I tried doing this using:

process fetchRunAccesionsForBioProject {
    output:
        path 'runAccessions.txt'

    script:
    """
    wf.sh fetchRunAccesionsForBioProject "${params.bioProjectID}" > "runAccessions.txt"
    """
}

process downloadSRAForRunAccession {
    input:
        val runAccession
    output:
        path "data/${runAccession}/${runAccession}.sra"

    script:
    """
    wf.sh downloadSRAForRunAccession "$runAccession"
    """
}

workflow {
    fetch = fetchRunAccesionsForBioProject()
    content = fetch.map { it.readLines() }
    println content.getClass()
    downloadSRAForRunAccession(content)
}

But, the problem with this is the map returns a value channel, so instead of broadcasting each value to downloadSRA process it just passes the entire list to the process.
I am sure this is something basic but can't wrap my head around it, I also tried

Channel.of(content) // this fails with Argument of 'channel.of' method cannot be a channel object

// this converts the underlying data class from class groovyx.gpars.dataflow.DataflowVariable to DataflowBroadcast but still passes it as a list

test = Channel.empty().concat(
      fetchRunAccesionsForBioProject().map { it.readLines() }
) 

Channel.fromSRA works fine but I wish to use my own bash script (for educational purposes :)

tl;dr: How to create a Channel.of(someChannel.toList()) ?

[ArchKudo]

I just needed another flatten and it works, although it feels very roundabout way of doing it

Channel.empty().concat(
        fetchRunAccesionsForBioProject().map { it.readLines() }
    ).flatten()

[bentsherman]

flatten is what you need, and you can make it a bit simpler:

fetchRunAccesionsForBioProject() .map { it.readLines() } .flatten()

The output of fetchRunAccesionsForBioProject is a value channel because it has no inputs. When a process has no inputs or all of its inputs are value channels, the output will also be a value channel.