fuzon/justfile at main · sdsc-ordes/fuzon · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
set positional-arguments
set shell := ["bash", "-cue"]
root := justfile_directory()

# Default recipe to list all recipes.
default:
  just --list

# Build all packages.
build *args:
  cargo build \
    --manifest-path src/fuzon/Cargo.toml \
    --release
  maturin build \
    --manifest-path src/pyfuzon/Cargo.toml \
    --release \
    {{args}}

# Package rust binary with nix.
package-nix *args:
    cd {{root}} && \
    nix build "./tools/nix#fuzon" -o "package/fuzon" {{args}}

# Enter nix devshell.
develop-nix *args:
  cd {{root}} \
    && cmd=("$@") \
    && { [ -n "${cmd:-}" ] || cmd=("zsh"); } \
    && nix develop ./tools/nix#default --command "${cmd[@]}"

# Enter development container
develop-docker:
  just image::run \
    -it \
    --user 1000:1000 \
    -w "/workspace" \
    --mount type=bind,source="$(pwd)",target=/workspace


# manage OCI container images
mod image './tools/just/image.just'
# manage Python package
mod maturin './tools/just/maturin.just'