Problems with external DAC, no music output

[TaylorDelta]

Hey, i have made a small PCB Project, using the ESP32 as a reciever for music via Bluethooth. The problem is that there is no music at played at the output. An external dac is used: es9023p. The esp is an ESP32-WROOM-32E-N4.

The bluetooth connection works, when no music is played on the phone the esp draws about 0.06A, with music played it uses 0.14A. At pin 18 i could see the 44khz signal using the oszilloscope.

This is the code i used:

#include "ESP_I2S.h"

#include "BluetoothA2DPSink.h"

  

// DAC control pins

#define PIN_DIF         16

#define PIN_MUTEB       17

  

const uint8_t I2S_SCK = 19;       /* Audio data bit clock */

const uint8_t I2S_WS = 18;       /* Audio data left and right clock */

const uint8_t I2S_SDOUT = 4;    /* ESP32 audio data output (to speakers) */

I2SClass i2s;

  

BluetoothA2DPSink a2dp_sink(i2s);

  

void setup() {

  

    // Setup DAC control pins

    pinMode(PIN_DIF, OUTPUT);

    digitalWrite(PIN_DIF, LOW);  // I2S mode

  

    pinMode(PIN_MUTEB, OUTPUT);

    %digitalWrite(PIN_MUTEB, HIGH);  // Unmute

  
  

    i2s.setPins(I2S_SCK, I2S_WS, I2S_SDOUT);

    if (!i2s.begin(I2S_MODE_STD, 44100, I2S_DATA_BIT_WIDTH_16BIT, I2S_SLOT_MODE_STEREO, I2S_STD_SLOT_BOTH)) {

      Serial.println("Failed to initialize I2S!");

      while (1); // do nothing

    }

  

    a2dp_sink.start("Music");

}

  

void loop() {

}

I tought it may be the DAC not doing its work, but the following code works fine:
It just makes two sines with different frequencies and switches between them. This can be heard at the output.

#include <driver/i2s.h>

  

#define I2S_PORT        I2S_NUM_0

  

// I2S pins for ES9023P

#define I2S_PIN_BCK     19

#define I2S_PIN_WS      18

#define I2S_PIN_SD      4

  

// DAC control pins

#define PIN_DIF         16

#define PIN_MUTEB       17

  

const int sampleRate = 44100;

const int amplitude = 10000; // 16-bit amplitude (max 32767)

  

int frequency = 220;

int halfWaveSamples = sampleRate / (frequency * 2);

int32_t sample = amplitude;

int sampleCount = 0;

  

unsigned long lastSwitchTime = 0;

const unsigned long switchInterval = 2000; // 2 seconds

  

void setup() {

  Serial.begin(115200);

  delay(1000);

  Serial.println("Starting 24-bit I2S tone output");

  

  // Setup DAC control pins

  pinMode(PIN_DIF, OUTPUT);

  digitalWrite(PIN_DIF, LOW);  // I2S mode

  

  pinMode(PIN_MUTEB, OUTPUT);

  digitalWrite(PIN_MUTEB, HIGH);  // Unmute

  

  // Configure I2S

  i2s_config_t i2s_config = {

    .mode = (i2s_mode_t)(I2S_MODE_MASTER | I2S_MODE_TX),

    .sample_rate = sampleRate,

    .bits_per_sample = I2S_BITS_PER_SAMPLE_24BIT,

    .channel_format = I2S_CHANNEL_FMT_RIGHT_LEFT,

    .communication_format = I2S_COMM_FORMAT_I2S,

    .intr_alloc_flags = ESP_INTR_FLAG_LEVEL1,

    .dma_buf_count = 8,

    .dma_buf_len = 64,

    .use_apll = false,

    .tx_desc_auto_clear = true,

    .fixed_mclk = 0

  };

  

  i2s_pin_config_t pin_config = {

    .bck_io_num = I2S_PIN_BCK,

    .ws_io_num = I2S_PIN_WS,

    .data_out_num = I2S_PIN_SD,

    .data_in_num = I2S_PIN_NO_CHANGE

  };

  

  esp_err_t err = i2s_driver_install(I2S_PORT, &i2s_config, 0, NULL);

  if (err != ESP_OK) {

    Serial.printf("Failed installing i2s driver: %d\n", err);

    while (true);

  }

  err = i2s_set_pin(I2S_PORT, &pin_config);

  if (err != ESP_OK) {

    Serial.printf("Failed setting i2s pins: %d\n", err);

    while (true);

  }

  

  lastSwitchTime = millis();

}

  

