resource-tuner: add BitBake recipe to recipe-support layer

Add initial BitBake recipe for resource-tuner in the recipe-support layer.
The recipe is included as part of the boot-essential package group.

This commit also incorporates review feedback from the initial submission.

Signed-off-by: Jagadeesh Pagadala <[email protected]>

Author: jpagadal

recipes-bsp/packagegroups/packagegroup-qcom.bb

@@ -15,6 +15,7 @@ RDEPENDS:${PN}-boot-essential = " \
     qrtr \
     rmtfs \
     tqftpserv \
+    resource-tuner \
 "
 
 RDEPENDS:${PN}-boot-additional:append:aarch64 = " \

recipes-support/urm/resource-tuner_0.2.bb

@@ -0,0 +1,40 @@
+HOMEPAGE = "https://github.com/qualcomm/resource-tuner"
+SUMMARY = "Userspace daemon for dynamic resource management via cgroups"
+DESCRIPTION = "Resource Tuner is a lightweight userspace daemon that monitors system \
+resources and enforces policies using Linux kernel interfaces such as cgroups and sysfs."
+
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=2998c54c288b081076c9af987bdf4838"
+
+SRC_URI = "git://github.com/qualcomm/resource-tuner.git;protocol=https;branch=main"
+SRCREV = "562e2e19472b6c5c51886a22869bc4c4973b4a6f"
+S = "${UNPACKDIR}/${PN}-${PV}"
+
+DEPENDS += "libyaml systemd"
+
+inherit cmake pkgconfig systemd
+
+EXTRA_OECMAKE += "${S}/Build"
+
+PACKAGECONFIG ??= "signals cli state-detector tests"
+PACKAGECONFIG[signals]        = "-DBUILD_SIGNALS=ON,-DBUILD_SIGNALS=OFF"
+PACKAGECONFIG[cli]            = "-DBUILD_CLI=ON,-DBUILD_CLI=OFF"
+PACKAGECONFIG[state-detector] = "-DBUILD_STATE_DETECTOR=ON,-DBUILD_STATE_DETECTOR=OFF"
+PACKAGECONFIG[tests]          = "-DBUILD_TESTS=ON,-DBUILD_TESTS=OFF"
+
+SYSTEMD_SERVICE:${PN} = "resource-tuner.service"
+
+do_install:append() {
+    install -d ${D}/etc/resource-tuner/common
+    install -m 0644 ${S}/Core/Configs/*.yaml ${D}/etc/resource-tuner/common/
+    install -m 0644 ${S}/Signals/Configs/*.yaml ${D}/etc/resource-tuner/common/
+
+    install -d ${D}/etc/resource-tuner/custom
+    install -d ${D}/etc/resource-tuner/tests/Configs/ResourceSysFsNodes
+    install -m 0644 ${S}/Tests/Configs/*.yaml ${D}/etc/resource-tuner/custom/
+    install -m 0644 ${S}/Tests/Configs/ResourceSysFsNodes/*.txt ${D}/etc/resource-tuner/tests/Configs/ResourceSysFsNodes/
+}
+
+FILES:${PN} += "${libdir}"
+FILES:${PN} += "/etc/resource-tuner/**"
+SOLIBS = ".so"