Implement growable stack and max-depth tracking (#8)

Author: HossamSaberr

src/Containers-Stack-Tests/CTGrowableStackTest.class.st

@@ -0,0 +1,46 @@
+Class {
+	#name : 'CTGrowableStackTest',
+	#superclass : 'TestCase',
+	#instVars : [
+		'stack'
+	],
+	#category : 'Containers-Stack-Tests',
+	#package : 'Containers-Stack-Tests'
+}
+
+{ #category : 'running' }
+CTGrowableStackTest >> setUp [
+	super setUp.
+	stack := CTGrowableStack new
+]
+
+{ #category : 'tests' }
+CTGrowableStackTest >> testIsEmpty [
+	self assert: stack isEmpty.
+	
+	stack push: 'x'.
+	self deny: stack isEmpty.
+	
+	stack pop.
+	self assert: stack isEmpty.
+]
+
+{ #category : 'tests' }
+CTGrowableStackTest >> testPop [
+	stack push: 'first'.
+	stack push: 'second'.
+	
+	self assert: stack pop equals: 'second'.
+	self assert: stack size equals: 1.
+	self assert: stack pop equals: 'first'.
+	self assert: stack isEmpty.
+]
+
+{ #category : 'tests' }
+CTGrowableStackTest >> testPush [
+	stack push: 'a'.
+	
+	self assert: stack size equals: 1.
+	self deny: stack isEmpty.
+	self assert: stack top equals: 'a'.
+]

src/Containers-Stack-Tests/CTTrackedGrowableStackTest.class.st

@@ -0,0 +1,82 @@
+Class {
+	#name : 'CTTrackedGrowableStackTest',
+	#superclass : 'TestCase',
+	#instVars : [
+		'stack'
+	],
+	#category : 'Containers-Stack-Tests',
+	#package : 'Containers-Stack-Tests'
+}
+
+{ #category : 'running' }
+CTTrackedGrowableStackTest >> setUp [
+	super setUp.
+	stack := CTTrackedGrowableStack new
+]
+
+{ #category : 'tests' }
+CTTrackedGrowableStackTest >> testErrorHandlingDoesNotAffectMaxDepth [
+	self should: [ stack pop ] raise: Error.
+	self assert: stack maxDepth equals: 0.
+	
+	stack push: 'temp'.
+	stack pop.
+	
+	self should: [ stack pop ] raise: Error.
+	self assert: stack maxDepth equals: 1.
+]
+
+{ #category : 'tests' }
+CTTrackedGrowableStackTest >> testInitialMaxDepth [
+	self assert: stack maxDepth equals: 0.
+	self assert: stack isEmpty.
+]
+
+{ #category : 'tests' }
+CTTrackedGrowableStackTest >> testMaxDepthAfterPop [
+	stack push: 'apple'.
+	stack push: 'banana'.
+	self assert: stack maxDepth equals: 2.
+	
+	stack pop. 
+	
+	self assert: stack size equals: 1.
+	self assert: stack maxDepth equals: 2. 
+]
+
+{ #category : 'tests' }
+CTTrackedGrowableStackTest >> testMaxDepthWithFluctuations [
+	stack push: 1.
+	stack push: 2.
+	stack pop.
+	stack pop. 
+	
+	stack push: 3.
+	stack push: 4.
+	stack push: 5. 
+	
+	self assert: stack maxDepth equals: 3.
+]
+
+{ #category : 'tests' }
+CTTrackedGrowableStackTest >> testMaxDepthWithLargeDataset [
+	1 to: 100 do: [ :i | stack push: i ].
+	
+	self assert: stack maxDepth equals: 100.
+	self assert: stack size equals: 100.
+	
+	1 to: 50 do: [ :i | stack pop ].
+	
+	self assert: stack maxDepth equals: 100. 
+	self assert: stack size equals: 50.
+]
+
+{ #category : 'tests' }
+CTTrackedGrowableStackTest >> testTopDoesNotAffectMaxDepth [
+	stack push: 'hello'.
+	self assert: stack maxDepth equals: 1.
+	
+	self assert: stack top equals: 'hello'.
+	self assert: stack maxDepth equals: 1.
+	self assert: stack size equals: 1.
+]

src/Containers-Stack/CTGrowableStack.class.st

@@ -0,0 +1,43 @@
+Class {
+	#name : 'CTGrowableStack',
+	#superclass : 'Object',
+	#instVars : [
+		'elements'
+	],
+	#category : 'Containers-Stack',
+	#package : 'Containers-Stack'
+}
+
+{ #category : 'initialization' }
+CTGrowableStack >> initialize [
+	super initialize.
+	elements := OrderedCollection new
+]
+
+{ #category : 'testing' }
+CTGrowableStack >> isEmpty [
+	^ elements isEmpty
+]
+
+{ #category : 'removing' }
+CTGrowableStack >> pop [
+	self isEmpty ifTrue: [ self error: 'Stack is empty' ].
+	^ elements removeLast
+]
+
+{ #category : 'adding' }
+CTGrowableStack >> push: anObject [
+	elements addLast: anObject.
+	^ self
+]
+
+{ #category : 'accessing' }
+CTGrowableStack >> size [
+	^ elements size
+]
+
+{ #category : 'accessing' }
+CTGrowableStack >> top [
+	self isEmpty ifTrue: [ self error: 'Stack is empty' ].
+	^ elements last
+]

src/Containers-Stack/CTTrackedGrowableStack.class.st

@@ -0,0 +1,27 @@
+Class {
+	#name : 'CTTrackedGrowableStack',
+	#superclass : 'CTGrowableStack',
+	#instVars : [
+		'maxDepth'
+	],
+	#category : 'Containers-Stack',
+	#package : 'Containers-Stack'
+}
+
+{ #category : 'initialization' }
+CTTrackedGrowableStack >> initialize [
+	super initialize.
+	maxDepth := 0
+]
+
+{ #category : 'accessing' }
+CTTrackedGrowableStack >> maxDepth [
+	^ maxDepth
+]
+
+{ #category : 'adding' }
+CTTrackedGrowableStack >> push: anObject [
+	super push: anObject.
+	maxDepth := maxDepth max: self size.
+	^ self
+]