Add pixie.data.json for reading and writing JSON

Author: jmglov

pixie/data/json.pxi

@@ -0,0 +1,40 @@
+(ns pixie.data.json
+  (:require [pixie.parser.json]
+            [pixie.string :as string]))
+
+(def read-string pixie.parser.json/read-string)
+
+(defprotocol IToJSON
+  (write-string [this]))
+
+(defn- write-map [m]
+  (if (empty? m)
+    "{}"
+    (str "{ "
+         (->> m
+              (map (fn [[k v]] (string/interp "$(write-string k)$: $(write-string v)$")))
+              (string/join ", "))
+         " }")))
+
+(defn- write-sequential [xs]
+  (if (empty? xs)
+    "[]"
+    (str "[ "
+         (->> (map write-string xs)
+              (string/join ", "))
+         " ]")))
+
+(defn- write-str [s]
+  (string/interp "\"$s$\""))
+
+(extend-protocol IToJSON
+  Character (write-string [this] (write-str this))
+  Cons (write-string [this] (write-sequential this))
+  EmptyList (write-string [this] (write-sequential this))
+  Number (write-string [this] (str this))
+  Keyword (write-string [this] (write-str (name this)))
+  LazySeq (write-string [this] (write-sequential this))
+  IMap (write-string [this] (write-map this))
+  IVector (write-string [this] (write-sequential this))
+  Ratio (write-string [this] (str (float this)))
+  String (write-string [this] (write-str this)))

tests/pixie/tests/data/test-json.pxi

@@ -0,0 +1,19 @@
+(ns pixie.tests.data.test-json
+  (:require [pixie.test :refer :all]
+            [pixie.data.json :as json]))
+
+
+
+;; This test just ensures that we can use read-string; more thorough testing is
+;; done in pixie.tests.parser.test-json
+(deftest test-read-string
+  (assert= (json/read-string "{\"foo\": 42, \"bar\": [\"baz\"]}")
+           {"foo" 42, "bar" ["baz"]}))
+
+(deftest test-write-string
+  (assert= (json/write-string {:strings {:a \a, :b "b", :c "", :d :d}
+                               :numbers {:one 1, :two 2.0, :three 3/1}
+                               :lists {:empty {:vector [], :list '(), :seq (take 0 (range))}
+                                       :non-empty {:vector [1 2 3], :list '(1 2 3), :seq (take 3 (range))}}
+                               :maps {:empty {}, :non-empty {:this "is covered, right? ;)"}}})
+           "{ \"strings\": { \"b\": \"b\", \"c\": \"\", \"a\": \"a\", \"d\": \"d\" }, \"maps\": { \"non-empty\": { \"this\": \"is covered, right? ;)\" }, \"empty\": {} }, \"lists\": { \"non-empty\": { \"seq\": [ 0, 1, 2 ], \"list\": [ 1, 2, 3 ], \"vector\": [ 1, 2, 3 ] }, \"empty\": { \"seq\": [], \"list\": [], \"vector\": [] } }, \"numbers\": { \"one\": 1, \"two\": 2.000000, \"three\": 3 } }"))