Merge pull request #321 from sonwh98/better-file-tests

Add option to change priority of wrap-file

Author: weavejester

ring-core/src/ring/middleware/file.clj

@@ -40,15 +40,28 @@
   Accepts the following options:
 
   :index-files?    - look for index.* files in directories, defaults to true
-  :allow-symlinks? - serve files through symbolic links, defaults to false"
+  :allow-symlinks? - serve files through symbolic links, defaults to false
+  :prefer-handler? - prioritize handler response over files, defaults to false"
   ([handler root-path]
    (wrap-file handler root-path {}))
   ([handler root-path options]
    (ensure-dir root-path)
    (fn
      ([request]
-      (or (file-request request root-path options) (handler request)))
+      (if (:prefer-handler? options)
+        (let [response (handler request)]
+          (if (= 404 (:status response))
+            (file-request request root-path options)
+            response))
+        (or (file-request request root-path options) (handler request))))
      ([request respond raise]
-      (if-let [response (file-request request root-path options)]
-        (respond response)
-        (handler request respond raise))))))
+      (if (:prefer-handler? options)
+        (handler request
+                 (fn [response]
+                   (if (= 404 (:status response))
+                     (respond (file-request request root-path options))
+                     (respond response)))
+                 raise)
+        (if-let [response (file-request request root-path options)]
+          (respond response)
+          (handler request respond raise)))))))

ring-core/test/ring/middleware/test/file.clj

@@ -8,7 +8,7 @@
 
 (deftest wrap-file-no-directory
   (is (thrown-with-msg? Exception #".*Directory does not exist.*"
-    (wrap-file (constantly test-response) "not_here"))))
+                        (wrap-file (constantly test-response) "not_here"))))
 
 (def public-dir "test/ring/assets")
 (def index-html (File. ^String public-dir "index.html"))
@@ -93,3 +93,42 @@
       (is (= 200 status))
       (is (= (into #{} (keys headers)) #{"Content-Length" "Last-Modified"}))
       (is (= foo-html body)))))
+
+(defn- prefer-foo-handler
+  ([request]
+   (if (= (:uri request) "/foo.html")
+     {:status 200, :headers {}, :body "override"}
+     {:status 404, :headers {}, :body "not found"}))
+  ([request respond raise]
+   (respond (prefer-foo-handler request))))
+
+(deftest test-wrap-file-with-prefer-handler
+  (let [handler (wrap-file prefer-foo-handler
+                           (File. public-dir)
+                           {:prefer-handler? true})]
+
+    (testing "middleware serves file (synchronously)"
+      (let [response (handler {:request-method :get, :uri "/index.html"})]
+        (is (= 200 (:status response)))
+        (is (= index-html (:body response)))))
+
+    (testing "middleware serves file (asynchronously)"
+      (let [response (promise)
+            error    (promise)]
+        (handler {:request-method :get, :uri "/index.html"} response error)
+        (is (= 200 (:status @response)))
+        (is (= index-html (:body @response)))
+        (is (not (realized? error)))))
+
+    (testing "handler serves file (synchronously)"
+      (let [response (handler {:request-method :get, :uri "/foo.html"})]
+        (is (= 200 (:status response)))
+        (is (= "override" (:body response)))))
+
+    (testing "handler serves file (asynchronously)"
+      (let [response (promise)
+            error    (promise)]
+        (handler {:request-method :get, :uri "/foo.html"} response error)
+        (is (= 200 (:status @response)))
+        (is (= "override" (:body @response)))
+        (is (not (realized? error)))))))