void loop() {

  // Check if it's time to switch frequency

  unsigned long currentTime = millis();

  if (currentTime - lastSwitchTime >= switchInterval) {

    frequency = (frequency == 220) ? 660 : 220;

    halfWaveSamples = sampleRate / (frequency * 2);

    lastSwitchTime = currentTime;

    Serial.printf("Switched frequency to %d Hz\n", frequency);

  }

  

  // Generate square wave sample

  if (sampleCount % halfWaveSamples == 0) {

    sample = -sample;

  }

  

  // Convert 16-bit sample to 24-bit left-justified in 32-bit container

  int32_t sample24 = sample << 8;

  int32_t buffer[2] = { sample24, sample24 }; // Stereo: L+R

  size_t bytes_written = 0;

  

  esp_err_t ret = i2s_write(I2S_PORT, buffer, sizeof(buffer), &bytes_written, portMAX_DELAY);

  if (ret != ESP_OK) {

    Serial.printf("i2s_write error: %d\n", ret);

  }

  

  sampleCount++;

}

I tried to combine both parts but did not succed.
Maybe someone has an idea.
This is the schematic of the pcb:

I appreciate your help — thanks in advance!

[pschatzmann]

Are you sure that the es9023p supports 16 bits ?
I don't understand why you created a test using 24 bits when you want to use 16 bits.
What is your reason why you are still using an obsolete ESP32 Arduino core: The actual version is 3.2.1!

I suggest that you upgrade the ESP32 core and that you use the Arduino Audio Tools to output the signal: this provides you additional functionality e.g. to convert 16 bits to 24 or 32 bits....

[TaylorDelta]

Thanks for your fast reply.

This is my first project, so i dont have much experience.
The core is 3.2.1 is already installed, also the additional boards manager url is set to the espressif arduino github.

I changed the code to this:

#include "AudioTools.h"
#include "BluetoothA2DPSink.h"


// DAC control pins
#define PIN_DIF 16
#define PIN_MUTEB 17

I2SStream i2s;
BluetoothA2DPSink a2dp_sink(i2s);

void setup() {

    pinMode(PIN_DIF, OUTPUT);
    digitalWrite(PIN_DIF, LOW);

    pinMode(PIN_MUTEB, OUTPUT);
    digitalWrite(PIN_MUTEB, HIGH);

    auto cfg = i2s.defaultConfig();
    cfg.pin_bck = 19; 
    cfg.pin_ws = 18;      
    cfg.pin_data = 4;  
    cfg.bits_per_sample = 24; 
    i2s.begin(cfg);

    a2dp_sink.start("MyMusic");
    a2dp_sink.set_on_data_received(data_received_callback);

}

void loop() {
    // Empty loop
}

