feat(front): partial pipeline rebuild in UI (#414)

## 📝 Description
Related task: #29

## ✅ Checklist
- [x] I have tested this change
- [ ] This change requires documentation update

Author: skipi

front/assets/js/workflow_view/interactive_pipeline_tree.js

@@ -11,6 +11,7 @@ export var InteractivePipelineTree = {
   init: function(opts = {}) {
     InteractivePipelineTree.handleWorkflowTreeItemClicks(opts);
     InteractivePipelineTree.handlePipelineStopClicks();
+    InteractivePipelineTree.handlePipelineRebuildClicks();
     InteractivePipelineTree.handleToggleSkippedBlocksClicks();
   },
 
@@ -41,6 +42,35 @@ export var InteractivePipelineTree = {
     });
   },
 
+  handlePipelineRebuildClicks: function() {
+    $("body").on("click", "[pipeline-rebuild-button]", function(event) {
+      event.preventDefault();
+      let button = $(event.currentTarget);
+      let href = button.attr("href");
+      button.text("Rebuilding...")
+      button.attr("disabled", true);
+
+      let req = $.ajax({
+        url: href,
+        type: "POST",
+        beforeSend: function(xhr) {
+          xhr.setRequestHeader("X-CSRF-Token", $("meta[name='csrf-token']").attr("content"));
+        }
+      });
+
+      req.done(function(data) {
+        if(data.error != undefined) {
+          Notice.error(data.error)
+          button.text("Rebuild Pipeline")
+          button.attr("disabled", false);
+        } else {
+          Notice.notice(data.message)
+          button.remove();
+        }
+      })
+    });
+  },
+
   onWorkflowTreeItemClick: function(event) {
     let pipelineId = $(event.currentTarget).data("pipeline-id");
 

front/lib/front/clients/pipeline.ex

@@ -184,4 +184,28 @@ defmodule Front.Clients.Pipeline do
       response
     end)
   end
+
+  def partial_rebuild(request) do
+    Watchman.benchmark("pipeline.partial_rebuild.duration", fn ->
+      response =
+        channel()
+        |> Stub.partial_rebuild(request, metadata: metadata(), timeout: timeout())
+
+      case response do
+        {:ok, _} -> Watchman.increment("pipeline.partial_rebuild.success")
+        {:error, _} -> Watchman.increment("pipeline.partial_rebuild.failure")
+      end
+
+      Logger.debug(fn ->
+        """
+        Pipeline API partial_rebuild returned response
+        #{inspect(response)}
+        for request
+        #{inspect(request)}
+        """
+      end)
+
+      response
+    end)
+  end
 end

front/lib/front/models/pipeline.ex

@@ -14,6 +14,7 @@ defmodule Front.Models.Pipeline do
     DescribeTopologyRequest,
     ListKeysetRequest,
     ListRequest,
+    PartialRebuildRequest,
     Pipeline,
     TerminateRequest
   }
@@ -349,6 +350,23 @@ defmodule Front.Models.Pipeline do
     end
   end
 
+  def rebuild(id, requester_id, _tracing_headers \\ nil) do
+    request =
+      PartialRebuildRequest.new(
+        ppl_id: id,
+        user_id: requester_id,
+        request_token: UUID.uuid4()
+      )
+
+    {:ok, response} = Clients.Pipeline.partial_rebuild(request)
+
+    case ResponseCode.key(response.response_status.code) do
+      :OK -> {:ok, response.ppl_id}
+      :BAD_PARAM -> {:error, response.response_status.message}
+      _ -> {:error, "Failed to rebuild pipeline"}
+    end
+  end
+
   defp request_stream(req, tracing_headers, override \\ nil) do
     request(req, tracing_headers) |> stream_if_needed(override)
   end

front/lib/front_web/controllers/pipeline_controller.ex

@@ -18,9 +18,10 @@ defmodule FrontWeb.PipelineController do
   plug(PublicPageAccess when action in @public_endpoints)
   plug(PageAccess, [permissions: "project.view"] when action not in @public_endpoints)
   plug(PageAccess, [permissions: "project.job.stop"] when action == :stop)
