Add wrap-content-length middleware

Author: weavejester

ring-core/src/ring/middleware/content_length.clj

@@ -0,0 +1,53 @@
+(ns ring.middleware.content-length
+  (:require [ring.util.response :as resp]))
+
+(defprotocol SizableResponseBody
+  (body-size-in-bytes [body response]
+    "Return the number of bytes that an object will require when it is
+    serialized as a response body. This number will be placed in the
+    Content-Length header of the response by the wrap-content-length
+    middleware. If the number of bytes cannot be ascertained, nil is
+    returned."))
+
+;; Extending primitive arrays prior to Clojure 1.12 requires using the low-level
+;; extend function.
+(extend (Class/forName "[B")
+  SizableResponseBody
+  {:body-size-in-bytes
+   (fn [bs _] (alength bs))})
+
+(extend-protocol SizableResponseBody
+  String
+  (body-size-in-bytes [s response]
+    (when-let [charset (resp/get-charset response)]
+      (alength (.getBytes s charset))))
+  java.io.File
+  (body-size-in-bytes [f _]
+    (.length f))
+  Object
+  (body-size-in-bytes [_ _] nil)
+  nil
+  (body-size-in-bytes [_ _] 0))
+
+(defn content-length-response
+  "Adds a Content-Length header to the response. See: wrap-content-length."
+  {:added "1.15"}
+  [response]
+  (if (resp/get-header response "content-length")
+    response
+    (if-let [size (body-size-in-bytes (:body response) response)]
+      (-> response (resp/header "Content-Length" (str size)))
+      response)))
+
+(defn wrap-content-length
+  "Middleware that adds a Content-Length header to the response, if the
+  response body satisfies the ContentLength protocol."
+  {:added "1.15"}
+  [handler]
+  (fn
+    ([request]
+     (content-length-response (handler request)))
+    ([request respond raise]
+     (handler request
+              (comp respond content-length-response)
+              raise))))

ring-core/test/ring/middleware/test/content_length.clj

@@ -0,0 +1,70 @@
+(ns ring.middleware.test.content-length
+  (:require [clojure.test :refer [deftest is testing]]
+            [ring.middleware.content-length :refer [content-length-response
+                                                    wrap-content-length]]))
+
+(deftest test-content-length-response
+  (testing "strings"
+    (is (= "5" (-> (content-length-response
+                    {:status 200
+                     :headers {"Content-Type" "text/plain; charset=UTF-8"}
+                     :body "hello"})
+                   (get-in [:headers "Content-Length"])))))
+  (testing "strings without a defined charset"
+    (is (nil? (-> (content-length-response
+                   {:status 200
+                    :headers {"Content-Type" "text/plain"}
+                    :body "hello"})
+                  (get-in [:headers "Content-Length"])))))
+  (testing "byte arrays"
+    (is (= "11" (-> (content-length-response
+                     {:status 200
+                      :headers {}
+                      :body (.getBytes "hello world" "UTF-8")})
+                    (get-in [:headers "Content-Length"])))))
+  (testing "files"
+    (is (= "6" (-> (content-length-response
+                    {:status 200
+                     :headers {}
+                     :body (java.io.File. "test/ring/assets/plain.txt")})
+                   (get-in [:headers "Content-Length"])))))
+  (testing "nil"
+    (is (= "0" (-> (content-length-response
+                    {:status 200, :headers {}, :body nil})
+                   (get-in [:headers "Content-Length"])))))
+  (testing "other data"
+    (is (nil? (-> (content-length-response
+                   {:status 200
+                    :headers {"Content-Type" "text/plain; charset=UTF-8"}
+                    :body (list "hello" "world")})
+                  (get-in [:headers "Content-Length"])))))
+  (testing "manual content-length overrides middleware"
+    (is (= "10" (-> (content-length-response
+                     {:status 200
+                      :headers {"Content-Length" "10"}
+                      :body (.getBytes "hello world" "UTF-8")})
+                    (get-in [:headers "Content-Length"]))))))
+
+(deftest test-wrap-content-length
+  (testing "synchronous handlers"
+    (let [handler (wrap-content-length
+                   (constantly
+                    {:status 200
+                     :headers {"Content-Type" "text/plain; charset=UTF-8"}
+                     :body "hello"}))]
+      (is (= "5" (-> (handler {:request-method :get, :uri "/"})
+                     (get-in [:headers "Content-Length"]))))))
+  (testing "asynchronous handlers"
+    (let [response (promise)
+          error    (promise)
+          request  {:request-method :get, :url "/"}
+          handler  (wrap-content-length
+                    (fn [_ respond _]
+                      (respond
+                       {:status 200
+                        :headers {"Content-Type" "text/plain; charset=UTF-8"}
+                        :body "hello"})))]
+      (handler request response error)
+      (is (not (realized? error)))
+      (is (realized? response))
+      (is (= "5" (get-in @response [:headers "Content-Length"]))))))