Leave workflow file solution in main dir as previous

Author: pinin4fjords

nf4-science/genomics/genomics-4.nf

@@ -0,0 +1,64 @@
+#!/usr/bin/env nextflow
+
+/*
+ * Pipeline parameters
+ */
+
+// Primary input (file of input files, one per line)
+params.reads_bam = "${projectDir}/data/sample_bams.txt"
+
+// Output directory
+params.outdir = "results_genomics"
+
+// Accessory files
+params.reference        = "${projectDir}/data/ref/ref.fasta"
+params.reference_index  = "${projectDir}/data/ref/ref.fasta.fai"
+params.reference_dict   = "${projectDir}/data/ref/ref.dict"
+params.intervals        = "${projectDir}/data/ref/intervals.bed"
+
+// Base name for final output file
+params.cohort_name = "family_trio"
+
+include { SAMTOOLS_INDEX } from './modules/samtools/index/main.nf'
+include { GATK_HAPLOTYPECALLER } from './modules/gatk/haplotypecaller/main.nf'
+include { GATK_JOINTGENOTYPING } from './modules/gatk/jointgenotyping/main.nf'
+
+
+workflow {
+
+    // Create input channel from a text file listing input file paths
+    reads_ch = Channel.fromPath(params.reads_bam).splitText()
+
+    // Load the file paths for the accessory files (reference and intervals)
+    ref_file        = file(params.reference)
+    ref_index_file  = file(params.reference_index)
+    ref_dict_file   = file(params.reference_dict)
+    intervals_file  = file(params.intervals)
+
+    // Create index file for input BAM file
+    SAMTOOLS_INDEX(reads_ch)
+
+    // Call variants from the indexed BAM file
+    GATK_HAPLOTYPECALLER(
+        SAMTOOLS_INDEX.out,
+        ref_file,
+        ref_index_file,
+        ref_dict_file,
+        intervals_file
+    )
+
+    // Collect variant calling outputs across samples
+    all_gvcfs_ch = GATK_HAPLOTYPECALLER.out.vcf.collect()
+    all_idxs_ch = GATK_HAPLOTYPECALLER.out.idx.collect()
+
+    // Combine GVCFs into a GenomicsDB data store and apply joint genotyping
+    GATK_JOINTGENOTYPING(
+        all_gvcfs_ch,
+        all_idxs_ch,
+        intervals_file,
+        params.cohort_name,
+        ref_file,
+        ref_index_file,
+        ref_dict_file
+    )
+}