+  plug(PageAccess, [permissions: "project.job.rerun"] when action == :rebuild)
 
   plug(:assign_pipeline_with_blocks when action in [:show, :poll])
-  plug(:assign_pipeline_without_blocks when action in [:status, :switch, :stop])
+  plug(:assign_pipeline_without_blocks when action in [:status, :switch, :stop, :rebuild])
   plug(:preload_switch when action in [:show, :poll, :switch])
 
   def path(conn, params) do
@@ -130,6 +131,32 @@ defmodule FrontWeb.PipelineController do
     end
   end
 
+  def rebuild(conn, _params) do
+    Watchman.benchmark("rebuild.duration", fn ->
+      project = conn.assigns.project
+      workflow = conn.assigns.workflow
+      pipeline = conn.assigns.pipeline
+
+      log_rebuild(conn, project, workflow, pipeline)
+      rebuild_pipeline(conn, pipeline.id, conn.assigns.user_id, conn.assigns.tracing_headers)
+    end)
+  end
+
+  defp rebuild_pipeline(conn, ppl_id, user_id, tracing_headers) do
+    case Pipeline.rebuild(ppl_id, user_id, tracing_headers) do
+      {:ok, new_pipeline_id} ->
+        conn
+        |> json(%{
+          message: "Pipeline rebuild initiated successfully.",
+          pipeline_id: new_pipeline_id
+        })
+
+      {:error, message} ->
+        conn
+        |> json(%{error: message})
+    end
+  end
+
   defp organization_matches?(organization_id, pipeline_organization_id) do
     organization_id == pipeline_organization_id
   end
@@ -152,6 +179,20 @@ defmodule FrontWeb.PipelineController do
     |> Audit.log()
   end
 
+  defp log_rebuild(conn, project, workflow, pipeline) do
+    conn
+    |> Audit.new(:Pipeline, :Rebuild)
+    |> Audit.add(:resource_name, pipeline.name)
+    |> Audit.add(:description, "Rebuilt the pipeline")
+    |> Audit.metadata(project_id: project.id)
+    |> Audit.metadata(project_name: project.name)
+    |> Audit.metadata(branch_name: workflow.branch_name)
+    |> Audit.metadata(workflow_id: workflow.id)
+    |> Audit.metadata(commit_sha: workflow.commit_sha)
+    |> Audit.metadata(pipeline_id: pipeline.id)
+    |> Audit.log()
+  end
+
   defp pipeline_data(conn, params) do
     diagram =
       if FeatureProvider.feature_enabled?(:toggle_skipped_blocks,

front/lib/front_web/router.ex

@@ -638,6 +638,10 @@ defmodule FrontWeb.Router do
       as: :pipeline_stop
     )
 
+    post("/workflows/:workflow_id/pipelines/:pipeline_id/rebuild", PipelineController, :rebuild,
+      as: :pipeline_rebuild
+    )
+
     post(
       "/workflows/:workflow_id/pipelines/:pipeline_id/swithes/:switch_id/targets/:name",
       TargetController,

front/lib/front_web/templates/workflow/status/_interactive_pipeline.html.eex

@@ -21,6 +21,10 @@
       <span class="gray mh2">&middot;</span>
       <%= link "Stop Pipeline", to: pipeline_stop_path(@conn, :stop, @workflow.id, @pipeline.id), class: "btn btn-secondary btn-tiny", pipeline_stop_button: "true" %>
     <% end %>
+    <%= if @conn.assigns.permissions["project.job.rerun"] && FrontWeb.PipelineView.pipeline_rebuildable?(@pipeline) && !FrontWeb.PipelineView.anonymous?(@conn) do %>
+      <span class="gray mh2">&middot;</span>
+      <%= link "Rebuild Pipeline", to: pipeline_rebuild_path(@conn, :rebuild, @workflow.id, @pipeline.id), class: "btn btn-secondary btn-tiny", pipeline_rebuild_button: "true", title: "Rerun only failed jobs in this pipeline" %>
+    <% end %>
     <span class="child ml2">←</span>
   </div>
 </div>

front/lib/front_web/views/pipeline_view.ex

@@ -299,6 +299,10 @@ defmodule FrontWeb.PipelineView do
     pipeline.state != :DONE && pipeline.state != :STOPPING
   end
 
+  def pipeline_rebuildable?(pipeline) do
+    pipeline.state == :DONE && pipeline.result != :PASSED
+  end
+
   def anonymous?(conn) do
     conn.assigns.anonymous
   end

front/test/front/clients/pipeline_test.exs

@@ -7,6 +7,7 @@ defmodule Front.Clients.PipelineTest do
     DescribeManyRequest,
     DescribeRequest,
     DescribeTopologyRequest,
+    PartialRebuildRequest,
     TerminateRequest
   }
 
