Add cc_onehot module (#121)

* Add `cc_onehot` module

A fast implementation of $onehot()

* Make linter happy

Author: zarubaf

Bender.yml

@@ -23,6 +23,7 @@ sources:
   # Level 0
   - src/binary_to_gray.sv
   - src/cb_filter_pkg.sv
+  - src/cc_onehot.sv
   - src/cdc_2phase.sv
   - src/cf_math_pkg.sv
   - src/clk_div.sv

CHANGELOG.md

@@ -6,6 +6,9 @@ and this project adheres to [Semantic Versioning](http://semver.org/spec/v2.0.0.
 
 ## Unreleased
 
+### Added
+- Add `cc_onehot`
+
 ## 1.22.1 - 2021-06-14
 ### Fixed
 - Remove breaking change of `spill_register`

src/cc_onehot.sv

@@ -0,0 +1,50 @@
+// Copyright 2021 ETH Zurich.
+// Copyright and related rights are licensed under the Solderpad Hardware
+// License, Version 0.51 (the "License"); you may not use this file except in
+// compliance with the License. You may obtain a copy of the License at
+// http://solderpad.org/licenses/SHL-0.51. Unless required by applicable law
+// or agreed to in writing, software, hardware and materials distributed under
+// this License is distributed on an "AS IS" BASIS, WITHOUT WARRANTIES OR
+// CONDITIONS OF ANY KIND, either express or implied. See the License for the
+// specific language governing permissions and limitations under the License.
+
+/// Hardware implementation of SystemVerilog's `$onehot()` function.
+/// It uses a tree of half adders and a separate
+/// or reduction tree for the carry.
+
+// Author: Florian Zaruba <[email protected]>
+// Author: Fabian Schuiki <[email protected]>
+// Author: Stefan Mach <[email protected]>
+module cc_onehot #(
+  parameter int unsigned Width = 4
+) (
+  input  logic [Width-1:0] d_i,
+  output logic is_onehot_o
+);
+  // trivial base case
+  if (Width == 1) begin : gen_degenerated_onehot
+    assign is_onehot_o = d_i;
+  end else begin : gen_onehot
+    localparam int LVLS = $clog2(Width) + 1;
+
+    logic [LVLS-1:0][2**(LVLS-1)-1:0] sum, carry;
+    logic [LVLS-2:0] carry_array;
+
+    // Extend to a power of two.
+    assign sum[0] = $unsigned(d_i);
+
+    // generate half adders for each lvl
+    // lvl 0 is the input level
+    for (genvar i = 1; i < LVLS; i++) begin : gen_lvl
+      localparam int unsigned LVLWidth = 2**LVLS / 2**i;
+      for (genvar j = 0; j < LVLWidth; j+=2) begin : gen_width
+        assign sum[i][j/2] = sum[i-1][j] ^ sum[i-1][j+1];
+        assign carry[i][j/2] = sum[i-1][j] & sum[i-1][j+1];
+      end
+      // generate carry tree
+      assign carry_array[i-1] = |carry[i][LVLWidth/2-1:0];
+    end
+    assign is_onehot_o = sum[LVLS-1][0] & ~|carry_array;
+  end
+
+endmodule