Utility helpers to convert between std::vector and NSArray.

Differential Revision: D71752746

Pull Request resolved: #9597

Author: shoumikhin

extension/apple/ExecuTorch/Internal/ExecuTorchUtils.h

@@ -23,25 +23,7 @@ using namespace runtime;
  * @param number The NSNumber instance whose scalar type is to be deduced.
  * @return The corresponding ScalarType.
  */
-static inline ScalarType deduceType(NSNumber *number) {
-  auto type = [number objCType][0];
-  type = (type >= 'A' && type <= 'Z') ? type + ('a' - 'A') : type;
-  if (type == 'c') {
-    return ScalarType::Byte;
-  } else if (type == 's') {
-    return ScalarType::Short;
-  } else if (type == 'i') {
-    return ScalarType::Int;
-  } else if (type == 'q' || type == 'l') {
-    return ScalarType::Long;
-  } else if (type == 'f') {
-    return ScalarType::Float;
-  } else if (type == 'd') {
-    return ScalarType::Double;
-  }
-  ET_CHECK_MSG(false, "Unsupported type: %c", type);
-  return ScalarType::Undefined;
-}
+ScalarType deduceType(NSNumber *number);
 
 /**
  * Converts the value held in the NSNumber to the specified C++ type T.
@@ -51,8 +33,8 @@ static inline ScalarType deduceType(NSNumber *number) {
  * @return The value converted to type T.
  */
 template <typename T>
-static inline T extractValue(NSNumber *number) {
-  ET_CHECK_MSG(!(isFloatingType(deduceScalarType(number)) &&
+T extractValue(NSNumber *number) {
+  ET_CHECK_MSG(!(isFloatingType(deduceType(number)) &&
     isIntegralType(CppTypeToScalarType<T>::value, true)),
     "Cannot convert floating point to integral type");
   T value;
@@ -93,6 +75,49 @@ static inline T extractValue(NSNumber *number) {
   return value;
 }
 
+/**
+ * Converts an NSArray of NSNumber objects to a std::vector of type T.
+ *
+ * @tparam T The target C++ numeric type.
+ * @param array The NSArray containing NSNumber objects.
+ * @return A std::vector with the values extracted as type T.
+ */
+template <typename T>
+std::vector<T> toVector(NSArray<NSNumber *> *array) {
+  std::vector<T> vector;
+  vector.reserve(array.count);
+  for (NSNumber *number in array) {
+    vector.push_back(extractValue<T>(number));
+  }
+  return vector;
+}
+
+// Trait for types that can be wrapped into an NSNumber.
+template <typename T>
+constexpr bool isNSNumberWrapable =
+    std::is_arithmetic_v<T> ||
+    std::is_same_v<T, BOOL> ||
+    std::is_same_v<T, BFloat16> ||
+    std::is_same_v<T, Half>;
+
+/**
+ * Converts a generic container of numeric values to an NSArray of NSNumber objects.
+ *
+ * @tparam Container The container type holding numeric values.
+ * @param container The container whose items are to be converted.
+ * @return An NSArray populated with NSNumber objects representing the container's items.
+ */
+template <typename Container>
+NSArray<NSNumber *> *toNSArray(const Container &container) {
+  static_assert(isNSNumberWrapable<typename Container::value_type>, "Invalid container value type");
+  const NSUInteger count = std::distance(std::begin(container), std::end(container));
+  NSMutableArray<NSNumber *> *array = [NSMutableArray arrayWithCapacity:count];
+  for (const auto &item : container) {
+    [array addObject:@(item)];
+  }
+  return array;
+}
+
 } // namespace executorch::extension::utils
 
 #endif // __cplusplus

extension/apple/ExecuTorch/Internal/ExecuTorchUtils.mm

@@ -0,0 +1,35 @@
+/*
+ * Copyright (c) Meta Platforms, Inc. and affiliates.
+ * All rights reserved.
+ *
+ * This source code is licensed under the BSD-style license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+#import "ExecuTorchUtils.h"
+
+namespace executorch::extension::utils {
+using namespace aten;
+using namespace runtime;
+
+ScalarType deduceType(NSNumber *number) {
+  auto type = [number objCType][0];
+  type = (type >= 'A' && type <= 'Z') ? type + ('a' - 'A') : type;
+  if (type == 'c') {
+    return ScalarType::Byte;
+  } else if (type == 's') {
+    return ScalarType::Short;
+  } else if (type == 'i') {
+    return ScalarType::Int;
+  } else if (type == 'q' || type == 'l') {
+    return ScalarType::Long;
+  } else if (type == 'f') {
+    return ScalarType::Float;
+  } else if (type == 'd') {
+    return ScalarType::Double;
+  }
+  ET_CHECK_MSG(false, "Unsupported type: %c", type);
+  return ScalarType::Undefined;
+}
+
+} // namespace executorch::extension::utils

runtime/core/span.h

@@ -35,6 +35,7 @@ namespace runtime {
 template <typename T>
 class Span final {
  public:
+  using value_type = T;
   using iterator = T*;
   using size_type = size_t;