@@ -53,4 +54,15 @@ defmodule Front.Clients.PipelineTest do
       assert {:ok, response} == Pipeline.terminate(request)
     end
   end
+
+  describe "partial_rebuild" do
+    test "returns PartialRebuildResponse for PartialRebuildRequest" do
+      request = PartialRebuildRequest.new()
+
+      response = Factories.Pipeline.partial_rebuild_response()
+      GrpcMock.stub(PipelineMock, :partial_rebuild, response)
+
+      assert {:ok, response} == Pipeline.partial_rebuild(request)
+    end
+  end
 end

front/test/front_web/controllers/pipeline_controller_test.exs

@@ -262,4 +262,50 @@ defmodule FrontWeb.PipelineControllerTest do
       assert conn.status == 404
     end
   end
+
+  describe "rebuild" do
+    test "sends partial rebuild request", %{
+      conn: conn,
+      workflow_id: workflow_id,
+      pipeline_id: pipeline_id
+    } do
+      conn =
+        conn
+        |> post("/workflows/#{workflow_id}/pipelines/#{pipeline_id}/rebuild")
+
+      assert conn.status == 200
+      assert json_response(conn, 200)["message"] == "Pipeline rebuild initiated successfully."
+      assert json_response(conn, 200)["pipeline_id"] != nil
+    end
+
+    test "returns 404 when organization_id mismatches", %{
+      conn: conn,
+      workflow_id: workflow_id,
+      pipeline_id: pipeline_id
+    } do
+      conn =
+        conn
+        |> Plug.Conn.put_req_header("x-semaphore-org-id", Ecto.UUID.generate())
+        |> post("/workflows/#{workflow_id}/pipelines/#{pipeline_id}/rebuild")
+
+      assert conn.status == 404
+    end
+  end
+
+  describe "rebuild => when user does not have permission to rerun jobs" do
+    test "returns 404", %{conn: conn, workflow_id: workflow_id, pipeline_id: pipeline_id} do
+      Support.Stubs.PermissionPatrol.remove_all_permissions()
+
+      org = Support.Stubs.DB.first(:organizations)
+      user = Support.Stubs.DB.first(:users)
+
+      Support.Stubs.PermissionPatrol.allow_everything_except(org.id, user.id, "project.job.rerun")
+
+      conn =
+        conn
+        |> post("/workflows/#{workflow_id}/pipelines/#{pipeline_id}/rebuild")
+
+      assert conn.status == 404
+    end
+  end
 end

front/test/front_web/views/pipeline_view_test.exs

@@ -244,4 +244,26 @@ defmodule FrontWeb.PipelineViewTest do
       assert action =~ "Triggered"
     end
   end
+
+  describe ".pipeline_rebuildable?" do
+    test "returns true when pipeline is in DONE state" do
+      pipeline = %Models.Pipeline{state: :DONE}
+      assert PipelineView.pipeline_rebuildable?(pipeline) == true
+    end
+
+    test "returns false when pipeline is in PENDING state" do
+      pipeline = %Models.Pipeline{state: :PENDING}
+      assert PipelineView.pipeline_rebuildable?(pipeline) == false
+    end
+
+    test "returns false when pipeline is in RUNNING state" do
+      pipeline = %Models.Pipeline{state: :RUNNING}
+      assert PipelineView.pipeline_rebuildable?(pipeline) == false
+    end
+
+    test "returns false when pipeline is in STOPPING state" do
+      pipeline = %Models.Pipeline{state: :STOPPING}
+      assert PipelineView.pipeline_rebuildable?(pipeline) == false
+    end
+  end
 end