Ch11 added tests and solutions (#226)

* Ch11 added tests and solutions

* Cleanup testParens

Some trailing whitespace snuck in

Co-authored-by: milesfrain <[email protected]>

Author: marer

exercises/chapter11/spago.dhall

@@ -10,6 +10,7 @@ You can edit this file as you like.
     , "ordered-collections"
     , "psci-support"
     , "strings"
+    , "test-unit"
     , "transformers"
     , "yargs"
     ]

exercises/chapter11/test/Main.purs

@@ -2,10 +2,105 @@ module Test.Main where
 
 import Prelude
 
+import Test.MySolutions
+import Test.NoPeeking.Solutions  -- Note to reader: Delete this line
+
 import Effect (Effect)
-import Effect.Class.Console (log)
+import Control.Monad.Writer (runWriterT, execWriter)
+import Control.Monad.Except (runExceptT)
+import Control.Monad.State (runStateT)
+import Data.Either (Either(..))
+import Data.Monoid.Additive (Additive(..))
+import Data.Newtype (unwrap)
+import Data.Tuple (Tuple(..))
+import Test.Unit (TestSuite, success, suite, test)
+import Test.Unit.Assert as Assert
+import Test.Unit.Main (runTest)
 
 main :: Effect Unit
-main = do
-  log "🍝"
-  log "You should add some tests."
+main =
+  runTest do
+    test "" success
+    {-  Move this block comment starting point to enable more tests
+Note to reader: Delete this line to expand comment block -}
+    suite "Exercises Group - The State Monad" do
+      suite "testParens" do
+        let 
+          runTestParens :: Boolean -> String -> TestSuite
+          runTestParens expected str = 
+            test testName do
+              Assert.equal expected $ testParens str
+            where testName = "str = \"" <> str <> "\""
+        runTestParens true ""
+        runTestParens true "(()(())())"
+        runTestParens true "(hello)"
+        runTestParens false ")"
+        runTestParens false "(()()"
+        runTestParens false ")("
+    suite "Exercises Group - The Reader Monad" do
+      suite "indents" do
+        let
+          expectedText =
+            "Here is some indented text:\n\
+            \  I am indented\n\
+            \  So am I\n\
+            \    I am even more indented"
+        test "should render with indentations" do
+          Assert.equal expectedText
+            $ render $ cat
+              [ line "Here is some indented text:"
+              , indent $ cat
+                [ line "I am indented"
+                , line "So am I"
+                , indent $ line "I am even more indented"
+                ]
+              ]
+    suite "Exercises Group - The Writer Monad" do
+      suite "sumArrayWriter" do
+        test "should sum arrays" do
+          Assert.equal (Additive 21)
+            $ execWriter $ do
+              sumArrayWriter [1, 2, 3]
+              sumArrayWriter [4, 5]
+              sumArrayWriter [6]
+      suite "collatz" do
+        let
+          expected_11 =
+            Tuple 14 [11, 34, 17, 52, 26, 13, 40, 20, 10, 5, 16, 8, 4, 2, 1]
+          expected_15 =
+            Tuple 17 [15, 46, 23, 70, 35, 106, 53, 160, 80, 40, 20, 10, 5, 16, 8, 4, 2, 1]
+        test "c = 11" do
+          Assert.equal expected_11
+            $ collatz 11
+        test "c = 15" do
+          Assert.equal expected_15
+            $ collatz 15
+    suite "Exercises Group - Monad Transformers" do
+      suite "parser" do
+        let
+          runParser p s = unwrap $ runExceptT $ runWriterT $ runStateT p s
+        test "should parse a string" do
+          Assert.equal (Right (Tuple (Tuple "abc" "def") ["The state is abcdef"]))
+            $ runParser (string "abc") "abcdef"
+        test "should fail if string could not be parsed" do
+          Assert.equal (Left ["Could not parse"])
+            $ runParser (string "abc") "foobar"
+      suite "indents with ReaderT and WriterT" do
+        let
+          expectedText =
+            "Here is some indented text:\n\
+            \  I am indented\n\
+            \  So am I\n\
+            \    I am even more indented"
+        test "should render with indentations" do
+          Assert.equal expectedText
+            $ render' $ do
+                line' "Here is some indented text:"
+                indent' $ do
+                  line' "I am indented"
+                  line' "So am I"
+                  indent' $ do
+                    line' "I am even more indented"
+
+{- Note to reader: Delete this line to expand comment block
+-}

