fix(zig): wrap parentheses patterns in arguments node for call_expression

The parser structure has parentheses as children of the
arguments field within call_expression, not as direct children of
call_expression itself.

This update correctly wraps the parentheses and their contents
within the arguments node.

Fixes: #813

Author: FilipNikolovski

queries/zig/textobjects.scm

@@ -56,20 +56,24 @@
 ; arguments
 (call_expression
   function: (_)
-  "("
-  "," @parameter.outer
-  .
-  (_) @parameter.inner @parameter.outer
-  ")")
+  arguments: (arguments
+    "("
+    "," @_start
+    .
+    (_) @parameter.inner
+    ")")
+  (#make-range! "parameter.outer" @_start @parameter.inner))
 
 (call_expression
   function: (_)
-  "("
-  .
-  (_) @parameter.inner @parameter.outer
-  .
-  ","? @parameter.outer
-  ")")
+  arguments: (arguments
+    "("
+    .
+    (_) @parameter.inner
+    .
+    ","? @_end
+    ")")
+  (#make-range! "parameter.outer" @parameter.inner @_end))
 
 ; comments
 (comment) @comment.outer
@@ -102,6 +106,11 @@
 (call_expression) @call.outer
 
 (call_expression
-  "("
-  _+ @call.inner
-  ")")
+  arguments: (arguments
+    "("
+    .
+    _ @_start
+    _? @_end
+    .
+    ")")
+  (#make-range! "call.inner" @_start @_end))