Add support for obtaining box texture regions

Author: rsubtil

source/Config.gd

@@ -391,6 +391,17 @@ func fetch_game_data(path: String, game: RetroHubGameData) -> bool:
 	game.has_media = data["has_media"]
 	if data.has("emulator"):
 		game.emulator = data["emulator"]
+	if data.has("box_texture_regions"):
+		for key in data["box_texture_regions"]:
+			var region_data : PackedFloat64Array = data["box_texture_regions"][key].split_floats(";")
+			if region_data.size() < 4: continue
+			var key_idx : int = RetroHubGameData.BoxTextureRegions.keys().find(key.to_upper())
+			if key_idx == -1: key_idx = int(key)
+			game.box_texture_regions[key_idx] = Rect2(region_data[0], region_data[1], region_data[2], region_data[3])
+	else:
+		# Update older game data with ScreenScraper box texture regions
+		RetroHubScreenScraperScraper._process_box_texture_regions(game)
+		save_game_data(game)
 
 	return true
 
@@ -417,6 +428,18 @@ func save_game_data(game_data: RetroHubGameData) -> bool:
 		"emulator": game_data.emulator
 	}
 
+	var box_texture_regions : Dictionary = {}
+	for key in game_data.box_texture_regions.keys():
+		var region_data := "%f;%f;%f;%f" % [
+			game_data.box_texture_regions[key].position.x,
+			game_data.box_texture_regions[key].position.y,
+			game_data.box_texture_regions[key].size.x,
+			game_data.box_texture_regions[key].size.y
+		]
+		var key_name : String = RetroHubGameData.BoxTextureRegions.keys()[key]
+		box_texture_regions[key_name.to_lower()] = region_data
+	game_data_raw["box_texture_regions"] = box_texture_regions
+
 	var file := FileAccess.open(metadata_path, FileAccess.WRITE)
 	if not file:
 		push_error("Error when opening file %s!" % metadata_path)

source/Media.gd

@@ -372,3 +372,51 @@ func compute_blurhash(game_data: RetroHubGameData) -> void:
 	FileUtils.ensure_path(file_path)
 	JSONUtils.save_json_file(json_data, file_path)
 
+func get_box_texture_region(data: RetroHubGameData, media: RetroHubGameMediaData, type: RetroHubGameData.BoxTextureRegions, rotate: bool = true) -> Texture2D:
+	if not data.box_texture_regions.has(type) or not media.box_texture:
+		return null
+
+	var coords_raw : Rect2 = data.box_texture_regions[type]
+	var _offset_1 := coords_raw.position
+	var _offset_2 := coords_raw.size
+
+	var offset : Vector2
+	var size : Vector2
+	var rotation : int = 0
+
+	# Coords embed text direction. We infer it by the xy ordering of both coords.
+	# 90 degrees (text up-to-down)
+	if _offset_1.x >= _offset_2.x and _offset_1.y < _offset_2.y:
+		offset = Vector2(_offset_2.x, _offset_1.y)
+		size = Vector2(_offset_1.x, _offset_2.y) - offset
+		rotation = 90
+	# 180 degrees (text right-to-left)
+	elif _offset_1.x >= _offset_2.x and _offset_1.y >= _offset_2.y:
+		offset = Vector2(_offset_2.x, _offset_2.y)
+		size = Vector2(_offset_1.x, _offset_1.y) - offset
+		rotation = 180
+	# -90 degrees (text down-to-up)
+	elif _offset_1.x < _offset_2.x and _offset_1.y >= _offset_2.y:
+		offset = Vector2(_offset_1.x, _offset_2.y)
+		size = Vector2(_offset_2.x, _offset_1.y) - offset
+		rotation = -90
+	else:
+		offset = Vector2(_offset_1.x, _offset_1.y)
+		size = Vector2(_offset_2.x, _offset_2.y) - offset
+
+	var image := media.box_texture.get_image()
+	var image_size := Vector2(image.get_width(), image.get_height())
+	var offset_i := Vector2i((offset * image_size).round())
+	var size_i := Vector2i((size * image_size).round())
+	var blit_image := Image.create(size_i.x, size_i.y, false, image.get_format())
+	blit_image.blit_rect(image, Rect2i(offset_i, size_i), Vector2i.ZERO)
+	if rotate:
+		match rotation:
+			-90:
+				blit_image.rotate_90(CLOCKWISE)
+			90:
+				blit_image.rotate_90(COUNTERCLOCKWISE)
+			180:
+				blit_image.rotate_180()
+
+	return ImageTexture.create_from_image(blit_image)

source/data/GameData.gd

@@ -1,6 +1,12 @@
 extends Resource
 class_name RetroHubGameData
 
+enum BoxTextureRegions {
+	BACK,
+	SPINE,
+	FRONT,
+}
+
 # Sorter function
 static func sort(a: RetroHubGameData, b: RetroHubGameData):
 	return a.name.naturalnocasecmp_to(b.name) == -1
@@ -24,6 +30,7 @@ func copy_from(other: RetroHubGameData) -> void:
 	play_count = other.play_count
 	last_played = other.last_played
 	emulator = other.emulator
+	box_texture_regions = other.box_texture_regions.duplicate()
 
 ## Whether this game already has metadata; if it doesn't, you should
 ## present a much simpler view of it
@@ -88,3 +95,8 @@ var last_played : String
 ## Custom emulator to run this game on, overriding default values.
 ## If non-empty, specifies a valid emulator name
 var emulator : String
+
+## Information about box texture regions. This is a dictionary of
+## Rect2 dimensions, with range [0.0 , 1.0] delimiting the regions of the box texture.
+## (use `RetroHubMedia.get_box_texture_region` to fetch the region's sub-Texture)
+var box_texture_regions : Dictionary = {}