exercises/chapter11/test/MySolutions.purs

@@ -0,0 +1,5 @@
+module Test.MySolutions where
+
+import Prelude
+
+-- Note to reader : Add your solutions to this file

exercises/chapter11/test/no-peeking/Solutions.purs

@@ -0,0 +1,114 @@
+module Test.NoPeeking.Solutions where
+
+import Prelude
+
+import Control.Monad.Except (ExceptT, throwError)
+import Control.Monad.Reader (Reader, ReaderT, ask, lift, local, runReader, runReaderT)
+import Control.Monad.State (State, StateT, get, put, execState, modify_)
+import Control.Monad.Writer (Writer, WriterT, tell, runWriter, execWriterT)
+import Data.Identity (Identity)
+import Data.Maybe (Maybe(..))
+import Data.Monoid (power)
+import Data.Monoid.Additive (Additive(..))
+import Data.Newtype (unwrap)
+import Data.String (joinWith)
+import Data.String.CodeUnits (stripPrefix, toCharArray)
+import Data.String.Pattern (Pattern(..))
+import Data.Traversable (sequence, traverse_)
+import Data.Tuple (Tuple)
+
+--
+
+testParens :: String -> Boolean
+testParens str =
+  let
+    openTally :: Char -> Int -> Int
+    -- Open parens only considered if not already in deficit.
+    -- No recovery from too-many closed parens.
+    openTally '(' tally | tally >= 0 = tally + 1
+    openTally ')' tally = tally - 1
+    -- Non-parens has no effect
+    openTally _ tally = tally
+
+    sumParens :: Array Char -> State Int Unit
+    sumParens = traverse_ \c -> modify_ $ openTally c
+
+    finalTally :: Int
+    finalTally = execState (sumParens $ toCharArray str) 0
+  in
+    finalTally == 0
+
+--
+
+type Level = Int
+type Doc = (Reader Level) String
+
+line :: String -> Doc
+line str = do
+  level <- ask
+  pure $ (power "  " level) <> str
+
+indent :: Doc -> Doc
+indent = local $ (+) 1
+
+cat :: Array Doc -> Doc
+cat = sequence >=> joinWith "\n" >>> pure
+
+render :: Doc -> String
+render doc = runReader doc 0
+
+--
+
+sumArrayWriter :: Array Int -> Writer (Additive Int) Unit
+sumArrayWriter = traverse_ \n -> do
+  tell $ Additive n
+  pure unit
+
+--
+
+collatz :: Int -> Tuple Int (Array Int)
+collatz c = runWriter $ cltz 0 c
+  where
+    cltz :: Int -> Int -> Writer (Array Int) Int
+    cltz i 1 = do
+      tell [ 1 ]
+      pure i
+    cltz i n = do
+      tell [ n ]
+      if mod n 2 == 0
+        then cltz (i + 1) (n / 2)
+        else cltz (i + 1) ((3 * n) + 1)
+
+--
+
+type Errors = Array String
+type Log = Array String
+type Parser = StateT String (WriterT Log (ExceptT Errors Identity))
+
+string :: String -> Parser String
+string prefix = do
+  st <- get
+  lift $ tell ["The state is " <> st]
+  case stripPrefix (Pattern prefix) st of
+    Just rest -> do
+      put rest
+      pure prefix
+    _ -> do
+      lift $ lift $ throwError ["Could not parse"]
+
+--
+
+type Level' = Int
+type Doc' = (WriterT (Array String) (ReaderT Level' Identity)) Unit
+
+line' :: String -> Doc'
+line' s = do
+  level <- lift $ ask
+  tell [ (power "  " level) <> s ]
+  pure unit
+
+indent' :: Doc' -> Doc'
+indent' = local $ (+) 1
+
+render' :: Doc' -> String
+render' doct = joinWith "\n" $ unwrap $ runReaderT (execWriterT doct) 0