meson: make several optional features explicitly configurable

Several libraries are detected at setup time, and the corresponding
feature is enabled or disabled based on the library's presence. This
commit retains this behavior by default while making it possible to
explicitly enable or disable the feature via,

  $ meson setup -Dfoo=disabled

or

  $ meson setup -Dfoo=enabled

The former disables the feature even if the library is installed, and the
latter makes it an error if the library is not installed.

The list of features (valid values for foo) is,

  * bliss
  * brial
  * coxeter3
  * mcqd
  * meataxe
  * rankwidth
  * sirocco
  * tdlib

Author: orlitzky

meson.options

@@ -16,3 +16,62 @@ option(
   type: 'boolean',
   description: 'Build the HTML / PDF documentation'
 )
+
+#
+# Features
+#
+option(
+  'bliss',
+  type: 'feature',
+  value: 'auto',
+  description: 'Bliss interface to graph isomorphisms'
+)
+
+option(
+  'brial',
+  type: 'feature',
+  value: 'auto',
+  description: 'BRiAl interface to polynomials over boolean rings'
+)
+
+option(
+  'coxeter3',
+  type: 'feature',
+  value: 'auto',
+  description: 'Coxeter 3.x interface to Coxeter groups'
+)
+
+option(
+  'mcqd',
+  type: 'feature',
+  value: 'auto',
+  description: 'MCQD interface to the MaxCliqueDyn algorithm'
+)
+
+option(
+  'meataxe',
+  type: 'feature',
+  value: 'auto',
+  description: 'Interface to the MeatAxe program'
+)
+
+option(
+  'rankwidth',
+  type: 'feature',
+  value: 'auto',
+  description: 'Interface to librw for rank-width decompositions'
+)
+
+option(
+  'sirocco',
+  type: 'feature',
+  value: 'auto',
+  description: 'Sirocco interface to certified root continuation'
+)
+
+option(
+  'tdlib',
+  type: 'feature',
+  value: 'auto',
+  description: 'Interface to tdlib for tree decompositions'
+)

src/meson.build

@@ -151,7 +151,7 @@ endif
 # Cannot be found via pkg-config
 mtx = cc.find_library(
   'mtx',
-  required: false,
+  required: get_option('meataxe'),
   disabler: true,
   has_headers: ['meataxe.h'],
 )

src/sage/graphs/graph_decompositions/meson.build

@@ -1,11 +1,10 @@
-# tdlib is a header-only library
-if cc.has_header('treedec/combinations.hpp')
+tdlib = disabler()
+if cc.has_header('treedec/combinations.hpp', required: get_option('tdlib'))
+  # tdlib is a header-only library
   tdlib = declare_dependency()
-else
-  tdlib = disabler()
 endif
 # Cannot be found via pkg-config
-rw = cc.find_library('rw', required: false, disabler: true)
+rw = cc.find_library('rw', required: get_option('rankwidth'), disabler: true)
 
 py.install_sources(
   '__init__.py',

src/sage/graphs/meson.build

@@ -1,9 +1,9 @@
-bliss = cc.find_library('bliss', required: false, disabler: true)
-# mcqd is a header-only library
-if cc.has_header('mcqd.h')
+bliss = cc.find_library('bliss', required: get_option('bliss'), disabler: true)
+
+mcqd = disabler()
+if cc.has_header('mcqd.h', required: get_option('mcqd'))
+  # mcqd is a header-only library
   mcqd = declare_dependency()
-else
-  mcqd = disabler()
 endif
 cliquer = cc.find_library('cliquer', required: not is_windows, disabler: true)
 

src/sage/libs/coxeter3/meson.build

@@ -1,4 +1,4 @@
-coxeter3 = cc.find_library('coxeter3', required: false, disabler: true)
+coxeter3 = cc.find_library('coxeter3', required: get_option('coxeter3'), disabler: true)
 py.install_sources(
   '__init__.py',
   'all__sagemath_coxeter3.py',

src/sage/libs/meson.build

@@ -1,4 +1,4 @@
-sirocco = cc.find_library('sirocco', required: false, disabler: true)
+sirocco = cc.find_library('sirocco', required: get_option('sirocco'), disabler: true)
 # cannot be found via pkg-config
 ecl = cc.find_library('ecl', required: false, disabler: true)
 if not ecl.found() and not is_windows

src/sage/rings/polynomial/pbori/meson.build

@@ -1,8 +1,8 @@
-brial = cc.find_library('brial', required: false, disabler: true)
+brial = cc.find_library('brial', required: get_option('brial'), disabler: true)
 # Cannot be found via pkg-config
 brial_groebner = cc.find_library(
   'brial_groebner',
-  required: false,
+  required: get_option('brial'),
   disabler: true,
 )