plugin/emacs: unify all plugin settings into a single library

Currently there is at least two customizeble variables per plugin,
using more than one plugin at time is annoying to configure, this
change generalize and centralize configuration in a single place.

This commit also adds configuration for searching quick-lint-js
executable, along with helper to find it under npm folder structure.

Signed-off-by: wagner riffel <[email protected]>

Author: wgrr

plugin/emacs/CMakeLists.txt

@@ -5,6 +5,7 @@ cmake_minimum_required(VERSION 3.10)
 include(GNUInstallDirs)
 
 install(
+  FILES quicklintjs.el
   FILES flycheck-quicklintjs.el
   FILES lsp-quicklintjs.el
   FILES eglot-quicklintjs.el

plugin/emacs/eglot-quicklintjs.el

@@ -19,26 +19,10 @@
 ;;; Code:
 
 (require 'eglot)
+(require 'quicklintjs)
 
-(defgroup eglot-quicklintjs nil
-  "quick-lint-js Eglot integration."
-  :group 'eglot-quicklintjs
-  :link '(url-link :tag "Website" "https://quick-lint-js.com"))
-
-(defcustom eglot-quicklintjs-program "quick-lint-js"
-  "Path to quick-lint-js program to run."
-  :group 'eglot-quicklintjs
-  :type 'stringp)
-
-(defcustom eglot-quicklintjs-args nil
-  "Arguments to quick-lint-js."
-  :group 'eglot-quicklintjs
-  :type '(repeat string))
-
-(add-to-list 'eglot-server-programs `(js-mode . (,eglot-quicklintjs-program
-                                                  "--lsp-server"
-                                                  ,@eglot-quicklintjs-args)))
-
+(add-to-list 'eglot-server-programs `(js-mode . ,(quicklintjs-find-program
+                                                  "--lsp-server")))
 (provide 'eglot-quicklintjs)
 
 ;; quick-lint-js finds bugs in JavaScript programs.

plugin/emacs/flycheck-quicklintjs.el

@@ -35,16 +35,7 @@
 ;;; Code:
 
 (require 'flycheck)
-
-(defgroup flycheck-quicklintjs nil
-  "quick-lint-js Flycheck integration."
-  :prefix "flycheck-"
-  :group 'flycheck
-  :group 'quicklintjs
-  :link '(url-link :tag "Website" "https://quick-lint-js.com"))
-
-(flycheck-def-args-var flycheck-quicklintjs-args javascript-quicklintjs)
-(flycheck-def-executable-var javascript-quicklintjs "quick-lint-js")
+(require 'quicklintjs)
 
 (defun flycheck-quicklintjs-parse-errors (output checker buffer)
   "Parse quick-lint-js alist output format from OUTPUT"
@@ -62,25 +53,22 @@
                :checker checker
                :end-pos (cdr region)))) (car (read-from-string output))))
 
-(flycheck-define-checker javascript-quicklintjs
+(flycheck-define-command-checker 'javascript-quicklintjs
   "quick-lint-js finds bugs in JavaScript programs.
 
 https://quick-lint-js.com"
-  :command ("quick-lint-js"
-            "--output-format=emacs-lisp"
-            (eval (let ((file (buffer-file-name)))
-                    (if file
-                      `("--path-for-config-search" ,file)
-                      ())))
-            "--stdin"
-            (eval flycheck-quicklintjs-args))
-  :standard-input t
-  :error-parser flycheck-quicklintjs-parse-errors
+  :command (quicklintjs-find-program
+                  "--output-format=emacs-lisp"
+                  (let ((file (buffer-file-name)))
+                    (when file (concat "--path-for-config-search=" file)))
+                  "--stdin")
+  :standard-input 't
+  :error-parser 'flycheck-quicklintjs-parse-errors
   :error-explainer (lambda (err)
                      (let ((error-code (flycheck-error-id err))
                            (url "https://quick-lint-js.com/errors/#%s"))
                        (and error-code `(url . ,(format url error-code)))))
-  :modes js-mode)
+  :modes 'js-mode)
 
 (add-to-list 'flycheck-checkers 'javascript-quicklintjs t)
 

plugin/emacs/flymake-quicklintjs.el

@@ -24,20 +24,7 @@
 ;;; Code:
 
 (require 'flymake)
-
-(defgroup flymake-quicklintjs nil
-  "Flymake backend for quick-lint-js"
-  :link '(url-link :tag "Website" "https://quick-lint-js.com"))
-
-(defcustom flymake-quicklintjs-program "quick-lint-js"
-  "Path to quick-lint-js program to run."
-  :group 'flymake-quicklintjs
-  :type 'stringp)
-
-(defcustom flymake-quicklintjs-args nil
-  "Arguments to quick-lint-js."
-  :group 'flymake-quicklintjs
-  :type '(repeat 'string))
+(require 'quicklintjs)
 
 (defvar-local flymake-quicklintjs--proc nil
   "Internal variable for `flymake-quicklintjs'")
@@ -68,13 +55,10 @@ REPORT-FN is Flymake's callback."
            :connection-type 'pipe
            :noquery t
            :buffer (get-buffer-create " *flymake-quicklintjs*")
-           :command `(,flymake-quicklintjs-program
-                      ,@(let ((file (buffer-file-name)))
-                          (if file
-                            `("--path-for-config-search" ,file)
-                            ()))
-                      "--stdin" "--output-format=emacs-lisp"
-                      ,@flymake-quicklintjs-args)
+           :command (quicklintjs-find-program
+                     (let ((file (buffer-file-name)))
+                       (when file (concat "--path-for-config-search=" file)))
+                      "--stdin" "--output-format=emacs-lisp")
            :sentinel
            (lambda (p _ev)
              (unwind-protect

plugin/emacs/lsp-quicklintjs.el

@@ -18,25 +18,12 @@
 ;;; Code:
 
 (require 'lsp-mode)
-
-(defgroup lsp-quicklintjs nil
-  "quick-lint-js LSP Mode integration."
-  :link '(url-link :tag "Website" "https://quick-lint-js.com"))
-
-(defcustom lsp-quicklintjs-program "quick-lint-js"
-  "Path to quick-lint-js program to run."
-  :group 'lsp-quicklintjs
-  :type 'stringp)
-
-(defcustom lsp-quicklintjs-args nil
-  "Arguments to quick-lint-js."
-  :group 'lsp-quicklintjs
-  :type '(repeat string))
+(require 'quicklintjs)
 
 (lsp-register-client
  (make-lsp-client
-  :new-connection (lsp-stdio-connection `(,lsp-quicklintjs-program "--lsp-server"
-                                                                     ,@lsp-quicklintjs-args))
+  :new-connection (lsp-stdio-connection `,(quicklintjs-find-program
+                                           "--lsp-server"))
   :major-modes '(js-mode)
   :server-id 'quick-lint-js))
 

plugin/emacs/quicklintjs.el

@@ -0,0 +1,90 @@
+;;; quicklintjs.el --- Helper functions for quicklintjs Emacs plugins   -*- lexical-binding: t; -*-
+;;; Commentary:
+
+;; Shared parts of configuration and code among others Emacs plugins.
+
+;;; Code:
+
+(require 'cl-seq)
+
+(defgroup quicklintjs nil
+  "quick-lint-js finds bugs in JavaScript programs."
+  :prefix "quicklintjs-"
+  :group 'tools
+  :group 'processes
+  :link '(url-link :tag "Website" "https://quick-lint-js.com"))
+
+(defcustom quicklintjs-program-name "quick-lint-js"
+  "quick-lint-js executable to use."
+  :group 'quicklintjs
+  :type 'string
+  :safe 'stringp)
+
+(defcustom quicklintjs-program-args nil
+  "Arguments to `quicklintjs-program-name'."
+  :group 'quicklintjs
+  :type '(repeat 'string))
+
+(defcustom quicklintjs-find-program-function #'quicklintjs-executable-find
+  "Function to find quick-lint-js."
+  :group 'quicklintjs
+  :type '(choice (const :tag "Search quick-lint-js in `exec-path'"
+                        quicklintjs-executable-find)
+                 (const :tag "Search quick-lint-js in node-modules"
+                        quicklintjs-node-modules-executable-find)
+                 (function :tag "Function to get quick-lint-js path")))
+
+;;;###autoload
+(defun quicklintjs-executable-find ()
+  "Search `quicklintjs-program-name' in `exec-path'."
+  (executable-find quicklintjs-program-name))
+
+;;;###autoload
+(defun quicklintjs-find-program (&rest argv)
+  "Make a list of strings by calling `quicklintjs-find-program-function',
+appending `quicklintjs-program-args' and `argv'.
+Empty strings and nil are ignored."
+  (cl-remove-if-not (lambda (a) (and (stringp a)
+                                     (> (length a) 0)))
+                    (append (list (funcall
+                                   quicklintjs-find-program-function))
+                            quicklintjs-program-args argv)))
+
+;;;###autoload
+(defun quicklintjs-node-modules-executable-find ()
+  "Search `quicklintjs-program-name' in nearest node_modules relative to
+`default-directory'."
+  (let ((node-mod-dir
+         (locate-dominating-file default-directory
+                                 (lambda (f) (directory-files
+                                              f nil "^node_modules$" t)))))
+    (when node-mod-dir
+      (expand-file-name (concat
+                         (file-name-as-directory node-mod-dir)
+                         (file-name-as-directory "node_modules")
+                         (file-name-as-directory ".bin")
+                         quicklintjs-program-name
+                         (when (memq system-type '(windows-nt ms-dos))
+                           ".cmd"))))))
+
+(provide 'quicklintjs)
+
+;; quick-lint-js finds bugs in JavaScript programs.
+;; Copyright (C) 2020  Matthew Glazar
+;;
+;; This file is part of quick-lint-js.
+;;
+;; quick-lint-js is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+;;
+;; quick-lint-js is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+;;
+;; You should have received a copy of the GNU General Public License
+;; along with quick-lint-js.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; quicklintjs.el ends here

plugin/emacs/test/quicklintjs-test.el

@@ -2,8 +2,10 @@
 ;;; Commentary:
 
 ;;; Code:
+(require 'cl-lib)
 (require 'ert)
 (require 'package)
+(require 'quicklintjs)
 
 (defconst cache-dir-name (concat
                           (expand-file-name default-directory)
@@ -28,10 +30,13 @@
   (quicklintjs-install-deps (if (>= emacs-major-version 26)
                                 '(flycheck eglot lsp-mode)
                               '(flycheck)))
+
+  (set 'quicklintjs-find-program-function (lambda () "quick-lint-js"))
   (def-flycheck-tests)
   (def-eglot-tests)
   (def-lsp-tests)
   (def-flymake-tests)
+  (def-quicklintjs-tests)
   (ert-run-tests-batch-and-exit))
 
 (defun def-flymake-tests ()
@@ -73,7 +78,7 @@ foobar\")((16 . 22) 2 \"E057\" \"use of undeclared variable: foobar\")(\
       (with-current-buffer js-buf
         (insert "foobar")
         (should (equal (call-process-region (point-min) (point-max)
-                                            flymake-quicklintjs-program nil
+                                            quicklintjs-program-name nil
                                             out-buf nil "--stdin"
                                             "--output-format=emacs-lisp") 0)))))
 
@@ -84,7 +89,7 @@ foobar\")((16 . 22) 2 \"E057\" \"use of undeclared variable: foobar\")(\
         (insert "function")
         (should (equal (call-process-region
                         (point-min) (point-max)
-                        flymake-quicklintjs-program nil
+                        quicklintjs-program-name nil
                         out-buf nil "--stdin"
                         "--output-format=emacs-lisp") 0))))))
 
@@ -136,6 +141,20 @@ foobar\")((16 . 22) 2 \"E057\" \"use of undeclared variable: foobar\")(\
           :id "E059" :checker javascript-quicklintjs
           :end-line 1 :end-column 2)))))
 
+(defun def-quicklintjs-tests ()
+  (ert-deftest quicklintjs-find-program-argv ()
+    (should (cl-every (lambda (a b) (string= a b))
+                      (quicklintjs-find-program "foo" "baz")
+                      '("quick-lint-js" "foo" "baz"))))
+  (ert-deftest quicklintjs-find-program-removes-nil ()
+    (should (cl-every (lambda (a b) (string= a b))
+                      (quicklintjs-find-program "foo" nil "baz")
+                      '("quick-lint-js" "foo" "baz"))))
+  (ert-deftest quicklintjs-find-program-removes-empty ()
+    (should (cl-every (lambda (a b) (string= a b))
+                      (quicklintjs-find-program "foo" "" "baz")
+                      '("quick-lint-js" "foo" "baz")))))
+
 ;; quick-lint-js finds bugs in JavaScript programs.
 ;; Copyright (C) 2020  Matthew "strager" Glazar
 ;;