https://play.openpolicyagent.org/p/Yx4t1akZmC

[rakesh0022]

i am trying to write a rego code for comparing "key" of multiple map not the "value", only the key is present in both the maps policy should give true result else false
below is the code i prepared, howver its not working(not getting true as a result)
added the rego playground link in the title itself

package test
import future.keywords
deny[msg] {
labels = {"lifecycle": "", "project_name":""}
new_labels = {"lifecycle":"prod", "project_name": "test"}
keys_in_map(labels).keys == keys_in_map(new_labels).keys
msg := sprintf("label is matching %v ", [new_labels ])
}
keys(labels) = [k | l := labels, {k, _} := l]

#keys(labels) = [k | k := label, _ := label[k]]

key(new_labels) = [k | k = new_labels _ := new_labels[k]]

error i am getting is

2 errors occurred:
policy.rego:10: rego_parse_error: unexpected assign token: expected "," or "]"
keys(labels) = [k | l := labels, {k, _} := l]
^
policy.rego:10: rego_parse_error: unexpected assign token: expected rule value term (e.g., keys[] = { ... })
keys(labels) = [k | l := labels, {k, _} := l]
^

[anderseknert]

Hi @rakesh0022 👋 If you're running the latest version of OPA, you can use the new object.keys built-in function:

package test

import future.keywords

deny[msg] {
	labels = {"lifecycle": "", "project_name": ""}
	new_labels = {"lifecycle": "prod", "project_name": "test"}
	object.keys(labels) == object.keys(new_labels)

	msg := sprintf("label is matching %v ", [new_labels])
}

If you're running an older version of OPA, a custom function to iterate over object keys could look like this:

package test

import future.keywords

deny[msg] {
	labels = {"lifecycle": "", "project_name": ""}
	new_labels = {"lifecycle": "prod", "project_name": "test"}
	keys(labels) == keys(new_labels)

	msg := sprintf("label is matching %v ", [new_labels])
}

keys(o) := {k | _ = o[k]}

[rakesh0022]

Thank you @anderseknert
Will try this solution

[rakesh0022]

Its working. Thanks for the solution

[rakesh0022]

@anderseknert is their any built in function to get the value of a map(i.e object.value)

[anderseknert]

I'm happy to hear that! Please mark the answer as accepted so that we don't have to return to it later to check 🙂

If you want to get a set of the values, you can use a comprehension:

values := {value | value := object[_]}

[rakesh0022]

Sure thanks for all the help