void data_received_callback() {
  Serial.println(("Data packet received");
}

but still dont work and i get no "Data packet received" in the serial monitor, but when music is send, the esp takes more energy, so they should be recieved. Does the conversion has to be done seperatly?

Thanks in advance

[pschatzmann]

Yes, of cause not! You cant send 16 bit data and pretend that it is 24 bit!
Have a look at the provided example...
Or read the Transforming Audio Data Wikis of the AudioTools...

Also consider this Wiki!

[TaylorDelta]

Thanks, i tried the different examples but im not able to get anything. Output is completly silent. Tried it with 32bit output, with 24bit output. Also tried the sine generator but theres also nothing. I dont have the time for more test, but thanks for your time.

[TaylorDelta]

I looked again in the datasheet for the ES9023P, it states that if smaller bit-width is used, the remaining is 'zero-padded'. I adjusted my test script to 16bit and it works fine:

#include <driver/i2s.h>
#include <math.h>

#define I2S_PORT        I2S_NUM_0

// I2S pins for ES9023P
#define I2S_PIN_BCK     19
#define I2S_PIN_WS      18
#define I2S_PIN_SD      4

// DAC control pins
#define PIN_DIF         16
#define PIN_MUTEB       17

const int sampleRate = 44100;
const int amplitude = 10000; // 16-bit amplitude (max 32767)

int frequency = 220;
const int maxTableSize = 512;
int16_t sineTable[maxTableSize];
int tableSize = 0;
int tableIndex = 0;

unsigned long lastSwitchTime = 0;
const unsigned long switchInterval = 2000; // 2 seconds

void generateSineTable(int freq) {
  tableSize = sampleRate / freq;
  if (tableSize > maxTableSize) tableSize = maxTableSize;

  for (int i = 0; i < tableSize; i++) {
    float angle = 2.0f * M_PI * i / tableSize;
    sineTable[i] = (int16_t)(amplitude * sinf(angle));
  }
  tableIndex = 0;
}

void setup() {
  Serial.begin(115200);
  delay(1000);
  Serial.println("Starting 16-bit I2S sine wave output to ES9023P");

  // DAC control
  pinMode(PIN_DIF, OUTPUT);
  digitalWrite(PIN_DIF, LOW);  // I2S mode
  pinMode(PIN_MUTEB, OUTPUT);
  digitalWrite(PIN_MUTEB, HIGH);  // Unmute

  // I2S config
  i2s_config_t i2s_config = {
    .mode = (i2s_mode_t)(I2S_MODE_MASTER | I2S_MODE_TX),
    .sample_rate = sampleRate,
    .bits_per_sample = I2S_BITS_PER_SAMPLE_16BIT,
    .channel_format = I2S_CHANNEL_FMT_RIGHT_LEFT,
    .communication_format = I2S_COMM_FORMAT_I2S,
    .intr_alloc_flags = ESP_INTR_FLAG_LEVEL1,
    .dma_buf_count = 8,
    .dma_buf_len = 64,
    .use_apll = false,
    .tx_desc_auto_clear = true,
    .fixed_mclk = 0
  };

  i2s_pin_config_t pin_config = {
    .bck_io_num = I2S_PIN_BCK,
    .ws_io_num = I2S_PIN_WS,
    .data_out_num = I2S_PIN_SD,
    .data_in_num = I2S_PIN_NO_CHANGE
  };

  esp_err_t err = i2s_driver_install(I2S_PORT, &i2s_config, 0, NULL);
  if (err != ESP_OK) {
    Serial.printf("Failed installing i2s driver: %d\n", err);
    while (true);
  }
  err = i2s_set_pin(I2S_PORT, &pin_config);
  if (err != ESP_OK) {
    Serial.printf("Failed setting i2s pins: %d\n", err);
    while (true);
  }

  generateSineTable(frequency);
  lastSwitchTime = millis();
}

void loop() {
  // Frequency switch logic
  unsigned long currentTime = millis();
  if (currentTime - lastSwitchTime >= switchInterval) {
    frequency = (frequency == 220) ? 660 : 220;
    generateSineTable(frequency);
    lastSwitchTime = currentTime;
    Serial.printf("Switched frequency to %d Hz\n", frequency);
  }

  // Get next sine sample
  int16_t sample = sineTable[tableIndex++];
  if (tableIndex >= tableSize) tableIndex = 0;

  int16_t buffer[2] = { sample, sample }; // Stereo L+R
  size_t bytes_written;
  i2s_write(I2S_PORT, buffer, sizeof(buffer), &bytes_written, portMAX_DELAY);
}

[pschatzmann]

Why are you still using this obsolete I2S API from an obsolete core version ?

[TaylorDelta]

Well its just to test if the hardware works and still the only script that is able to get a sound out of the dac. Did it with ChatGpt, i didnt look at core version. Since it works its a proof to me that the hardware works. But im still not able to get any of your examples running. Atleast we now know that the sample bit width is not the problem.

[pschatzmann]

fair enough! But don't waste too much time using an API which is not supported any more...