feat: add oracle + tests

Author: MerlinEgalite

src/adapters/WstEthOracle.sol

@@ -0,0 +1,44 @@
+// SPDX-License-Identifier: GPL-2.0-or-later
+pragma solidity 0.8.21;
+
+import {IStETH} from "../interfaces/IStETH.sol";
+import {AggregatorV3Interface} from "../interfaces/AggregatorV3Interface.sol";
+
+/// @title WstEthOracle
+/// @author Morpho Labs
+/// @custom:contact [email protected]
+/// @notice wstETH/ETH exchange rate price feed.
+contract WstEthOracle is AggregatorV3Interface {
+    uint256 public constant version = 1;
+    uint8 public constant DECIMALS = uint8(18);
+    string public constant description = "wstETH/ETH exchange rate price";
+
+    IStETH public immutable ST_ETH;
+
+    constructor(address stEth) {
+        require(stEth != address(0), "WstEthOracle: ZERO_ADDRESS");
+        ST_ETH = IStETH(stEth);
+    }
+
+    function decimals() external view returns (uint8) {
+        return DECIMALS;
+    }
+
+    function getRoundData(uint80)
+        external
+        view
+        returns (uint80 roundId, int256 answer, uint256 startedAt, uint256 updatedAt, uint80 answeredInRound)
+    {
+        return latestRoundData();
+    }
+
+    function latestRoundData()
+        public
+        view
+        returns (uint80 roundId, int256 answer, uint256 startedAt, uint256 updatedAt, uint80 answeredInRound)
+    {
+        uint256 ethByShares = ST_ETH.getPooledEthByShares(10 ** DECIMALS);
+        require(ethByShares < type(uint256).max, "WstEthOracle: OVERFLOW");
+        answer = int256(ethByShares);
+    }
+}

src/interfaces/IStEth.sol

@@ -0,0 +1,6 @@
+// SPDX-License-Identifier: GPL-2.0-or-later
+pragma solidity >=0.5.0;
+
+interface IStETH {
+    function getPooledEthByShares(uint256) external view returns (uint256);
+}

test/WstEthOracle.sol

@@ -0,0 +1,68 @@
+// SPDX-License-Identifier: GPL-2.0-or-later
+pragma solidity ^0.8.0;
+
+import "../lib/forge-std/src/Test.sol";
+import "../src/adapters/WstEthOracle.sol";
+
+contract ChainlinkOracleTest is Test {
+    IStETH internal constant ST_ETH = IStETH(0xae7ab96520DE3A18E5e111B5EaAb095312D7fE84);
+
+    WstEthOracle internal oracle;
+
+    function setUp() public {
+        vm.createSelectFork(vm.envString("ETH_RPC_URL"));
+        oracle = new WstEthOracle(address(ST_ETH));
+    }
+
+    function testLastRoundDataUintMax() public {
+        vm.mockCall(
+            address(ST_ETH),
+            abi.encodeWithSelector(ST_ETH.getPooledEthByShares.selector, 10 ** 18),
+            abi.encode(type(uint256).max)
+        );
+        vm.expectRevert("WstEthOracle: OVERFLOW");
+        oracle.latestRoundData();
+    }
+
+    function testGetRoundDataUintMax() public {
+        vm.mockCall(
+            address(ST_ETH),
+            abi.encodeWithSelector(ST_ETH.getPooledEthByShares.selector, 10 ** 18),
+            abi.encode(type(uint256).max)
+        );
+        vm.expectRevert("WstEthOracle: OVERFLOW");
+        oracle.getRoundData(1);
+    }
+
+    function testDecimals() public {
+        assertEq(oracle.decimals(), uint8(18));
+    }
+
+    function testDeployZeroAddress() public {
+        vm.expectRevert("WstEthOracle: ZERO_ADDRESS");
+        new WstEthOracle(address(0));
+    }
+
+    function testConfig() public {
+        assertEq(oracle.description(), "wstETH/ETH exchange rate price");
+        assertEq(oracle.version(), 1);
+    }
+
+    function testLastRoundData() public {
+        (uint80 roundId, int256 answer, uint256 startedAt, uint256 updatedAt, uint80 answeredInRound) = oracle.latestRoundData();
+        assertEq(roundId, 0);
+        assertEq(answer,int256(ST_ETH.getPooledEthByShares(10 ** 18)));
+        assertEq(startedAt, 0);
+        assertEq(updatedAt, 0);
+        assertEq(answeredInRound, 0);
+    }
+
+    function testGetLastRoundData() public {
+        (uint80 roundId, int256 answer, uint256 startedAt, uint256 updatedAt, uint80 answeredInRound) = oracle.getRoundData(1);
+        assertEq(roundId, 0);
+        assertEq(answer, int256(ST_ETH.getPooledEthByShares(10 ** 18)));
+        assertEq(startedAt, 0);
+        assertEq(updatedAt, 0);
+        assertEq(answeredInRound, 0);
+    }
+}