Add ecl subproject

Author: tobiasdiez

src/meson.build

@@ -118,7 +118,7 @@ png = dependency(['libpng', 'png', 'png16'], version: '>=1.2')
 zlib = dependency('zlib', version: '>=1.2.11')
 # We actually want >= 20231212, but the version number is not updated in the pkgconfig
 # https://github.com/conda-forge/eclib-feedstock/issues/48
-ec = dependency('eclib', version: '>=20231211', required: false)
+ec = dependency('eclib', version: '>=20231211', required: false, disabler: true)
 # Cannot be found via pkg-config
 ecm = cc.find_library('ecm')
 gmpxx = dependency('gmpxx')

src/sage/libs/meson.build

@@ -1,6 +1,10 @@
 sirocco = cc.find_library('sirocco', required: false, disabler: true)
 # cannot be found via pkg-config
 ecl = cc.find_library('ecl', required: false, disabler: true)
+if not ecl.found()
+  ecl_proj = subproject('ecl')
+  ecl = ecl_proj.get_variable('ecl_dep')
+endif
 braiding = dependency('libbraiding', required: false)
 if not braiding.found()
   # Fallback since pkg-config support was only added in v1.3.1
@@ -39,14 +43,18 @@ extension_data = {
   'meataxe': files('meataxe.pyx'),
 }
 
-dependencies = [py_dep, braiding, cysignals, ecl, ecm, gc, gmp, homfly]
+dependencies = [py_dep, cysignals, ecl, gc, gmp]
 
 foreach name, pyx : extension_data
   deps = dependencies
   if name == 'sirocco'
     deps += [sirocco]
   elif name == 'meataxe'
     deps += [mtx]
+  elif name == 'homfly'
+    deps += [homfly]
+  elif name == 'libecm'
+    deps += [ecm]
   endif
 
   py.extension_module(
@@ -62,14 +70,18 @@ endforeach
 extension_data_cpp = {'braiding': files('braiding.pyx')}
 
 foreach name, pyx : extension_data_cpp
+  deps = dependencies
+  if name == 'braiding'
+    deps += [braiding]
+  endif
   py.extension_module(
     name,
     sources: pyx,
     subdir: 'sage/libs',
     install: true,
     override_options: ['cython_language=cpp'],
     include_directories: [inc_cpython, inc_rings],
-    dependencies: dependencies,
+    dependencies: deps,
   )
 endforeach
 

subprojects/ecl.wrap

@@ -0,0 +1,5 @@
+[wrap-git]
+url = https://gitlab.com/embeddable-common-lisp/ecl.git
+revision = 24.5.10
+depth = 1
+patch_directory = ecl

subprojects/packagefiles/ecl/meson.build

@@ -0,0 +1,6 @@
+project('ecl', 'c',
+  meson_version : '>=0.57.0',
+)
+
+mod = import('unstable-external_project')
+subdir('src')

subprojects/packagefiles/ecl/src/meson.build

@@ -0,0 +1,10 @@
+proj = mod.add_project('configure',
+  configure_options : [
+                       '--enable-manual=no',
+                       '--enable-unicode=yes',
+                       '--with-defsystem' 
+                      ],
+)
+
+ecl_dep = proj.dependency('ecl')
+meson.override_dependency('ecl', ecl_dep)